Add "version-redirect.rkt" script for pruning global redirects

It's convenient for a release to just redirect all
`releases/<vers>/installers` requests at `download.racket-lang.org` to
`mirror.racket-lang.org`, but we can only link up to 50 versions that
way through a bucket redirect rule. For old versions, make an
indivudual bucket object for each redirection that should work (and
there are a small number, because it's roughlyone per installer).

For now, versions before v7.0 have been changed in this way, which
buys us another 4 years or so before we run out of redirections again.
Assuming no problems are desovered in the next year or so, we can turn
it up to before v9.0, which will put off the problem for a decae or
so. And we can keep turning up the version this way indefinitely in
the future.

Author: mflatt

sync.rkt

@@ -76,6 +76,7 @@
                #:jobs jobs
                #:log displayln))
 
+#;
 (unless render-locally?
   (upload "www" "racket-lang.org")
   (upload "www" "www.racket-lang.org")
@@ -113,7 +114,10 @@
                                  #:redirect-code "302"
                                  #:new-protocol 'https)
    (for/list ([r (in-list all-releases)]
-              #:when (version<=? "5.92" (release-version r)))
+              ;; when we run out of redirects (max is 50), this version number
+              ;; will need to be increased by running the "version-redirect.rkt"
+              ;; script
+              #:when (version<=? "7.0" (release-version r)))
      (redirect-prefix-routing-rule #:old-prefix (format "releases/~a/installers" (release-version r))
                                    #:new-prefix (format "~ainstallers/~a"
                                                         download-mirror-path

version-redirect.rkt

@@ -0,0 +1,70 @@
+#lang racket/base
+
+;; How to use this script:
+;;
+;;  * Add new versions to "version-redirect.txt".
+;;    The original context of that file was created by
+;;    looking at a mirror of "mirror.racket-lang.org",
+;;    which was made with
+;;
+;;      wget --no-check-certificate -nv -m -X "/docs" --reject-regex ".*[?].*" \
+;;            https://mirror.racket-lang.org/installers/
+;;
+;;    and running `find .` to get the list, and then pruning
+;;    some garbage.
+;;
+;;  * Adjust the `redirect-before-version` definition below.
+;;
+;; The script will create new redirection objects, but it does not
+;; remove bucket-wide redirection rules that are meant to be covered
+;; by the added objects, so remove those manually via the S3 console.
+
+(define redirect-before-version "7.0")
+
+(define bucket "download.racket-lang.org")
+(define target "mirror.racket-lang.org")
+
+(define bucket-pattern "releases/~a/installers")
+(define target-pattern "installers/~a")
+
+(require version/utils
+         racket/runtime-path
+         aws/keys
+         aws/s3)
+
+(define-runtime-path version-redirect.txt "version-redirect.txt")
+
+(define version+paths
+  (call-with-input-file*
+   version-redirect.txt
+   (lambda (i)
+     (for/list ([line (in-lines i)]
+                #:do [(unless (regexp-match? #rx"^[.]/" line)
+                        (error 'redirect "bad line in \"version-redirect.txt\": ~s" line))
+                      (define elems (explode-path line))
+                      (define vers (path->string (cadr elems)))]
+                #:when (version<? vers redirect-before-version)
+                #:unless (equal? line (string-append "./" vers)))
+       (list vers (substring line (+ 3 (string-length vers))))))))
+
+version+paths
+
+(with-handlers ([exn:fail? (lambda _ (ensure-have-keys))])
+  (credentials-from-environment!))
+
+(s3-host "s3.amazonaws.com")
+
+(s3-region (bucket-location bucket))
+
+(for ([version+path (in-list version+paths)])
+  (define vers (car version+path))
+  (define path (cadr version+path))
+  (define redirect-to (format "https://~a/~a/~a" target (format target-pattern vers) path))
+  (define bucket+path (format "~a/~a/~a" bucket (format bucket-pattern vers) path))
+  (define data #"")
+  (define mime-type "application/octet-stream")
+  (define heads (hash 'x-amz-website-redirect-location redirect-to
+                      'x-amz-storage-class "REDUCED_REDUNDANCY"
+                      'x-amz-acl "public-read"))
+  (printf "linking ~a to ~a\n" bucket+path redirect-to)
+  (put/bytes bucket+path data mime-type heads))