Eliminate OPAL_FLAGS_UNIQ

OPAL_FLAGS_UNIQ lied and uniq'ed all flags, not just those startig
with -I, -L, and -l.  This caused all kinds of corner cases if
the macro was called at the wrong time (like on LDFLAGS if it
contained '-Wl,-rpath -Wl,/path1 -Wl,-rpath -Wl,/path2', because
it would eliminate the second '-Wl,-rpath', leaving a weird
directory path in the linker commands.

Since we've gotten good at adding flags via the UNIQ_APPEND calls
already, just do that in the small number of remaining places that
we were using OPAL_FLAGS_UNIQ and kill off the broken, dangerous
macro.

Signed-off-by: Brian Barrett <bbarrett@amazon.com>

Author: bwbarrett

config/ompi_fortran_check_real16_c_equiv.m4

@@ -48,8 +48,7 @@ AC_DEFUN([OMPI_FORTRAN_CHECK_REAL16_C_EQUIV],[
                        AS_IF([test "$opal_cv_c_compiler_vendor" = "intel"],
                              [AC_MSG_CHECKING([if intel compiler _Quad == REAL*16])
                               CFLAGS_save="$CFLAGS"
-                              CFLAGS="$CFLAGS -Qoption,cpp,--extended_float_types"
-                              OPAL_FLAGS_UNIQ([CFLAGS])
+                              OPAL_FLAGS_APPEND_UNIQ([CFLAGS], ["-Qoption,cpp,--extended_float_types"])
                               OMPI_FORTRAN_CHECK_REAL16_EQUIV_TYPE([_Quad], [q])
                               AS_IF([test "$happy" = "yes"],
                                     [OMPI_FORTRAN_REAL16_C_TYPE="_Quad"
@@ -59,7 +58,6 @@ AC_DEFUN([OMPI_FORTRAN_CHECK_REAL16_C_EQUIV],[
                              ])
                        AS_IF([test "$opal_cv_c_compiler_vendor" = "gnu" && test "$ac_cv_type___float128" = "yes"],
                              [AC_MSG_CHECKING([if gnu compiler __float128 == REAL*16])
-                              OPAL_FLAGS_UNIQ([CFLAGS])
                               OMPI_FORTRAN_CHECK_REAL16_EQUIV_TYPE([__float128], [q])
                               AS_IF([test "$happy" = "yes"],
                                     [OMPI_FORTRAN_REAL16_C_TYPE="__float128"

config/opal_check_cflags.m4

@@ -23,7 +23,7 @@ AC_DEFUN([_OPAL_CFLAGS_FAIL_SEARCH],[
 AC_DEFUN([_OPAL_CHECK_SPECIFIC_CFLAGS], [
 AC_MSG_CHECKING(if $CC supports ([$1]))
             CFLAGS_orig=$CFLAGS
-            CFLAGS="$CFLAGS $1"
+            OPAL_FLAGS_APPEND_UNIQ([CFLAGS], ["$1"])
             AC_CACHE_VAL(opal_cv_cc_[$2], [
                    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [$3])],
                                    [
@@ -55,7 +55,7 @@ AC_DEFUN([_OPAL_CXXFLAGS_FAIL_SEARCH],[
 AC_DEFUN([_OPAL_CHECK_SPECIFIC_CXXFLAGS], [
 AC_MSG_CHECKING(if $CXX supports ([$1]))
             CXXFLAGS_orig=$CXXFLAGS
-            CXXFLAGS="$CXXFLAGS $1"
+            OPAL_FLAGS_APPEND_UNIQ([CXXFLAGS], ["$1"])
             AC_CACHE_VAL(opal_cv_cxx_[$2], [
                    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [$3])],
                                    [

config/opal_functions.m4

@@ -357,103 +357,6 @@ dnl #######################################################################
 dnl #######################################################################
 dnl #######################################################################
 
-# Remove all duplicate -I, -L, and -l flags from the variable named $1
-AC_DEFUN([OPAL_FLAGS_UNIQ],[
-    # 1 is the variable name to be uniq-ized
-    opal_name=$1
-
-    # Go through each item in the variable and only keep the unique ones
-
-    opal_count=0
-    for val in ${$1}; do
-        opal_done=0
-        opal_i=1
-        opal_found=0
-
-        # Loop over every token we've seen so far
-
-        opal_done="`expr $opal_i \> $opal_count`"
-        while test "$opal_found" = "0" && test "$opal_done" = "0"; do
-
-            # Have we seen this token already?  Prefix the comparison
-            # with "x" so that "-Lfoo" values won't be cause an error.
-
-	    opal_eval="expr x$val = x\$opal_array_$opal_i"
-	    opal_found=`eval $opal_eval`
-
-            # Check the ending condition
-
-	    opal_done="`expr $opal_i \>= $opal_count`"
-
-            # Increment the counter
-
-	    opal_i="`expr $opal_i + 1`"
-        done
-
-        # Check for special cases where we do want to allow repeated
-        # arguments (per
-        # https://www.open-mpi.org/community/lists/devel/2012/08/11362.php
-        # and
-        # https://github.com/open-mpi/ompi/issues/324).
-
-        case $val in
-        -Xclang)
-                opal_found=0
-                opal_i=`expr $opal_count + 1`
-                ;;
-        -framework)
-                opal_found=0
-                opal_i=`expr $opal_count + 1`
-                ;;
-        --param)
-                opal_found=0
-                opal_i=`expr $opal_count + 1`
-                ;;
-        esac
-
-        # If we didn't find the token, add it to the "array"
-
-        if test "$opal_found" = "0"; then
-	    opal_eval="opal_array_$opal_i=$val"
-	    eval $opal_eval
-	    opal_count="`expr $opal_count + 1`"
-        else
-	    opal_i="`expr $opal_i - 1`"
-        fi
-    done
-
-    # Take all the items in the "array" and assemble them back into a
-    # single variable
-
-    opal_i=1
-    opal_done="`expr $opal_i \> $opal_count`"
-    opal_newval=
-    while test "$opal_done" = "0"; do
-        opal_eval="opal_newval=\"$opal_newval \$opal_array_$opal_i\""
-        eval $opal_eval
-
-        opal_eval="unset opal_array_$opal_i"
-        eval $opal_eval
-
-        opal_done="`expr $opal_i \>= $opal_count`"
-        opal_i="`expr $opal_i + 1`"
-    done
-
-    # Done; do the assignment
-
-    opal_newval="`echo $opal_newval`"
-    opal_eval="$opal_name=\"$opal_newval\""
-    eval $opal_eval
-
-    # Clean up
-
-    unset opal_name opal_i opal_done opal_newval opal_eval opal_count
-])dnl
-
-dnl #######################################################################
-dnl #######################################################################
-dnl #######################################################################
-
 # OPAL_FLAGS_APPEND_UNIQ(variable, new_argument)
 # ----------------------------------------------
 # Append new_argument to variable if:

config/opal_setup_cc.m4

@@ -106,7 +106,7 @@ AC_DEFUN([OPAL_PROG_CC_C11],[
             for flag in $(echo $opal_prog_cc_c11_flags | tr ' ' '\n') ; do
                 OPAL_PROG_CC_C11_HELPER([$flag],[opal_cv_c11_flag=$flag],[])
                 if test "x$opal_cv_c11_flag" != "x" ; then
-                    CFLAGS="$CFLAGS $opal_cv_c11_flag"
+                    OPAL_FLAGS_APPEND_UNIQ([CFLAGS], ["$opal_cv_c11_flag"])
                     AC_MSG_NOTICE([using $flag to enable C11 support])
                     opal_cv_c11_supported=yes
                     break
@@ -268,7 +268,7 @@ AC_DEFUN([OPAL_SETUP_CC],[
         # compiling and linking to circumvent trouble with
         # libgcov.
         LDFLAGS_orig="$LDFLAGS"
-        LDFLAGS="$LDFLAGS_orig --coverage"
+        OPAL_FLAGS_APPEND_UNIQ([LDFLAGS], ["--coverage"])
         OPAL_COVERAGE_FLAGS=
 
         _OPAL_CHECK_SPECIFIC_CFLAGS(--coverage, coverage)
@@ -287,8 +287,6 @@ AC_DEFUN([OPAL_SETUP_CC],[
             CLEANFILES="*.bb *.bbg ${CLEANFILES}"
             OPAL_COVERAGE_FLAGS="-ftest-coverage -fprofile-arcs"
         fi
-        OPAL_FLAGS_UNIQ(CFLAGS)
-        OPAL_FLAGS_UNIQ(LDFLAGS)
         WANT_DEBUG=1
    fi
 
@@ -419,7 +417,6 @@ AC_DEFUN([OPAL_SETUP_CC],[
     OPAL_ENSURE_CONTAINS_OPTFLAGS(["$CFLAGS"])
     AC_MSG_RESULT([$co_result])
     CFLAGS="$co_result"
-    OPAL_FLAGS_UNIQ([CFLAGS])
     AC_MSG_RESULT(CFLAGS result: $CFLAGS)
     OPAL_VAR_SCOPE_POP
 ])