Use CMake 4.2+ set(CACHE{<var>}) unset(CACHE{<var>}) signatures

Author: petk

CMakeLists.txt

@@ -78,8 +78,10 @@ project(
 # Configuration.
 block(PROPAGATE phpUrl)
   set(
-    PHP_VERSION_DOWNLOAD "${PROJECT_VERSION}-dev"
-    CACHE STRING "The PHP version to download"
+    CACHE{PHP_VERSION_DOWNLOAD}
+    TYPE STRING
+    HELP "The PHP version to download"
+    VALUE "${PROJECT_VERSION}-dev"
   )
   mark_as_advanced(PHP_VERSION_DOWNLOAD)
 

cmake/Zend/CMakeLists.txt

@@ -85,10 +85,10 @@ mark_as_advanced(PHP_ZEND_GLOBAL_REGISTER_VARIABLES)
 
 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Windows")
   set(
-    PHP_ZEND_MAX_EXECUTION_TIMERS
-    "auto"
-    CACHE STRING
-    "Enable Zend max execution timers"
+    CACHE{PHP_ZEND_MAX_EXECUTION_TIMERS}
+    TYPE STRING
+    HELP "Enable Zend max execution timers"
+    VALUE "auto"
   )
   mark_as_advanced(PHP_ZEND_MAX_EXECUTION_TIMERS)
   set_property(

cmake/Zend/cmake/CheckDlsym.cmake

@@ -122,10 +122,10 @@ block()
 endblock()
 
 set(
-  PHP_ZEND_DLSYM_NEEDS_UNDERSCORE
-  ""
-  CACHE INTERNAL
-  "Whether 'dlsym()' requires a leading underscore in symbol names."
+  CACHE{PHP_ZEND_DLSYM_NEEDS_UNDERSCORE}
+  TYPE INTERNAL
+  HELP "Whether 'dlsym()' requires a leading underscore in symbol names."
+  VALUE ""
 )
 
 if(

cmake/cmake/Configuration.cmake

@@ -16,65 +16,97 @@ include_guard(GLOBAL)
 include(CMakeDependentOption)
 include(FeatureSummary)
 
-set(PHP_UNAME "" CACHE STRING "Build system uname")
-mark_as_advanced(PHP_UNAME)
-
-if(CMAKE_UNAME AND NOT PHP_UNAME)
-  execute_process(
-    COMMAND ${CMAKE_UNAME} -a
-    OUTPUT_VARIABLE PHP_UNAME
-    OUTPUT_STRIP_TRAILING_WHITESPACE
-    ERROR_QUIET
+block()
+  set(CACHE{PHP_UNAME} TYPE STRING HELP "Build system uname" VALUE "")
+  mark_as_advanced(PHP_UNAME)
+
+  find_program(
+    PHP_UNAME_EXECUTABLE
+    NAMES uname
+    DOC "Path to the uname command-line executable"
   )
-elseif(NOT PHP_UNAME AND CMAKE_HOST_SYSTEM)
-  set_property(CACHE PHP_UNAME PROPERTY VALUE "${CMAKE_HOST_SYSTEM}")
-endif()
+  mark_as_advanced(PHP_UNAME_EXECUTABLE)
+
+  if(NOT PHP_UNAME AND PHP_UNAME_EXECUTABLE)
+    execute_process(
+      COMMAND ${PHP_UNAME_EXECUTABLE} -a
+      OUTPUT_VARIABLE output
+      OUTPUT_STRIP_TRAILING_WHITESPACE
+      ERROR_QUIET
+    )
+    set_property(CACHE PHP_UNAME PROPERTY VALUE "${output}")
+  elseif(NOT PHP_UNAME AND CMAKE_HOST_SYSTEM)
+    set_property(CACHE PHP_UNAME PROPERTY VALUE "${CMAKE_HOST_SYSTEM}")
+  endif()
+endblock()
 
-set(PHP_BUILD_SYSTEM "${PHP_UNAME}" CACHE STRING "Build system uname")
+set(
+  CACHE{PHP_BUILD_SYSTEM}
+  TYPE STRING
+  HELP "Build system uname"
+  VALUE "${PHP_UNAME}"
+)
 mark_as_advanced(PHP_BUILD_SYSTEM)
 
 set(
-  PHP_BUILD_ARCH "${CMAKE_C_COMPILER_ARCHITECTURE_ID}"
-  CACHE STRING "Build target architecture displayed in phpinfo"
+  CACHE{PHP_BUILD_ARCH}
+  TYPE STRING
+  HELP "Build target architecture displayed in phpinfo"
+  VALUE "${CMAKE_C_COMPILER_ARCHITECTURE_ID}"
 )
 mark_as_advanced(PHP_BUILD_ARCH)
 
 set(
-  PHP_BUILD_COMPILER "${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION}"
-  CACHE STRING "Compiler used for build displayed in phpinfo"
+  CACHE{PHP_BUILD_COMPILER}
+  TYPE STRING
+  HELP "Compiler used for build displayed in phpinfo"
+  VALUE "${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION}"
 )
 mark_as_advanced(PHP_BUILD_COMPILER)
 
-set(PHP_BUILD_PROVIDER "" CACHE STRING "Build provider displayed in phpinfo")
+set(
+  CACHE{PHP_BUILD_PROVIDER}
+  TYPE STRING
+  HELP "Build provider displayed in phpinfo"
+  VALUE ""
+)
 mark_as_advanced(PHP_BUILD_PROVIDER)
 
 set(
-  PHP_INCLUDE_PREFIX "php"
-  CACHE STRING
-  "The relative directory inside the CMAKE_INSTALL_INCLUDEDIR, where to install\
-  PHP headers. For example, 'php/${PHP_VERSION}' to specify version or other\
-  build-related characteristics and have multiple PHP versions installed.\
-  Absolute paths are treated as relative; set CMAKE_INSTALL_INCLUDEDIR if\
-  absolute path needs to be set."
+  CACHE{PHP_INCLUDE_PREFIX}
+  TYPE STRING
+  HELP
+    "The relative directory inside the CMAKE_INSTALL_INCLUDEDIR, where to "
+    "install PHP headers. For example, 'php/${PHP_VERSION}' to specify version "
+    "or other build-related characteristics and have multiple PHP versions "
+    "installed. Absolute paths are treated as relative; set "
+    "CMAKE_INSTALL_INCLUDEDIR if absolute path needs to be set."
+  VALUE "php"
 )
 mark_as_advanced(PHP_INCLUDE_PREFIX)
 
 set(
-  PHP_CONFIG_FILE_SCAN_DIR ""
-  CACHE PATH "The path where to scan for additional INI configuration files; By\
-  default it is empty value; Pass it as a relative path inside the install\
-  prefix, which will be automatically prepended; If given as an absolute path,\
-  install prefix is not prepended."
+  CACHE{PHP_CONFIG_FILE_SCAN_DIR}
+  TYPE PATH
+  HELP
+    "The path where to scan for additional INI configuration files; By default "
+    "it is empty value; Pass it as a relative path inside the install prefix, "
+    "which will be automatically prepended; If given as an absolute path, "
+    "install prefix is not prepended."
+  VALUE ""
 )
 mark_as_advanced(PHP_CONFIG_FILE_SCAN_DIR)
 
 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Windows")
   set(
-    PHP_CONFIG_FILE_PATH ""
-    CACHE FILEPATH "The path in which to look for php.ini; By default, it is\
-    set to SYSCONFDIR (etc); Relative path gets the CMAKE_INSTALL_PREFIX\
-    automatically prepended; If given as an absolute path, install prefix is\
-    not appended."
+    CACHE{PHP_CONFIG_FILE_PATH}
+    TYPE FILEPATH
+    HELP
+      "The path in which to look for php.ini; By default, it is set to "
+      "SYSCONFDIR (etc); Relative path gets the CMAKE_INSTALL_PREFIX "
+      "automatically prepended; If given as an absolute path, install prefix "
+      "is not appended."
+    VALUE ""
   )
   mark_as_advanced(PHP_CONFIG_FILE_PATH)
   if(NOT PHP_CONFIG_FILE_PATH)
@@ -86,10 +118,20 @@ if(NOT CMAKE_SYSTEM_NAME STREQUAL "Windows")
   endif()
 endif()
 
-set(PHP_PROGRAM_PREFIX "" CACHE STRING "Prepend prefix to the program names")
+set(
+  CACHE{PHP_PROGRAM_PREFIX}
+  TYPE STRING
+  HELP "Prepend prefix to the program names"
+  VALUE ""
+)
 mark_as_advanced(PHP_PROGRAM_PREFIX)
 
-set(PHP_PROGRAM_SUFFIX "" CACHE STRING "Append suffix to the program names")
+set(
+  CACHE{PHP_PROGRAM_SUFFIX}
+  TYPE STRING
+  HELP "Append suffix to the program names"
+  VALUE ""
+)
 mark_as_advanced(PHP_PROGRAM_SUFFIX)
 
 option(PHP_THREAD_SAFETY "Enable thread safety (ZTS)")
@@ -130,13 +172,18 @@ mark_as_advanced(PHP_DMALLOC)
 option(PHP_DTRACE "Enable DTrace support")
 mark_as_advanced(PHP_DTRACE)
 
-set(PHP_FD_SETSIZE "" CACHE STRING "Size of file descriptor sets")
+set(
+  CACHE{PHP_FD_SETSIZE}
+  TYPE STRING
+  HELP "Size of file descriptor sets"
+  VALUE ""
+)
+mark_as_advanced(PHP_FD_SETSIZE)
 if(CMAKE_SYSTEM_NAME STREQUAL "Windows" AND PHP_FD_SETSIZE STREQUAL "")
   # This allows up to 256 sockets to be select()ed in a single call to select(),
   # instead of the usual 64.
   set_property(CACHE PHP_FD_SETSIZE PROPERTY VALUE "256")
 endif()
-mark_as_advanced(PHP_FD_SETSIZE)
 
 option(PHP_VALGRIND "Enable the Valgrind support")
 mark_as_advanced(PHP_VALGRIND)
@@ -167,30 +214,30 @@ mark_as_advanced(PHP_CCACHE)
 ################################################################################
 
 set(
-  PHP_EXTENSION_DIR ""
-  CACHE PATH
-  "Default directory for dynamically loadable PHP extensions. If left empty, it\
-  is determined automatically. Can be overridden using the PHP 'extension_dir'\
-  INI directive."
+  CACHE{PHP_EXTENSION_DIR}
+  TYPE PATH
+  HELP
+    "Default directory for dynamically loadable PHP extensions. If left empty, "
+    "it is determined automatically. Can be overridden using the PHP "
+    "'extension_dir' INI directive."
+  VALUE ""
 )
 mark_as_advanced(PHP_EXTENSION_DIR)
 
 # Assemble the PHP_EXTENSION_DIR default value.
-block()
-  if(NOT PHP_EXTENSION_DIR)
-    set(
-      extensionDir
-      "${CMAKE_INSTALL_LIBDIR}/php/$<TARGET_PROPERTY:Zend::Zend,ZEND_MODULE_API_NO>$<$<BOOL:$<TARGET_PROPERTY:PHP::config,PHP_THREAD_SAFETY>>:-zts>$<$<BOOL:$<CONFIG>>:-$<CONFIG>>"
-    )
-
-    # This would resemble the PHP Autotools --with-layout=GNU:
-    #set(extensionDir "${CMAKE_INSTALL_LIBDIR}/php/$<TARGET_PROPERTY:Zend::Zend,ZEND_MODULE_API_NO>$<$<BOOL:$<TARGET_PROPERTY:PHP::config,PHP_THREAD_SAFETY>>:-zts>$<$<CONFIG:Debug,DebugAssertions>:-debug>")
-    # This would resemble the PHP Autotools --with-layout=PHP (default):
-    #set(extensionDir "${CMAKE_INSTALL_LIBDIR}/php/extensions/$<IF:$<CONFIG:Debug,DebugAssertions>,debug,no-debug>$<IF:$<BOOL:$<TARGET_PROPERTY:PHP::config,PHP_THREAD_SAFETY>>,-zts,-non-zts>-$<TARGET_PROPERTY:Zend::Zend,ZEND_MODULE_API_NO>")
+if(NOT PHP_EXTENSION_DIR)
+  set_property(
+    CACHE PHP_EXTENSION_DIR
+    PROPERTY
+      VALUE
+        "${CMAKE_INSTALL_LIBDIR}/php/$<TARGET_PROPERTY:Zend::Zend,ZEND_MODULE_API_NO>$<$<BOOL:$<TARGET_PROPERTY:PHP::config,PHP_THREAD_SAFETY>>:-zts>$<$<BOOL:$<CONFIG>>:-$<CONFIG>>"
+  )
 
-    set_property(CACHE PHP_EXTENSION_DIR PROPERTY VALUE "${extensionDir}")
-  endif()
-endblock()
+  # This would resemble the PHP Autotools --with-layout=GNU:
+  #set(extension_dir "${CMAKE_INSTALL_LIBDIR}/php/$<TARGET_PROPERTY:Zend::Zend,ZEND_MODULE_API_NO>$<$<BOOL:$<TARGET_PROPERTY:PHP::config,PHP_THREAD_SAFETY>>:-zts>$<$<CONFIG:Debug,DebugAssertions>:-debug>")
+  # This would resemble the PHP Autotools --with-layout=PHP (default):
+  #set(extension_dir "${CMAKE_INSTALL_LIBDIR}/php/extensions/$<IF:$<CONFIG:Debug,DebugAssertions>,debug,no-debug>$<IF:$<BOOL:$<TARGET_PROPERTY:PHP::config,PHP_THREAD_SAFETY>>,-zts,-non-zts>-$<TARGET_PROPERTY:Zend::Zend,ZEND_MODULE_API_NO>")
+endif()
 
 ################################################################################
 # Various global internal configuration.

cmake/cmake/ConfigureChecks.cmake

@@ -396,7 +396,7 @@ set(HAVE_EXPLICIT_MEMSET ${PHP_HAVE_EXPLICIT_MEMSET})
 check_symbol_exists(fdatasync unistd.h PHP_HAVE_FDATASYNC)
 # The fdatasync declaration on macOS is missing in headers, yet is in C library.
 if(NOT PHP_HAVE_FDATASYNC)
-  unset(PHP_HAVE_FDATASYNC CACHE)
+  unset(CACHE{PHP_HAVE_FDATASYNC})
   check_function_exists(fdatasync PHP_HAVE_FDATASYNC)
 endif()
 set(HAVE_FDATASYNC ${PHP_HAVE_FDATASYNC})

cmake/cmake/Extensions.cmake

@@ -96,11 +96,11 @@ function(php_extensions_preprocess)
         )
 
         set(
-          PHP_EXT_${extensionUpper}_SHARED
-          ON
-          CACHE BOOL
-          "Build the ${extension} extension as a shared library"
+          CACHE{PHP_EXT_${extensionUpper}_SHARED}
+          TYPE BOOL
+          HELP "Build the ${extension} extension as a shared library"
           FORCE
+          VALUE ON
         )
 
         break()
@@ -393,11 +393,11 @@ function(php_extensions_postconfigure extension)
       set_property(CACHE PHP_EXT_${dependencyUpper} PROPERTY VALUE ON)
     else()
       set(
-        PHP_EXT_${dependencyUpper}
-        ON
-        CACHE BOOL
-        "Enable the ${dependency} extension"
+        CACHE{PHP_EXT_${dependencyUpper}}
+        TYPE BOOL
+        HELP "Enable the ${dependency} extension"
         FORCE
+        VALUE ON
       )
     endif()
   endforeach()

cmake/cmake/Version.cmake

@@ -18,8 +18,10 @@ block(PROPAGATE PHP_VERSION)
   file(STRINGS configure.ac _ REGEX "^AC_INIT.+PHP\\],\\[([0-9.]+)([^]]*)")
   set(PHP_VERSION "${CMAKE_MATCH_1}")
   set(
-    PHP_VERSION_LABEL "${CMAKE_MATCH_2}"
-    CACHE STRING "Extra PHP version label suffix, e.g. '-dev', 'rc1', '-acme'"
+    CACHE{PHP_VERSION_LABEL}
+    TYPE STRING
+    HELP "Extra PHP version label suffix, e.g. '-dev', 'rc1', '-acme'"
+    VALUE "${CMAKE_MATCH_2}"
   )
   mark_as_advanced(PHP_VERSION_LABEL)
 endblock()

cmake/cmake/checks/CheckInline.cmake

@@ -73,9 +73,9 @@ if(NOT DEFINED PHP_INLINE_KEYWORD_CODE)
   _php_check_inline(PHP_INLINE_KEYWORD_CODE)
 
   set(
-    PHP_INLINE_KEYWORD_CODE
-    "${PHP_INLINE_KEYWORD_CODE}"
-    CACHE INTERNAL
-    "Compiler inline keyword definition."
+    CACHE{PHP_INLINE_KEYWORD_CODE}
+    TYPE INTERNAL
+    HELP "Compiler inline keyword definition."
+    VALUE "${PHP_INLINE_KEYWORD_CODE}"
   )
 endif()

cmake/cmake/modules/FindACL.cmake

@@ -141,8 +141,8 @@ if(
   if(ACL_INCLUDE_DIR AND ACL_LIBRARY)
     set(ACL_IS_BUILT_IN FALSE)
   else()
-    unset(ACL_INCLUDE_DIR CACHE)
-    unset(ACL_LIBRARY CACHE)
+    unset(CACHE{ACL_INCLUDE_DIR})
+    unset(CACHE{ACL_LIBRARY})
   endif()
 endif()
 

cmake/cmake/modules/FindBerkeleyDB.cmake

@@ -106,7 +106,7 @@ if(BerkeleyDB_USE_DB1)
   cmake_pop_check_state()
 
   if(NOT _berkeleydb_db1_sanity_check)
-    unset(BerkeleyDB_DB1_INCLUDE_DIR CACHE)
+    unset(CACHE{BerkeleyDB_DB1_INCLUDE_DIR})
     message(CHECK_FAIL "disabled, not found")
   else()
     message(CHECK_PASS "enabled")