Rename PHPSystem

This renames the weird PHPSystem to simply PHP, however it may clash
with variables set by `project(PHP)`.

In checking and refactoring phase...

Author: petk

cmake/CMakeLists.txt

@@ -62,7 +62,7 @@ block()
 endblock()
 
 # Rebuild all targets as needed.
-if(NOT PHPSystem_EXECUTABLE)
+if(NOT PHP_EXECUTABLE)
   include(PHP/Rebuild)
 endif()
 

cmake/cmake/Requirements.cmake

@@ -127,4 +127,4 @@ find_package(Sendmail)
 # it can be used. Otherwise the built cli sapi is used at the build phase.
 # Minimum supported version for gen_stub.php is PHP 7.4.
 ################################################################################
-find_package(PHPSystem 7.4)
+find_package(PHP 7.4 MODULE)

cmake/cmake/modules/FindPHP.cmake

@@ -0,0 +1,74 @@
+#[=============================================================================[
+# FindPHP
+
+Find PHP on the system, if installed. This is a helper module for using PHP CLI
+during the build and development of PHP sources. See also
+`ext/skeleton/cmake/modules/FindPHP.cmake` module.
+
+## Result variables
+
+* `PHP_FOUND` - Whether the package has been found.
+* `PHP_EXECUTABLE_VERSION` - Package version, if found.
+
+## Cache variables
+
+* `PHP_EXECUTABLE` - PHP command-line executable, if available.
+#]=============================================================================]
+
+include(FeatureSummary)
+include(FindPackageHandleStandardArgs)
+
+set_package_properties(
+  PHP
+  PROPERTIES
+    URL "https://www.php.net"
+    DESCRIPTION "PHP: Hypertext Preprocessor"
+)
+
+set(_reason "")
+
+find_program(
+  PHP_EXECUTABLE
+  NAMES php
+  DOC "Path to the PHP executable"
+)
+mark_as_advanced(PHP_EXECUTABLE)
+
+if(NOT PHP_EXECUTABLE)
+  string(APPEND _reason "The php command-line executable could not be found. ")
+endif()
+
+unset(PHP_EXECUTABLE_VERSION)
+block(PROPAGATE PHP_EXECUTABLE_VERSION)
+  if(PHP_EXECUTABLE)
+    execute_process(
+      COMMAND ${PHP_EXECUTABLE} --version
+      OUTPUT_VARIABLE version
+      OUTPUT_STRIP_TRAILING_WHITESPACE
+      ERROR_VARIABLE error
+      RESULT_VARIABLE result
+    )
+
+    if(NOT result EQUAL 0)
+      message(
+        SEND_ERROR
+        "Command \"${PHP_EXECUTABLE} --version\" failed with output:\n"
+        "${error}"
+      )
+    endif()
+
+    if(version MATCHES "PHP ([0-9]+[0-9.]+[^ ]+) \\(cli\\)")
+      set(PHP_EXECUTABLE_VERSION "${CMAKE_MATCH_1}")
+    endif()
+  endif()
+endblock()
+
+find_package_handle_standard_args(
+  PHP
+  REQUIRED_VARS PHP_EXECUTABLE PHP_EXECUTABLE_VERSION
+  VERSION_VAR PHP_EXECUTABLE_VERSION
+  HANDLE_VERSION_RANGE
+  REASON_FAILURE_MESSAGE "${_reason}"
+)
+
+unset(_reason)

cmake/cmake/modules/FindPHPSystem.cmake

@@ -82,10 +82,10 @@ function(php_add_custom_command)
     set(verbatim "")
   endif()
 
