Распаковка одного файла epf в заданный каталог. (Портировано на 1Script) xDrivenDevelopment#30

Author: EvilBeaver

tests/v8files-extractor-test.os

@@ -0,0 +1,72 @@
+#Использовать tempfiles
+#Использовать asserts
+
+Перем юТест;
+
+Процедура Инициализация()
+		
+КонецПроцедуры
+
+Функция ПолучитьСписокТестов(Знач Контекст) Экспорт
+	
+	юТест = Контекст;
+	
+	ВсеТесты = Новый Массив;
+	
+	ВсеТесты.Добавить("Тест_ДолженРазложитьФайлОбработкиИзЗаданнойПапки");
+	
+	Возврат ВсеТесты;
+	
+КонецФункции
+
+Процедура ПослеЗапускаТеста() Экспорт
+	//ВременныеФайлы.Удалить();
+КонецПроцедуры
+
+Процедура Тест_ДолженРазложитьФайлОбработкиИзЗаданнойПапки() Экспорт
+
+	ИмяКаталога = ТекущийСценарий().Каталог;
+	ИмяФайла = "Fixture";
+	ИмяФайлаСРасширением = ИмяФайла+".epf";
+	
+	ПутьФайла = ОбъединитьПути(ИмяКаталога, ИмяФайлаСРасширением);
+	Ожидаем.Что(Новый Файл(ПутьФайла).Существует(), "Исходный файл должен существовать").ЭтоИстина();
+	
+	КаталогВыгрузки = ВременныеФайлы.СоздатьКаталог();
+	
+	Исполнитель = ЗагрузитьСценарий(ОбъединитьПути(ИмяКаталога,"../v8files-extractor.os"));
+	Лог = Логирование.ПолучитьЛог("oscript.app.v8files-extractor");
+	Лог.УстановитьУровень(УровниЛога.Отладка);
+	
+	Исполнитель.РазобратьФайл(ПутьФайла, КаталогВыгрузки);
+	
+	МассивФайлов = НайтиФайлы(КаталогВыгрузки, ПолучитьМаскуВсеФайлы());
+	Ожидаем.Что(МассивФайлов, "В каталоге выгрузки должны быть файлы").Заполнено();
+	Нашли = Ложь;
+	для Каждого КаталогИсходников Из МассивФайлов Цикл
+		Нашли = КаталогИсходников.Имя = ИмяФайла;
+		Если Нашли Тогда
+			Прервать;
+		КонецЕсли;
+	КонецЦикла;
+	Ожидаем.Что(Нашли, "Должны были найти имя каталога обработки ").ЭтоИстина();
+	ВыгруженныеФайлы = НайтиФайлы(КаталогИсходников.ПолноеИмя, ПолучитьМаскуВсеФайлы());
+	ИменаВыгруженныхФайлов = РазвернутьМассивФайловВИменаФайлов(ВыгруженныеФайлы);
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("renames.txt");
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("Form");
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("Макеты");
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("und");
+КонецПроцедуры
+
+Функция РазвернутьМассивФайловВИменаФайлов(Знач МассивОбъектовФайл)
+	
+	ИменаФайлов = Новый Массив;
+	Для Каждого Файл Из МассивОбъектовФайл Цикл
+		ИменаФайлов.Добавить(Файл.Имя);
+	КонецЦикла;
+	
+	Возврат ИменаФайлов;
+	
+КонецФункции
+
+Инициализация();

v8files-extractor.os

