kernel: Add Kconfig option to disable LTO for kernel sources

Some SoCs require kernel code to be placed in RAM, which makes
link-time optimization (LTO) unsuitable for these files.
Disabling LTO allows the affected code to be linked as separate
objects and placed in specific memory regions.

Running kernel code from RAM can improve execution performance,
especially for timing-critical routines or context switch paths.

Signed-off-by: Tim Lin <tim2.lin@ite.corp-partner.google.com>

Author: GTLin08

kernel/CMakeLists.txt

@@ -195,6 +195,11 @@ target_link_libraries(kernel zephyr_interface)
 
 endif()
 
+# Optionally build kernel sources without LTO
+if(CONFIG_KERNEL_NO_LTO)
+  include(${CMAKE_CURRENT_LIST_DIR}/kernel_no_lto.cmake)
+endif()
+
 add_dependencies(kernel zephyr_generated_headers)
 
 unset(libkernel)

kernel/Kconfig

@@ -1138,6 +1138,28 @@ endif # BOOTARGS
 
 endmenu
 
+config KERNEL_NO_LTO
+	bool "Build selected kernel core files without LTO"
+	depends on LTO
+	help
+	  Some SoCs require kernel code to be placed in RAM, which makes link-time
+	  optimization (LTO) unsuitable for these files (-fno-lto). Disabling LTO
+	  allows the affected code to be linked as separate objects and placed in
+	  specific memory regions.
+
+	  Running kernel code from RAM can improve execution performance, especially
+	  for timing-critical routines or context switch paths.
+
+if KERNEL_NO_LTO
+config KERNEL_LTO_ALLOWLIST
+	string "List of kernel source files to keep LTO"
+	help
+	  List of kernel source filenames that should retain LTO even when
+	  CONFIG_KERNEL_NO_LTO is enabled.
+	  Example: CONFIG_KERNEL_LTO_ALLOWLIST="timer.c xxx.c"
+
+endif # KERNEL_NO_LTO
+
 rsource "Kconfig.device"
 rsource "Kconfig.vm"
 rsource "Kconfig.init"

kernel/kernel_no_lto.cmake

@@ -0,0 +1,44 @@
+# SPDX-License-Identifier: Apache-2.0
+
+# Optional script to disable LTO for kernel files
+
+message(STATUS "[no-LTO] Building kernel files without LTO")
+
+# Retrieve all source files from the kernel library target
+if(TARGET kernel)
+  get_property(KERNEL_SRCS TARGET kernel PROPERTY SOURCES)
+else()
+  message(WARNING "[no-LTO] kernel target not found, skipping")
+  return()
+endif()
+
+# Split allowlist string into list
+if(DEFINED CONFIG_KERNEL_LTO_ALLOWLIST)
+  separate_arguments(LTO_ALLOWLIST NATIVE_COMMAND "${CONFIG_KERNEL_LTO_ALLOWLIST}")
+endif()
+
+# Apply -fno-lto to all C source files, except for initialization
+# and error handling modules (e.g. init.c, errno.c, fatal.c) and
+# CONFIG_KERNEL_LTO_ALLOWLIST
+foreach(src ${KERNEL_SRCS})
+  if(src MATCHES "\\.c$" AND
+     NOT src MATCHES "errno\\.c$" AND
+     NOT src MATCHES "fatal\\.c$" AND
+     NOT src MATCHES "init\\.c$")
+
+    # Skip if filename matches any in allowlist
+    set(skip FALSE)
+    foreach(allow ${LTO_ALLOWLIST})
+      get_filename_component(basename ${src} NAME)
+      if("${basename}" STREQUAL "${allow}")
+        set(skip TRUE)
+        break()
+      endif()
+    endforeach()
+
+    if(NOT skip)
+      set_source_files_properties(${src} PROPERTIES COMPILE_FLAGS "-fno-lto -g")
+    endif()
+
+  endif()
+endforeach()