[SILInliner] Removed lexical borrows of addrs.

In 79bc4cb, when
-enable-experimental-lexical-lifetimes was passed, all non-trivial types
were given borrow scopes.  That is incorrect because address types
should not receive borrow scopes.  Here, that is fixed by only
introducing lexical borrow scopes for arguments whose types is not an
address type.

Author: nate-chandler

lib/SILOptimizer/Utils/SILInliner.cpp

@@ -437,7 +437,8 @@ SILInlineCloner::cloneInline(ArrayRef<SILValue> AppliedArgs) {
     unsigned idx = p.index();
     if (idx >= calleeConv.getSILArgIndexOfFirstParam()) {
       if (Apply.getFunction()->hasOwnership() && enableLexicalLifetimes) {
-        if (!callArg->getType().isTrivial(*Apply.getFunction())) {
+        if (!callArg->getType().isTrivial(*Apply.getFunction()) &&
+            !callArg->getType().isAddress()) {
           SILBuilderWithScope builder(Apply.getInstruction(), getBuilder());
           if (calleeConv.getParamInfoForSILArg(idx).isGuaranteed()) {
             callArg = builder.createBeginBorrow(Apply.getLoc(), callArg,

test/SILOptimizer/inline_lifetime.sil

@@ -31,6 +31,12 @@ entry(%instance : $S):
     return %retval : $()
 }
 
+sil [ossa] [always_inline] @callee_address : $@convention(thin) (@in S) -> () {
+entry(%instance : $*S):
+    %retval = tuple ()
+    return %retval : $()
+}
+
 // tests
 
 // CHECK-LABEL: sil [ossa] @caller_owned_callee_owned : $@convention(thin) (@owned C) -> () {
@@ -111,6 +117,18 @@ entry(%instance : $S):
   return %result : $()
 }
 
+// CHECK-LABEL: sil [ossa] @caller_address_callee_address : $@convention(thin) (@in S) -> () {
+// CHECK:       {{bb[^,]+}}({{%[^,]+}} : $*S):
+// CHECK:         [[RETVAL:%[^,]+]] = tuple ()
+// CHECK:         return [[RETVAL]]
+// CHECK-LABEL: } // end sil function 'caller_address_callee_address'
+sil [ossa] @caller_address_callee_address : $@convention(thin) (@in S) -> () {
+entry(%instance : $*S):
+    %callee_address = function_ref @callee_address : $@convention(thin) (@in S) -> ()
+    %result = apply %callee_address(%instance) : $@convention(thin) (@in S) -> ()
+    return %result : $()
+}
+
 ////////////////////////////////////////////////////////////////////////////////
 // begin_apply
 ////////////////////////////////////////////////////////////////////////////////
@@ -164,6 +182,16 @@ bb2:
   unwind
 }
 
+sil hidden [ossa] [always_inline] @callee_coro_address : $@yield_once @convention(method) (@in S) -> @yields @inout S {
+bb0(%instance : $*S):
+  yield %instance : $*S, resume bb1, unwind bb2
+bb1:
+  %result = tuple ()
+  return %result : $()
+bb2:
+  unwind
+}
+
 // tests
 
 // CHECK-LABEL: sil [ossa] @caller_owned_callee_coro_owned : $@convention(method) (@owned C) -> () {
@@ -297,6 +325,23 @@ bb0(%instance : $S):
   return %retval : $()
 }
 
+// CHECK-LABEL: sil hidden [ossa] @caller_address_callee_coro_address : $@convention(method) (@in S) -> () {
+// CHECK:       {{bb[^,]+}}({{%[^,]+}} : $*S):
+// CHECK:         {{%[^,]+}} = tuple ()
+// CHECK:         [[RETVAL:%[^,]+]] = tuple ()
+// CHECK:         return [[RETVAL]]
+// CHECK:       {{bb[^,]+}}:
+// CHECK:         unreachable
+// CHECK-LABEL: } // end sil function 'caller_address_callee_coro_address'
+sil hidden [ossa] @caller_address_callee_coro_address : $@convention(method) (@in S) -> () {
+bb0(%instance : $*S):
+  %callee_coro_address = function_ref @callee_coro_address : $@yield_once @convention(method) (@in S) -> @yields @inout S
+  (%addr, %continuation) = begin_apply %callee_coro_address(%instance) : $@yield_once @convention(method) (@in S) -> @yields @inout S
+  end_apply %continuation
+  %retval = tuple ()
+  return %retval : $()
+}
+
 ////////////////////////////////////////////////////////////////////////////////
 // try_apply
 ////////////////////////////////////////////////////////////////////////////////
@@ -335,6 +380,16 @@ bb2:
   return %18 : $()
 }
 
+sil [ossa] @callee_error_address : $@convention(thin) (@in S) -> @error Error {
+bb0(%0 : $*S):
+  cond_br undef, bb1, bb2
+bb1:
+  throw undef : $Error
+bb2:
+  %18 = tuple ()
+  return %18 : $()
+}
+
 // tests
 
 // CHECK-LABEL: sil [ossa] @callee_owned_callee_error_owned : $@convention(thin) (@owned C) -> @error Error {
@@ -470,3 +525,24 @@ bb1(%9 : $()):
 bb2(%12 : @owned $Error):
   throw %12 : $Error
 }
+
+// CHECK-LABEL: sil hidden [ossa] @callee_address_callee_error_address : $@convention(thin) (@in S) -> @error Error {
+// CHECK:       {{bb[^,]+}}({{%[^,]+}} : $*S):
+// CHECK:         cond_br undef, [[THROW_BLOCK:bb[0-9]+]], [[REGULAR_BLOCK:bb[0-9]+]]
+// CHECK:       [[THROW_BLOCK]]:
+// CHECK:         throw undef
+// CHECK:       [[REGULAR_BLOCK]]:
+// CHECK:         {{%[^,]+}} = tuple ()
+// CHECK:         [[RETVAL:%[^,]+]] = tuple ()
+// CHECK:         return [[RETVAL]]
+// CHECK-LABEL: } // end sil function 'callee_address_callee_error_address'
+sil hidden [ossa] @callee_address_callee_error_address : $@convention(thin) (@in S) -> @error Error {
+bb0(%instance : $*S):
+  %callee_error_address = function_ref @callee_error_address : $@convention(thin) (@in S) -> @error Error
+  try_apply %callee_error_address(%instance) : $@convention(thin) (@in S) -> @error Error, normal bb1, error bb2
+bb1(%9 : $()):
+  %10 = tuple ()
+  return %10 : $()
+bb2(%12 : @owned $Error):
+  throw %12 : $Error
+}