SimplifyBuiltin: add constant folding of null pointer checks against string literals

A pointer to a string literal is never null

Author: eeckstein

SwiftCompilerSources/Sources/Optimizer/InstructionSimplification/SimplifyBuiltin.swift

@@ -49,6 +49,10 @@ extension BuiltinInst : OnoneSimplifyable {
         if context.options.enableEmbeddedSwift {
           optimizeArgumentToThinMetatype(argument: 1, context)
         }
+      case .ICMP_EQ:
+        constantFoldIntegerEquality(isEqual: true, context)
+      case .ICMP_NE:
+        constantFoldIntegerEquality(isEqual: false, context)
       default:
         if let literal = constantFold(context) {
           uses.replaceAll(with: literal, context)
@@ -200,6 +204,51 @@ private extension BuiltinInst {
     let newMetatype = builder.createMetatype(of: instanceType, representation: .Thin)
     operands[argument].set(to: newMetatype, context)
   }
+
+  func constantFoldIntegerEquality(isEqual: Bool, _ context: SimplifyContext) {
+    if constantFoldStringNullPointerCheck(isEqual: isEqual, context) {
+      return
+    }
+    if let literal = constantFold(context) {
+      uses.replaceAll(with: literal, context)
+    }
+  }
+
+  func constantFoldStringNullPointerCheck(isEqual: Bool, _ context: SimplifyContext) -> Bool {
+    if operands[1].value.isZeroInteger &&
+       operands[0].value.lookThroughScalarCasts is StringLiteralInst
+    {
+      let builder = Builder(before: self, context)
+      let result = builder.createIntegerLiteral(isEqual ? 0 : 1, type: type)
+      uses.replaceAll(with: result, context)
+      context.erase(instruction: self)
+      return true
+    }
+    return false
+  }
+}
+
+private extension Value {
+  var isZeroInteger: Bool {
+    if let literal = self as? IntegerLiteralInst,
+       let value = literal.value
+    {
+      return value == 0
+    }
+    return false
+  }
+
+  var lookThroughScalarCasts: Value {
+    guard let bi = self as? BuiltinInst else {
+      return self
+    }
+    switch bi.id {
+    case .ZExt, .ZExtOrBitCast, .PtrToInt:
+      return bi.operands[0].value.lookThroughScalarCasts
+    default:
+      return self
+    }
+  }
 }
 
 private func hasSideEffectForBuiltinOnce(_ instruction: Instruction) -> Bool {

test/SILOptimizer/simplify_builtin.sil

@@ -383,6 +383,74 @@ bb0:
   return %4 : $Int8
 }
 
+// CHECK-LABEL: sil @string_null_pointer_check :
+// CHECK:         %0 = integer_literal $Builtin.Int1, 0
+// CHECK-NEXT:    return %0
+// CHECK:       } // end sil function 'string_null_pointer_check'
+sil @string_null_pointer_check : $@convention(thin) () -> Builtin.Int1 {
+bb0:
+  %0 = string_literal utf8 "hello"
+  %1 = builtin "ptrtoint_Word"(%0 : $Builtin.RawPointer) : $Builtin.Word
+  %2 = builtin "zextOrBitCast_Word_Int64"(%1 : $Builtin.Word) : $Builtin.Int64
+  %3 = integer_literal $Builtin.Int64, 0
+  %4 = builtin "cmp_eq_Int64"(%2 : $Builtin.Int64, %3 : $Builtin.Int64) : $Builtin.Int1
+  return %4 : $Builtin.Int1
+}
+
+// CHECK-LABEL: sil @string_null_pointer_check_ne :
+// CHECK:         %0 = integer_literal $Builtin.Int1, -1
+// CHECK-NEXT:    return %0
+// CHECK:       } // end sil function 'string_null_pointer_check_ne'
+sil @string_null_pointer_check_ne : $@convention(thin) () -> Builtin.Int1 {
+bb0:
+  %0 = string_literal utf8 "hello"
+  %1 = builtin "ptrtoint_Word"(%0 : $Builtin.RawPointer) : $Builtin.Word
+  %2 = builtin "zextOrBitCast_Word_Int64"(%1 : $Builtin.Word) : $Builtin.Int64
+  %3 = integer_literal $Builtin.Int64, 0
+  %4 = builtin "cmp_ne_Int64"(%2 : $Builtin.Int64, %3 : $Builtin.Int64) : $Builtin.Int1
+  return %4 : $Builtin.Int1
+}
+
+// CHECK-LABEL: sil @string_null_pointer_check_no_integer_literal :
+// CHECK:         %4 = builtin "cmp_eq_Int64"(%3 : $Builtin.Int64, %0 : $Builtin.Int64)
+// CHECK-NEXT:    return %4
+// CHECK:       } // end sil function 'string_null_pointer_check_no_integer_literal'
+sil @string_null_pointer_check_no_integer_literal : $@convention(thin) (Builtin.Int64) -> Builtin.Int1 {
+bb0(%0 : $Builtin.Int64):
+  %1 = string_literal utf8 "hello"
+  %2 = builtin "ptrtoint_Word"(%1 : $Builtin.RawPointer) : $Builtin.Word
+  %3 = builtin "zextOrBitCast_Word_Int64"(%2 : $Builtin.Word) : $Builtin.Int64
+  %4 = builtin "cmp_eq_Int64"(%3 : $Builtin.Int64, %0 : $Builtin.Int64) : $Builtin.Int1
+  return %4 : $Builtin.Int1
+}
+
+// CHECK-LABEL: sil @string_null_pointer_check_not_zero :
+// CHECK:         %4 = builtin "cmp_eq_Int64"(%2 : $Builtin.Int64, %3 : $Builtin.Int64)
+// CHECK-NEXT:    return %4
+// CHECK:       } // end sil function 'string_null_pointer_check_not_zero'
+sil @string_null_pointer_check_not_zero : $@convention(thin) () -> Builtin.Int1 {
+bb0:
+  %0 = string_literal utf8 "hello"
+  %1 = builtin "ptrtoint_Word"(%0 : $Builtin.RawPointer) : $Builtin.Word
+  %2 = builtin "zextOrBitCast_Word_Int64"(%1 : $Builtin.Word) : $Builtin.Int64
+  %3 = integer_literal $Builtin.Int64, 123
+  %4 = builtin "cmp_eq_Int64"(%2 : $Builtin.Int64, %3 : $Builtin.Int64) : $Builtin.Int1
+  return %4 : $Builtin.Int1
+}
+
+// CHECK-LABEL: sil @string_null_pointer_check_no_string_literal :
+// CHECK:         %4 = builtin "cmp_eq_Int64"(%2 : $Builtin.Int64, %3 : $Builtin.Int64)
+// CHECK-NEXT:    return %4
+// CHECK:       } // end sil function 'string_null_pointer_check_no_string_literal'
+sil @string_null_pointer_check_no_string_literal : $@convention(thin) (Builtin.RawPointer) -> Builtin.Int1 {
+bb0(%0 : $Builtin.RawPointer):
+  %1 = builtin "ptrtoint_Word"(%0 : $Builtin.RawPointer) : $Builtin.Word
+  %2 = builtin "zextOrBitCast_Word_Int64"(%1 : $Builtin.Word) : $Builtin.Int64
+  %3 = integer_literal $Builtin.Int64, 0
+  %4 = builtin "cmp_eq_Int64"(%2 : $Builtin.Int64, %3 : $Builtin.Int64) : $Builtin.Int1
+  return %4 : $Builtin.Int1
+}
+
 // CHECK-LABEL: sil @convert_thick_to_thin1
 // CHECK-NOT: metatype $@thick C1<Int>.Type
 // CHECK:     [[L:%.*]] = metatype $@thin C1<Int>.Type
@@ -490,3 +558,4 @@ bb0(%0 : $Builtin.RawPointer, %1 : $Builtin.Word):
   %3 = builtin "destroyArray"<C1<Int>>(%2 : $@thick C1<Int>.Type, %0 : $Builtin.RawPointer, %1 : $Builtin.Word) : $()
   return %0 : $Builtin.RawPointer
 }
+