Add :prefer-handler? to wrap-resource options

Author: weavejester

ring-core/src/ring/middleware/resource.clj

@@ -17,6 +17,31 @@
        (-> (response/resource-response path (assoc options :root root-path))
            (head/head-response request))))))
 
+(defn- wrap-resource-prefer-resources [handler root-path options]
+  (fn
+    ([request]
+     (or (resource-request request root-path options)
+         (handler request)))
+    ([request respond raise]
+     (if-let [response (resource-request request root-path options)]
+       (respond response)
+       (handler request respond raise)))))
+
+(defn- wrap-resource-prefer-handler [handler root-path options]
+  (fn
+    ([request]
+     (let [response (handler request)]
+       (if (= 404 (:status response))
+         (resource-request request root-path options)
+         response)))
+    ([request respond raise]
+     (handler request
+              (fn [response]
+                (if (= 404 (:status response))
+                  (respond (resource-request request root-path options))
+                  (respond response)))
+              raise))))
+
 (defn wrap-resource
   "Middleware that first checks to see whether the request map matches a static
   resource. If it does, the resource is returned in a response map, otherwise
@@ -27,15 +52,12 @@
 
   :loader          - resolve the resource using this class loader
   :allow-symlinks? - allow symlinks that lead to paths outside the root
-                     classpath directories (defaults to false)"
+                     classpath directories (defaults to false)
+  :prefer-handler? - prioritize handler response over resources (defaults to
+                     false)"
   ([handler root-path]
    (wrap-resource handler root-path {}))
   ([handler root-path options]
-   (fn
-     ([request]
-      (or (resource-request request root-path options)
-          (handler request)))
-     ([request respond raise]
-      (if-let [response (resource-request request root-path options)]
-        (respond response)
-        (handler request respond raise))))))
+   (if (:prefer-handler? options)
+     (wrap-resource-prefer-handler   handler root-path options)
+     (wrap-resource-prefer-resources handler root-path options))))

ring-core/test/ring/middleware/test/resource.clj

@@ -79,3 +79,42 @@
           response (resource-request request "/ring/assets")]
       (is (= (:status response) 200))
       (is (nil? (:body response))))))
+
+(defn- prefer-foo-handler
+  ([request]
+   (if (= (:uri request) "/foo.html")
+     {:status 200, :headers {}, :body "override"}
+     {:status 404, :headers {}, :body "not found"}))
+  ([request respond raise]
+   (respond (prefer-foo-handler request))))
+
+(deftest test-wrap-resource-with-prefer-handler
+  (let [handler (wrap-resource prefer-foo-handler
+                               "/ring/assets"
+                               {:prefer-handler? true})]
+
+    (testing "middleware serves resource (synchronously)"
+      (let [response (handler {:request-method :get, :uri "/index.html"})]
+        (is (= 200 (:status response)))
+        (is (= "index" (slurp (:body response))))))
+
+    (testing "middleware serves resource (asynchronously)"
+      (let [response (promise)
+            error    (promise)]
+        (handler {:request-method :get, :uri "/index.html"} response error)
+        (is (= 200 (:status @response)))
+        (is (= "index" (slurp (:body @response))))
+        (is (not (realized? error)))))
+
+    (testing "handler serves resource (synchronously)"
+      (let [response (handler {:request-method :get, :uri "/foo.html"})]
+        (is (= 200 (:status response)))
+        (is (= "override" (:body response)))))
+
+    (testing "handler serves resource (asynchronously)"
+      (let [response (promise)
+            error    (promise)]
+        (handler {:request-method :get, :uri "/foo.html"} response error)
+        (is (= 200 (:status @response)))
+        (is (= "override" (:body @response)))
+        (is (not (realized? error)))))))