-  if(PHPSystem_EXECUTABLE)
+  if(PHP_EXECUTABLE)
     add_custom_command(
       OUTPUT ${parsed_OUTPUT}
-      COMMAND ${PHPSystem_EXECUTABLE} ${parsed_PHP_COMMAND}
+      COMMAND ${PHP_EXECUTABLE} ${parsed_PHP_COMMAND}
       DEPENDS ${parsed_DEPENDS}
       COMMENT "${parsed_COMMENT}"
       ${verbatim}
@@ -99,9 +99,12 @@ function(php_add_custom_command)
   endif()
 
   if(NOT CMAKE_CROSSCOMPILING)
-    set(PHP_EXECUTABLE "$<TARGET_FILE:PHP::sapi::cli>")
+    set(phpExecutable "$<TARGET_FILE:PHP::sapi::cli>")
   elseif(CMAKE_CROSSCOMPILING AND CMAKE_CROSSCOMPILING_EMULATOR)
-    set(PHP_EXECUTABLE "${CMAKE_CROSSCOMPILING_EMULATOR};$<TARGET_FILE:PHP::sapi::cli>")
+    set(
+      phpExecutable
+      "${CMAKE_CROSSCOMPILING_EMULATOR};$<TARGET_FILE:PHP::sapi::cli>"
+    )
   else()
     return()
   endif()
@@ -111,7 +114,7 @@ function(php_add_custom_command)
   add_custom_target(
     ${targetName} ALL
     COMMAND ${CMAKE_COMMAND}
-      -D "PHP_EXECUTABLE=${PHP_EXECUTABLE}"
+      -D "PHP_EXECUTABLE=${phpExecutable}"
       -D "OUTPUT=${parsed_OUTPUT}"
       -D "PHP_COMMAND=${parsed_PHP_COMMAND}"
       -D "DEPENDS=${parsed_DEPENDS}"

cmake/cmake/modules/PHP/AddCustomCommand.cmake

@@ -15,7 +15,7 @@ function(_php_stubs_get_php_command result)
   # If PHP is not found on the system, the PHP cli SAPI will be used with the
   # tokenizer extension.
   if(
-    NOT PHPSystem_EXECUTABLE
+    NOT PHP_EXECUTABLE
     AND (
       NOT TARGET PHP::sapi::cli
       OR (TARGET PHP::sapi::cli AND NOT TARGET PHP::ext::tokenizer)
@@ -25,16 +25,16 @@ function(_php_stubs_get_php_command result)
   endif()
 
   # If external PHP is available, check for the required tokenizer extension.
-  if(PHPSystem_EXECUTABLE)
+  if(PHP_EXECUTABLE)
     execute_process(
-      COMMAND ${PHPSystem_EXECUTABLE} --ri tokenizer
+      COMMAND ${PHP_EXECUTABLE} --ri tokenizer
       RESULT_VARIABLE code
       OUTPUT_QUIET
       ERROR_QUIET
     )
 
     if(code EQUAL 0)
-      set(${result} ${PHPSystem_EXECUTABLE})
+      set(${result} ${PHP_EXECUTABLE})
       return(PROPAGATE ${result})
     endif()
   endif()
@@ -113,7 +113,7 @@ block()
       $<PATH:ABSOLUTE_PATH,NORMALIZE,$<LIST:FILTER,$<TARGET_PROPERTY:${target},SOURCES>,INCLUDE,\.stub\.php$>,$<TARGET_PROPERTY:${target},SOURCE_DIR>>
     )
 
-    if(PHPSystem_EXECUTABLE)
+    if(PHP_EXECUTABLE)
       add_dependencies(${target} php_stubs)
     endif()
   endforeach()
@@ -128,7 +128,7 @@ block()
   )
 
   set(targetOptions "")
-  if(NOT PHPSystem_EXECUTABLE)
+  if(NOT PHP_EXECUTABLE)
     set(targetOptions ALL DEPENDS ${targets})
   endif()
 

cmake/cmake/modules/PHP/Stubs.cmake

@@ -125,9 +125,12 @@ if(NOT TARGET PHP::sapi::cli)
 endif()
 
 if(NOT CMAKE_CROSSCOMPILING)
-  set(PHP_EXECUTABLE "$<TARGET_FILE:PHP::sapi::cli>")
+  set(phpExecutable "$<TARGET_FILE:PHP::sapi::cli>")
 elseif(CMAKE_CROSSCOMPILING AND CMAKE_CROSSCOMPILING_EMULATOR)
-  set(PHP_EXECUTABLE "${CMAKE_CROSSCOMPILING_EMULATOR};$<TARGET_FILE:PHP::sapi::cli>")
+  set(
+    phpExecutable
+    "${CMAKE_CROSSCOMPILING_EMULATOR};$<TARGET_FILE:PHP::sapi::cli>"
+  )
 else()
   return()
 endif()
@@ -151,7 +154,7 @@ cmake_path(
 add_custom_command(
   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/phar.php
   COMMAND
-    ${PHP_EXECUTABLE}
+    ${phpExecutable}
       -n
       ${pharSharedOptions}
       -d open_basedir=
@@ -167,7 +170,7 @@ add_custom_command(
 add_custom_command(
   OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/phar.phar
   COMMAND
-    ${PHP_EXECUTABLE}
+    ${phpExecutable}
       -n
       ${pharSharedOptions}
       -d open_basedir=
@@ -244,7 +247,7 @@ set_property(SOURCE php_ext_phar_generated_phar PROPERTY SYMBOLIC TRUE)
 install(CODE "
   execute_process(
     COMMAND
-      ${PHP_EXECUTABLE}
+      ${phpExecutable}
         -n
         ${pharSharedOptions}
         -d open_basedir=

cmake/ext/phar/CMakeLists.txt

@@ -121,19 +121,22 @@ block()
   endforeach()
 endblock()
 
-set(PHP_EXECUTABLE "")
+set(phpExecutable "")
 if(NOT CMAKE_CROSSCOMPILING)
-  set(PHP_EXECUTABLE "$<TARGET_FILE:PHP::sapi::cli>")
+  set(phpExecutable "$<TARGET_FILE:PHP::sapi::cli>")
 elseif(CMAKE_CROSSCOMPILING AND CMAKE_CROSSCOMPILING_EMULATOR)
-  set(PHP_EXECUTABLE "${CMAKE_CROSSCOMPILING_EMULATOR};$<TARGET_FILE:PHP::sapi::cli>")
+  set(
+    phpExecutable
+    "${CMAKE_CROSSCOMPILING_EMULATOR};$<TARGET_FILE:PHP::sapi::cli>"
+  )
 endif()
 
 php_install(CODE "
   set(phpPearInstallDir \"$<PATH:ABSOLUTE_PATH,NORMALIZE,${PHP_PEAR_DIR},\${CMAKE_INSTALL_PREFIX}>\")
   set(phpPearInstallBinDir \"$<PATH:ABSOLUTE_PATH,NORMALIZE,${CMAKE_INSTALL_BINDIR},\${CMAKE_INSTALL_PREFIX}>\")
   set(phpPearCurrentSourceDir \"${CMAKE_CURRENT_SOURCE_DIR}\")
   set(phpPearCurrentBinaryDir \"${CMAKE_CURRENT_BINARY_DIR}\")
-  set(phpPearPhpExecutable \"${PHP_EXECUTABLE}\")
+  set(phpPearPhpExecutable \"${phpExecutable}\")
   set(phpExtensionDir \"$<PATH:ABSOLUTE_PATH,NORMALIZE,${PHP_EXTENSION_DIR},\${CMAKE_INSTALL_PREFIX}>\")
   set(PHP_EXT_OPENSSL_SHARED ${PHP_EXT_OPENSSL_SHARED})
   set(PHP_EXT_XML_SHARED ${PHP_EXT_XML_SHARED})

cmake/pear/CMakeLists.txt

@@ -141,8 +141,7 @@ file(
     ${phpPearStageTempDir}/temp
 )
 
-# Add options for PHP executable, when dependent extensions are shared, they
-# need to be loaded for the PHP_EXECUTABLE.
+# Add options for PHP executable, when dependent extensions are shared.
 set(phpPearOptions -d extension_dir=${PHP_BINARY_DIR}/modules)
 
 if(PHP_EXT_OPENSSL_SHARED)