Initial CMake Build

Adding an initial CMake build for the Swift-subprocess library.
At this time, it will build its own swift-system library, although we
should allow it to search for one if one is available.

CMake does not automatically generate modulemaps like SwiftPM does. As a
result, we need to add one for Swift to import the C shims.

There is one library target emitted from this build, Subprocess.

Author: etcwilde

CMakeLists.txt

@@ -0,0 +1,9 @@
+cmake_minimum_required(VERSION 3.29)
+project(Subprocess LANGUAGES C Swift)
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
+
+add_compile_options("$<$<COMPILE_LANGUAGE:Swift>:SHELL:-package-name ${PROJECT_NAME}>")
+
+include(InstallExternalDependencies)
+
+add_subdirectory(Sources)

Sources/CMakeLists.txt

@@ -0,0 +1,12 @@
+add_library(Subprocess)
+
+add_subdirectory(_SubprocessCShims)
+add_subdirectory(Subprocess)
+
+target_compile_options(Subprocess PRIVATE
+  "$<$<COMPILE_LANGUAGE:Swift>:SHELL:-enable-experimental-feature StrictConcurrency>"
+  "$<$<COMPILE_LANGUAGE:Swift>:SHELL:-enable-experimental-feature NonescapableTyeps>"
+  "$<$<COMPILE_LANGUAGE:Swift>:SHELL:-enable-experimental-feature LifetimeDependence>"
+  "$<$<COMPILE_LANGUAGE:Swift>:SHELL:-enable-experimental-feature Span>")
+
+target_link_libraries(Subprocess PRIVATE SystemPackage)

Sources/Subprocess/CMakeLists.txt

@@ -0,0 +1,27 @@
+target_sources(Subprocess PRIVATE
+  Execution.swift
+  Buffer.swift
+  Error.swift
+  Teardown.swift
+  Result.swift
+  IO/Output.swift
+  IO/Input.swift
+  Span+Subprocess.swift
+  AsyncBufferSequence.swift
+  API.swift
+  SubprocessFoundation/Span+SubprocessFoundation.swift
+  SubprocessFoundation/Output+Foundation.swift
+  SubprocessFoundation/Input+Foundation.swift
+  Configuration.swift)
+
+if(WIN32)
+  target_sources(Subprocess PRIVATE Platforms/Subprocess+Windows.swift)
+elseif(LINUX OR ANDROID)
+  target_sources(Subprocess PRIVATE
+    Platforms/Subprocess+Linux.swift
+    Platforms/Subprocess+Unix.swift)
+elseif(APPLE)
+  target_sources(Subprocess PRIVATE
+    Platforms/Subprocess+Darwin.swift
+    Platforms/Subprocess+Unix.swift)
+endif()

Sources/_SubprocessCShims/CMakeLists.txt

@@ -0,0 +1,4 @@
+target_sources(Subprocess PRIVATE process_shims.c)
+
+target_include_directories(Subprocess PRIVATE
+  "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>")

Sources/_SubprocessCShims/include/module.modulemap

@@ -0,0 +1,4 @@
+module _SubprocessCShims {
+  header "process_shims.h"
+  header "target_conditionals.h"
+}

cmake/modules/InstallExternalDependencies.cmake

@@ -0,0 +1,16 @@
+include_guard()
+
+# TODO: Use find_package to find a pre-built SwiftSystem
+
+include(FetchContent)
+
+FetchContent_Declare(SwiftSystem
+  GIT_REPOSITORY https://github.com/apple/swift-system.git
+  GIT_TAG a34201439c74b53f0fd71ef11741af7e7caf01e1 # 1.4.2
+  GIT_SHALLOW YES)
+list(APPEND dependencies SwiftSystem)
+
+
+if(dependencies)
+  FetchContent_MakeAvailable(${dependencies})
+endif()