@@ -0,0 +1,92 @@
+#Использовать cmdline
+#Использовать logos
+#Использовать tempfiles
+#Использовать asserts
+#Использовать v8runner
+
+Перем Лог;
+
+Процедура ЗапускВКоманднойСтроке()
+	
+	Парсер = Новый ПарсерАргументовКоманднойСтроки();
+	Парсер.ДобавитьПараметр("ВходящиеФайлы");
+	
+	Аргументы = Парсер.Разобрать(АргументыКоманднойСтроки);
+	
+	Для Каждого Параметр Из Аргументы Цикл
+		Лог.Отладка(Параметр);
+	КонецЦикла;
+	
+КонецПроцедуры
+
+Процедура Инициализация()
+	Лог = Логирование.ПолучитьЛог("oscript.app.v8files-extractor");
+	Лог.Отладка("Параметры командной строки:");
+КонецПроцедуры
+
+Процедура РазобратьФайл(Знач ПутьФайла, Знач КаталогВыгрузки) Экспорт
+	
+	Файл = Новый Файл(ПутьФайла);
+	Ожидаем.Что(Файл.Существует(), "Файл " + ПутьФайла + " должен существовать").ЭтоИстина();
+	
+	ПапкаИсходников = Новый Файл(ОбъединитьПути(КаталогВыгрузки, Файл.ИмяБезРасширения));
+	Лог.Отладка("Подготовка выгрузки файла "+ПутьФайла+" в каталог " + ПапкаИсходников.ПолноеИмя);
+	ОбеспечитьПустойКаталог(ПапкаИсходников);
+	ЗапуститьРаспаковку(Файл, ПапкаИсходников);
+	
+КонецПроцедуры
+
+Процедура ЗапуститьРаспаковку(Знач Файл, Знач ПапкаИсходников)
+	
+	Лог.Отладка("Запускаем распаковку файла");
+	
+	Конфигуратор = Новый УправлениеКонфигуратором();
+	ЛогКонфигуратора = Логирование.ПолучитьЛог("oscript.lib.v8runner");
+	ЛогКонфигуратора.УстановитьУровень(Лог.Уровень());
+	
+	Параметры = Конфигуратор.ПолучитьПараметрыЗапуска();
+	Параметры[0] = "ENTERPRISE";
+	
+	ПутьV8Reader = ОбъединитьПути(ТекущийСценарий().Каталог, "v8Reader", "V8Reader.epf");
+	Лог.Отладка("Путь к V8Reader: " + ПутьV8Reader);
+	Ожидаем.Что(Новый Файл(ПутьV8Reader).Существует()).ЭтоИстина();
+	
+	КоманднаяСтрокаV8Reader = СтрЗаменить("/C""decompile;pathtocf;%1;pathout;%2;ЗавершитьРаботуПосле;""","%1", Файл.ПолноеИмя);
+	КоманднаяСтрокаV8Reader = СтрЗаменить(КоманднаяСтрокаV8Reader,"%2", ПапкаИсходников.ПолноеИмя);
+	
+	Лог.Отладка("Командная строка V8Reader: " + КоманднаяСтрокаV8Reader);
+
+	Параметры.Добавить("/RunModeOrdinaryApplication");
+	Параметры.Добавить("/Execute """ + ПутьV8Reader + """");
+	Параметры.Добавить(КоманднаяСтрокаV8Reader);
+	
+	Конфигуратор.ВыполнитьКоманду(Параметры);
+	Лог.Отладка("Вывод 1С:Предприятия - " + Конфигуратор.ВыводКоманды());
+	
+КонецПроцедуры
+
+Процедура ОбеспечитьПустойКаталог(Знач ФайлОбъектКаталога)
+	
+	Если Не ФайлОбъектКаталога.Существует() Тогда
+		Лог.Отладка("Создаем новый каталог " + ФайлОбъектКаталога.ПолноеИмя);
+		СоздатьКаталог(ФайлОбъектКаталога.ПолноеИмя);
+	ИначеЕсли ФайлОбъектКаталога.ЭтоКаталог() Тогда
+		Лог.Отладка("Очищаем каталог " + ФайлОбъектКаталога.ПолноеИмя);
+		УдалитьФайлы(ФайлОбъектКаталога.ПолноеИмя, ПолучитьМаскуВсеФайлы());
+	Иначе
+		ВызватьИсключение "Путь " + ФайлОбъектКаталога.ПолноеИмя + " не является каталогом. Выгрузка невозможна";
+	КонецЕсли;
+	
+КонецПроцедуры
+
+Функция ЭтоЗапускТеста()
+	Возврат ТекущийСценарий().Источник <> СтартовыйСценарий().Источник;
+КонецФункции
+
+Инициализация();
+
+Если Не ЭтоЗапускТеста() Тогда
+	ЗапускВКоманднойСтроке();
+КонецЕсли;
+
+