[DestroyAddrHoisting] Skip init_enum_data_addrs.

A destroy of an `init_enum_data_addr` is not equivalent to a destroy of
the whole enum's address.  Treat such destroys just like destroys of
`struct_element_addr`s are treated: by bailing out.

rdar://152431332

Author: nate-chandler

lib/SILOptimizer/Transforms/DestroyAddrHoisting.cpp

@@ -164,6 +164,20 @@ struct KnownStorageUses : UniqueStorageUseVisitor {
   bool visitStore(Operand *use) override { return recordUser(use->getUser()); }
 
   bool visitDestroy(Operand *use) override {
+    // An init_enum_data_addr is viewed as an "identity projection", rather than
+    // a proper projection like a struct_element_addr.  As a result, its
+    // destroys are passed directly to visitors.  But such addresses aren't
+    // quite equivalent to the original address.  Specifically, a destroy of an
+    // init_enum_data_addr cannot in general be replaced with a destroy of the
+    // whole enum.  The latter destroy is only equivalent to the former if there
+    // has been an `inject_enum_addr`.
+    //
+    // Handle a destroy of such a projection just like we handle the destroy of
+    // a struct_element_addr: by bailing out.
+    if (isa<InitEnumDataAddrInst>(
+            stripAccessAndAccessStorageCasts(use->get()))) {
+      return false;
+    }
     originalDestroys.insert(use->getUser());
     return true;
   }

test/SILOptimizer/hoist_destroy_addr.sil

@@ -1280,3 +1280,39 @@ bb0(%aggregate : $*NCAggregate):
   %retval = tuple ()
   return %retval
 }
+
+// CHECK-LABEL: sil [ossa] @nohoist_ieda : {{.*}} {
+// CHECK:         [[IEDA:%[^,]+]] = init_enum_data_addr
+// CHECK:         tuple
+// CHECK-NEXT:    destroy_addr [[IEDA]]
+// CHECK-LABEL: } // end sil function 'nohoist_ieda'
+sil [ossa] @nohoist_ieda : $@convention(thin) () -> @out TwoCases {
+bb0(%out : $*TwoCases):
+  %ieda = init_enum_data_addr %out, #TwoCases.A!enumelt
+  apply undef(%ieda) : $@convention(thin) () -> @out X
+  %retval = tuple ()
+  destroy_addr %ieda
+  apply undef(%ieda) : $@convention(thin) () -> @out X
+  inject_enum_addr %out, #TwoCases.A!enumelt
+  return %retval
+}
+
+// CHECK-LABEL: sil [ossa] @nohoist_ieda_2 : {{.*}} {
+// CHECK:         [[IEDA:%[^,]+]] = init_enum_data_addr
+// CHECK:         tuple
+// CHECK:         [[CTM:%[^,]+]] = copyable_to_moveonlywrapper_addr [[IEDA]]
+// CHECK:         [[MTC:%[^,]+]] = moveonlywrapper_to_copyable_addr [[CTM]]
+// CHECK-NEXT:    destroy_addr [[MTC]]
+// CHECK-LABEL: } // end sil function 'nohoist_ieda_2'
+sil [ossa] @nohoist_ieda_2 : $@convention(thin) () -> @out TwoCases {
+bb0(%out : $*TwoCases):
+  %ieda = init_enum_data_addr %out, #TwoCases.A!enumelt
+  apply undef(%ieda) : $@convention(thin) () -> @out X
+  %retval = tuple ()
+  %ctm = copyable_to_moveonlywrapper_addr %ieda
+  %mtc = moveonlywrapper_to_copyable_addr %ctm
+  destroy_addr %mtc
+  apply undef(%ieda) : $@convention(thin) () -> @out X
+  inject_enum_addr %out, #TwoCases.A!enumelt
+  return %retval
+}