Perf: memoize _zsh_highlight_main_highlighter_highlight_argument

Author: romkatv

highlighters/main/main-highlighter.zsh

@@ -1234,6 +1234,19 @@ _zsh_highlight_main_highlighter_check_path()
 # This function currently assumes it's never called for the command word.
 _zsh_highlight_main_highlighter_highlight_argument()
 {
+  if (( $+_zsh_highlight_main__arg_cache )); then
+    local cache_key=$1$'\0'$2$'\0'$arg$'\0'$last_arg$'\0'$has_end$'\0'$highlight_glob$'\0'$in_redirection$'\0'$zsyh_user_options[multios]
+    local -a cache_val=(${(@0)_zsh_highlight_main__arg_cache[$cache_key]})
+    if (( $#cache_val )); then
+      integer offset=$(( start_pos - $cache_val[-1] ))
+      local start end_ style
+      for start end_ style in $cache_val[1,-2]; do
+        _zsh_highlight_main_add_region_highlight $(( start + offset )) $(( end_ + offset )) $style
+      done
+      return
+    fi
+  fi
+
   local base_style=default i=$1 option_eligible=${2:-1} path_eligible=1 ret start style
   local -a highlights
 
@@ -1381,6 +1394,11 @@ _zsh_highlight_main_highlighter_highlight_argument()
 
   highlights=($(( start_pos + $1 - 1 )) $end_pos $base_style $highlights)
   _zsh_highlight_main_add_many_region_highlights $highlights
+
+  if (( $+_zsh_highlight_main__arg_cache )); then
+    highlights+=($start_pos)
+    _zsh_highlight_main__arg_cache[$cache_key]=${(pj:\0:)highlights}
+  fi
 }
 
 # Quote Helper Functions
@@ -1761,6 +1779,7 @@ _zsh_highlight_main__precmd_hook() {
 
   _zsh_highlight_main__command_type_cache=()
   _zsh_highlight_main__path_cache=()
+  _zsh_highlight_main__arg_cache=()
 
   if [[ $ZSH_VERSION != (5.<9->*|<6->.*) ]]; then
     _zsh_highlight_main_calculate_styles
@@ -1770,11 +1789,11 @@ _zsh_highlight_main__precmd_hook() {
 autoload -Uz add-zsh-hook
 if add-zsh-hook precmd _zsh_highlight_main__precmd_hook 2>/dev/null; then
   # Initialize caches
-  typeset -gA _zsh_highlight_main__command_type_cache _zsh_highlight_main__path_cache
+  typeset -gA _zsh_highlight_main__command_type_cache _zsh_highlight_main__path_cache _zsh_highlight_main__arg_cache
 else
   print -r -- >&2 'zsh-syntax-highlighting: Failed to load add-zsh-hook. Some speed optimizations will not be used.'
   # Make sure the caches are unset
-  unset _zsh_highlight_main__command_type_cache _zsh_highlight_main__path_cache
+  unset _zsh_highlight_main__command_type_cache _zsh_highlight_main__path_cache _zsh_highlight_main__arg_cache
 fi
 typeset -ga ZSH_HIGHLIGHT_DIRS_BLACKLIST