Plugin architecture: Entrypoint (#292)

* Entrypoint for plugin architecture

* Add test for Entrypoint

Author: nkrishang

contracts/extension/plugin/Entrypoint.sol

@@ -0,0 +1,57 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.0;
+
+import "../interface/plugin/IMap.sol";
+import "../../extension/Multicall.sol";
+
+contract Entrypoint is Multicall {
+    /*///////////////////////////////////////////////////////////////
+                            State variables
+    //////////////////////////////////////////////////////////////*/
+
+    address public immutable functionMap;
+
+    /*///////////////////////////////////////////////////////////////
+                    Constructor + initializer logic
+    //////////////////////////////////////////////////////////////*/
+
+    constructor(address _functionMap) {
+        functionMap = _functionMap;
+    }
+
+    /*///////////////////////////////////////////////////////////////
+                        Generic contract logic
+    //////////////////////////////////////////////////////////////*/
+
+    fallback() external payable virtual {
+        address extension = IMap(functionMap).getExtensionForFunction(msg.sig);
+        _delegate(extension);
+    }
+
+    receive() external payable {}
+
+    function _delegate(address implementation) internal virtual {
+        assembly {
+            // Copy msg.data. We take full control of memory in this inline assembly
+            // block because it will not return to Solidity code. We overwrite the
+            // Solidity scratch pad at memory position 0.
+            calldatacopy(0, 0, calldatasize())
+
+            // Call the implementation.
+            // out and outsize are 0 because we don't know the size yet.
+            let result := delegatecall(gas(), implementation, 0, calldatasize(), 0, 0)
+
+            // Copy the returned data.
+            returndatacopy(0, 0, returndatasize())
+
+            switch result
+            // delegatecall returns 0 on error.
+            case 0 {
+                revert(0, returndatasize())
+            }
+            default {
+                return(0, returndatasize())
+            }
+        }
+    }
+}

docs/Entrypoint.md

@@ -0,0 +1,54 @@
+# Entrypoint
+
+
+
+
+
+
+
+
+
+## Methods
+
+### functionMap
+
+```solidity
+function functionMap() external view returns (address)
+```
+
+
+
+
+
+
+#### Returns
+
+| Name | Type | Description |
+|---|---|---|
+| _0 | address | undefined |
+
+### multicall
+
+```solidity
+function multicall(bytes[] data) external nonpayable returns (bytes[] results)
+```
+
+Receives and executes a batch of function calls on this contract.
+
+*Receives and executes a batch of function calls on this contract.*
+
+#### Parameters
+
+| Name | Type | Description |
+|---|---|---|
+| data | bytes[] | The bytes data that makes up the batch of function calls to execute. |
+
+#### Returns
+
+| Name | Type | Description |
+|---|---|---|
+| results | bytes[] | The bytes data that makes up the result of the batch of function calls executed. |
+
+
+
+

src/test/plugin/Entrypoint.t.sol

@@ -0,0 +1,52 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.0;
+
+import "contracts/extension/plugin/Map.sol";
+import "contracts/extension/plugin/Entrypoint.sol";
+import { BaseTest } from "../utils/BaseTest.sol";
+
+contract Counter {
+    uint256 private number_;
+
+    function number() external view returns (uint256) {
+        return number_;
+    }
+
+    function setNumber(uint256 _newNum) external {
+        number_ = _newNum;
+    }
+
+    function doubleNumber() external {
+        number_ *= 2;
+    }
+}
+
+contract EntrypointTest is BaseTest {
+    address entrypoint;
+
+    function setUp() public override {
+        super.setUp();
+
+        address counter = address(new Counter());
+
+        IMap.ExtensionMap[] memory extensionMaps = new IMap.ExtensionMap[](2);
+        extensionMaps[0] = IMap.ExtensionMap(Counter.number.selector, counter);
+        extensionMaps[1] = IMap.ExtensionMap(Counter.setNumber.selector, counter);
+
+        address map = address(new Map(extensionMaps));
+        entrypoint = address(new Entrypoint(map));
+    }
+
+    function test_state_callWithEntrypoint() external {
+        uint256 num = 5;
+
+        Counter(entrypoint).setNumber(num);
+
+        assertEq(Counter(entrypoint).number(), num);
+    }
+
+    function test_revert_callWithEntrypoint() external {
+        vm.expectRevert("No extension available for selector.");
+        Counter(entrypoint).doubleNumber();
+    }
+}