cmake: fix libswift build dependencies

Unfortunately using the convenient "bootstrapping0-all", etc. custom targets does not work.
For some reason it does not cause a dependent file (like libswift's SIL.o) being rebuilt when a depenency (like swift-frontend from the previous bootstrapping stage) changes.
Instead we have to list al library- and executable-targets explicitly.

Author: eeckstein

CMakeLists.txt

@@ -1089,9 +1089,6 @@ if(SWIFT_ENABLE_DISPATCH)
   include(Libdispatch)
 endif()
 
-add_bootstrapping_target(0)
-add_bootstrapping_target(1)
-
 # Add all of the subdirectories, where we actually do work.
 
 ###############

cmake/modules/SwiftUtils.cmake

@@ -111,35 +111,6 @@ function(get_bootstrapping_swift_lib_dir bs_lib_dir bootstrapping)
   set(bs_lib_dir ${bs_lib_dir} PARENT_SCOPE)
 endfunction()
 
-function(add_bootstrapping_target bootstrapping)
-  if(${LIBSWIFT_BUILD_MODE} MATCHES "BOOTSTRAPPING.*")
-
-    set(target "bootstrapping${bootstrapping}-all")
-    add_custom_target(${target})
-
-    if(${LIBSWIFT_BUILD_MODE} STREQUAL "BOOTSTRAPPING")
-      set(lib_target "bootstrapping${bootstrapping}-corelib")
-      add_custom_target(${lib_target})
-      add_dependencies(${target} ${lib_target})
-    endif()
-
-    if(SWIFT_PATH_TO_LIBICU_BUILD)
-      # Need to symlink the libicu libraries to be able to run
-      # the bootstrapping compiler with a custom library path.
-      get_bootstrapping_path(output_dir
-          "${SWIFTLIB_DIR}/${SWIFT_SDK_${SWIFT_HOST_VARIANT_SDK}_LIB_SUBDIR}" "${bootstrapping}")
-      if("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
-        message("TODO: support for copying ICU libraries on Windows")
-      endif()
-      add_custom_command(TARGET "${target}" POST_BUILD
-        COMMAND
-          "ln" "-s" "-f" "${SWIFT_PATH_TO_LIBICU_BUILD}/lib/libicu*" "."
-        WORKING_DIRECTORY "${output_dir}"
-        COMMENT "symlink ICU libraries for bootstrapping stage ${bootstrapping}")
-    endif()
-  endif()
-endfunction()
-
 function(is_build_type_optimized build_type result_var_name)
   if("${build_type}" STREQUAL "Debug")
     set("${result_var_name}" FALSE PARENT_SCOPE)

libswift/CMakeLists.txt

@@ -31,18 +31,33 @@ else()
 
   elseif(${LIBSWIFT_BUILD_MODE} MATCHES "BOOTSTRAPPING.*")
 
+    set(b0_deps swift-frontend-bootstrapping0 symlink-headers-bootstrapping0)
+    set(b1_deps swift-frontend-bootstrapping1 symlink-headers-bootstrapping1)
+    if(${LIBSWIFT_BUILD_MODE} STREQUAL "BOOTSTRAPPING")
+      set(b0_deps ${b0_deps} swiftCore-bootstrapping0)
+      set(b1_deps ${b1_deps} swiftCore-bootstrapping1)
+      if(CMAKE_BUILD_TYPE STREQUAL "Debug")
+        set(b0_deps ${b0_deps} swiftOnoneSupport-bootstrapping0)
+        set(b1_deps ${b1_deps} swiftOnoneSupport-bootstrapping1)
+      endif()
+      if(SWIFT_HOST_VARIANT_SDK IN_LIST SWIFT_DARWIN_PLATFORMS)
+        set(b0_deps ${b0_deps} swiftDarwin-bootstrapping0)
+        set(b1_deps ${b1_deps} swiftDarwin-bootstrapping1)
+      endif()
+    endif()
+
     # Bootstrapping - stage 1, using the compiler from level 0
 
     add_libswift("libswift-bootstrapping1"
       SWIFT_EXEC "${CMAKE_BINARY_DIR}/bootstrapping0/bin/swiftc"
-      DEPENDS "bootstrapping0-all"
+      DEPENDS ${b0_deps}
       BOOTSTRAPPING 1)
 
     # The final build, using the compiler from stage 1
 
     add_libswift("libswift"
         SWIFT_EXEC "${CMAKE_BINARY_DIR}/bootstrapping1/bin/swiftc"
-        DEPENDS "bootstrapping1-all")
+        DEPENDS ${b1_deps})
 
     if(LIBSWIFT_BUILD_MODE STREQUAL "BOOTSTRAPPING-WITH-HOSTLIBS")
       file(GLOB module_dirs "${CMAKE_BINARY_DIR}/bootstrapping*/lib/swift/macosx/*.swiftmodule")

stdlib/public/Platform/CMakeLists.txt

@@ -53,18 +53,22 @@ if(${LIBSWIFT_BUILD_MODE} STREQUAL "BOOTSTRAPPING" AND
       ARCHITECTURE ${SWIFT_HOST_VARIANT_ARCH}
       INSTALL_IN_COMPONENT "never_install")
 
+  set(b0_deps swiftCore-bootstrapping0)
+  set(b1_deps swiftCore-bootstrapping1)
+  if(CMAKE_BUILD_TYPE STREQUAL "Debug")
+    set(b0_deps ${b0_deps} swiftOnoneSupport-bootstrapping0)
+    set(b1_deps ${b1_deps} swiftOnoneSupport-bootstrapping1)
+  endif()
+
   add_swift_target_library_single(swiftDarwin-bootstrapping0 swiftDarwin
       ${swiftDarwin_common_bootstrapping_options}
-      FILE_DEPENDS bootstrapping0-corelib
+      FILE_DEPENDS ${b0_deps}
       BOOTSTRAPPING 0)
 
   add_swift_target_library_single(swiftDarwin-bootstrapping1 swiftDarwin
       ${swiftDarwin_common_bootstrapping_options}
-      FILE_DEPENDS bootstrapping1-corelib
+      FILE_DEPENDS ${b1_deps}
       BOOTSTRAPPING 1)
-
-  add_dependencies(bootstrapping1-all swiftDarwin-bootstrapping1)
-  add_dependencies(bootstrapping0-all swiftDarwin-bootstrapping0)
 endif()
 
 add_swift_target_library(swiftDarwin ${SWIFT_STDLIB_LIBRARY_BUILD_TYPES}

stdlib/public/SwiftOnoneSupport/CMakeLists.txt

@@ -27,17 +27,13 @@ if(CMAKE_BUILD_TYPE STREQUAL "Debug" AND ${LIBSWIFT_BUILD_MODE} STREQUAL "BOOTST
     FILE_DEPENDS swiftCore-bootstrapping0
     BOOTSTRAPPING 0)
 
-  add_dependencies(bootstrapping0-corelib swiftSwiftOnoneSupport-bootstrapping0)
-
   # Bootstrapping - stage 1
 
   add_swift_target_library_single(swiftSwiftOnoneSupport-bootstrapping1 swiftSwiftOnoneSupport
     ${swiftOnoneSupport_common_bootstrapping_options}
     FILE_DEPENDS swiftCore-bootstrapping1
     BOOTSTRAPPING 1)
 
-  add_dependencies(bootstrapping1-corelib swiftSwiftOnoneSupport-bootstrapping1)
-
 endif()
 
 add_swift_target_library(swiftSwiftOnoneSupport

stdlib/public/SwiftShims/CMakeLists.txt

@@ -177,7 +177,6 @@ if(${LIBSWIFT_BUILD_MODE} MATCHES "BOOTSTRAPPING.*")
         COMMENT "Symlinking headers for bootstrapping0")
 
     add_dependencies(${target_name} copy_shim_headers)
-    add_dependencies(bootstrapping${bootstrapping}-all ${target_name})
   endforeach()
 endif()
 

stdlib/public/core/CMakeLists.txt

@@ -340,6 +340,32 @@ set(swiftCore_common_dependencies
 
 if(${LIBSWIFT_BUILD_MODE} STREQUAL "BOOTSTRAPPING")
 
+  set(b0_deps symlink-headers-bootstrapping0)
+  set(b1_deps symlink-headers-bootstrapping1)
+
+  if(SWIFT_PATH_TO_LIBICU_BUILD)
+    foreach(bootstrapping "0" "1")
+      # Need to symlink the libicu libraries to be able to run
+      # the bootstrapping compiler with a custom library path.
+      get_bootstrapping_path(output_dir
+          "${SWIFTLIB_DIR}/${SWIFT_SDK_${SWIFT_HOST_VARIANT_SDK}_LIB_SUBDIR}" "${bootstrapping}")
+      if("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
+        message("TODO: support for copying ICU libraries on Windows")
+      endif()
+      set(target "symlink-icu-bootstrapping${bootstrapping}")
+      add_custom_target(${target})
+      add_custom_command(TARGET ${target} POST_BUILD
+       COMMAND
+          "${CMAKE_COMMAND}" "-E" "make_directory" "${output_dir}"
+        COMMAND
+          "ln" "-s" "-f" "${SWIFT_PATH_TO_LIBICU_BUILD}/lib/libicu*" "."
+        WORKING_DIRECTORY "${output_dir}"
+        COMMENT "symlink ICU libraries for bootstrapping stage ${bootstrapping}")
+    endforeach()
+    set(b0_deps ${b0_deps} symlink-icu-bootstrapping0)
+    set(b1_deps ${b1_deps} symlink-icu-bootstrapping1)
+  endif()
+
   list(FIND SWIFT_STDLIB_LIBRARY_BUILD_TYPES "SHARED" index_of_shared)
   if(index_of_shared EQUAL -1)
     message(FATAL_ERROR "bootstrapping requires SHARED stdlib build type")
@@ -358,19 +384,16 @@ if(${LIBSWIFT_BUILD_MODE} STREQUAL "BOOTSTRAPPING")
   add_swift_target_library_single(swiftCore-bootstrapping0 swiftCore
                     ${swiftCore_common_bootstrapping_options}
                     FILE_DEPENDS
-                      symlink-headers-bootstrapping0 ${swiftCore_common_dependencies}
+                      ${b0_deps} ${swiftCore_common_dependencies}
                     BOOTSTRAPPING 0)
 
   # Bootstrapping - stage 1
 
   add_swift_target_library_single(swiftCore-bootstrapping1 swiftCore
                     ${swiftCore_common_bootstrapping_options}
                     FILE_DEPENDS
-                      symlink-headers-bootstrapping1 ${swiftCore_common_dependencies}
+                      ${b1_deps} ${swiftCore_common_dependencies}
                     BOOTSTRAPPING 1)
-
-  add_dependencies(bootstrapping1-corelib swiftCore-bootstrapping1)
-  add_dependencies(bootstrapping0-corelib swiftCore-bootstrapping0)
 endif()
 
 add_swift_target_library(swiftCore

tools/driver/CMakeLists.txt

@@ -38,9 +38,6 @@ if(${LIBSWIFT_BUILD_MODE} MATCHES "BOOTSTRAPPING.*")
     SOURCE "swift-frontend${CMAKE_EXECUTABLE_SUFFIX}"
     DESTINATION "swiftc${CMAKE_EXECUTABLE_SUFFIX}"
     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}/bootstrapping1/bin")
-
-  add_dependencies(bootstrapping0-all swift-frontend-bootstrapping0)
-  add_dependencies(bootstrapping1-all swift-frontend-bootstrapping1)
 endif()
 
 add_swift_host_tool(swift-frontend