fix an annoying interaction in the way drracket initializes the REPL

Specifically, when the file being opened starts with #lang (and "The
Racket Language" is selected), use the language that's listed in the
file to initialize the REPL instead of the language of the last-edited

Author: rfindler

drracket/drracket/private/rep.rkt

@@ -1843,7 +1843,9 @@ TODO
            (define name (send definitions-text get-port-name))
            (define settings
              (drracket:language-configuration:language-settings-settings user-language-settings))
-           (define prog-port (open-input-string (send lang get-auto-text settings) name))
+           (define hash-lang-str (or (fetch-hash-lang-str definitions-text)
+                                     (send lang get-auto-text settings)))
+           (define prog-port (open-input-string hash-lang-str name))
            (port-count-lines! prog-port)
            (parameterize ([module-language-initial-run #t])
              (evaluate-from-port
@@ -2416,3 +2418,70 @@ TODO
                   (make-object string-snip% "c"))])
     (check-equal? (simplify-history-element in #t)
                   (old-conversion-code in))))
+
+(define (fetch-hash-lang-str text)
+  (define special-tp (open-input-text-editor text))
+  (define (special-filter f bytes)
+    ;; @ is not accepted anywhere in the regexp below
+    (bytes-set! bytes 0 (char->integer #\@))
+    1)
+  (define tp (special-filter-input-port special-tp special-filter))
+  (port-count-lines! tp)
+  (skip-past-comments tp)
+  (define-values (_1 _2 pos-before) (port-next-location tp))
+  (cond
+    [(regexp-match? #rx"^#lang [a-zA-Z0-9+_/-]+" tp)
+     (define c (peek-char tp))
+     (cond
+       [(eof-object? c)
+        (define-values (line col pos-after) (port-next-location tp))
+        (send text get-text (- pos-before 1) pos-after)]
+       [(char-whitespace? c)
+        (define-values (line col pos-after) (port-next-location tp))
+        (send text get-text (- pos-before 1) (- pos-after 1))]
+       [else #f])]
+    [else #f]))
+
+(module+ test
+  (check-equal? (let ([t (new text%)])
+                  (send t insert "blah")
+                  (fetch-hash-lang-str t))
+                #f)
+  (check-equal? (let ([t (new text%)])
+                  (send t insert "#lang racket")
+                  (fetch-hash-lang-str t))
+                "#lang racket")
+  (check-equal? (let ([t (new text%)])
+                  (send t insert " #lang racket")
+                  (fetch-hash-lang-str t))
+                "#lang racket")
+  (check-equal? (let ([t (new text%)])
+                  (send t insert "#lang racket ")
+                  (fetch-hash-lang-str t))
+                "#lang racket")
+  (check-equal? (let ([t (new text%)])
+                  (send t insert "#lang racket\n")
+                  (fetch-hash-lang-str t))
+                "#lang racket")
+  (check-equal? (let ([t (new text%)])
+                  (send t insert "#lang racket fjd ej ej")
+                  (fetch-hash-lang-str t))
+                "#lang racket")
+  (check-equal? (let ([t (new text%)])
+                  (send t insert ";; a\n#lang racket fjd ej ej")
+                  (fetch-hash-lang-str t))
+                "#lang racket")
+  (check-equal? (let ([t (new text%)])
+                  (send t insert ";; a")
+                  (define es (new editor-snip%))
+                  (send t insert es)
+                  (send t insert "\n#lang racket")
+                  (fetch-hash-lang-str t))
+                "#lang racket")
+  (check-equal? (let ([t (new text%)])
+                  (send t insert "#lang rac")
+                  (define es (new editor-snip%))
+                  (send t insert es)
+                  (send t insert "ket\n")
+                  (fetch-hash-lang-str t))
+                #f))