Create a network from Keras file; setting weights and biases remains TODO

Author: milancurcic

src/nf/nf_network.f90

@@ -32,14 +32,25 @@ module nf_network
   end type network
 
   interface network
-    module function network_cons(layers) result(res)
-      !! Create a new `network` instance.
+
+    module function network_from_layers(layers) result(res)
+      !! Create a new `network` instance from an array of `layer` instances.
       type(layer), intent(in) :: layers(:)
-        !! Input array of layer instances;
+        !! Input array of `layer` instances;
         !! the first element must be an input layer.
       type(network) :: res
         !! An instance of the `network` type
-    end function network_cons
+    end function network_from_layers
+
+    module function network_from_keras(filename) result(res)
+      !! Create a new `network` instance
+      !! from a Keras model saved in an h5 file.
+      character(*), intent(in) :: filename
+        !! Path to the Keras model h5 file
+      type(network) :: res
+        !! An instance of the `network` type
+    end function network_from_keras
+
   end interface network
 
   interface forward

src/nf/nf_network_submodule.f90

@@ -4,7 +4,9 @@
   use nf_flatten_layer, only: flatten_layer
   use nf_input1d_layer, only: input1d_layer
   use nf_input3d_layer, only: input3d_layer
+  use nf_keras, only: get_keras_h5_layers, keras_layer
   use nf_layer, only: layer
+  use nf_layer_constructors, only: dense, input
   use nf_loss, only: quadratic_derivative
   use nf_optimizers, only: sgd
   use nf_parallel, only: tile_indices
@@ -13,7 +15,7 @@
 
 contains
 
-  module function network_cons(layers) result(res)
+  module function network_from_layers(layers) result(res)
     type(layer), intent(in) :: layers(:)
     type(network) :: res
     integer :: n
@@ -45,7 +47,51 @@ module function network_cons(layers) result(res)
       call res % layers(n) % init(res % layers(n - 1))
     end do
 
-  end function network_cons
+  end function network_from_layers
+
+
+  module function network_from_keras(filename) result(res)
+    character(*), intent(in) :: filename
+    type(network) :: res
+    type(keras_layer), allocatable :: keras_layers(:)
+    type(layer), allocatable :: layers(:)
+    integer :: n
+
+    keras_layers = get_keras_h5_layers(filename)
+
+    allocate(layers(size(keras_layers)))
+
+    do n = 1, size(layers)
+
+      select case(keras_layers(n) % class)
+
+        case('InputLayer')
+          if (size(keras_layers(n) % num_elements) == 1) then
+            ! input1d
+            layers(n) = input(keras_layers(n) % num_elements(1))
+          else
+            ! input3d
+            layers(n) = input(keras_layers(n) % num_elements)
+          end if
+
+        case('Dense')
+          layers(n) = dense( &
+            keras_layers(n) % num_elements(1), &
+            keras_layers(n) % activation &
+          )
+
+        case default
+          error stop 'This Keras layer is not supported'
+
+      end select
+
+    end do
+
+    res = network(layers)
+
+    !TODO read weights and biases from Keras file and set here
+
+  end function network_from_keras
 
 
   pure module subroutine backward(self, output)

test/test_dense_network_from_keras.f90

@@ -0,0 +1,63 @@
+program test_dense_network_from_keras
+
+  use iso_fortran_env, only: stderr => error_unit
+  use nf, only: network
+  use nf_datasets, only: download_and_unpack, keras_model_dense_mnist_url
+
+  implicit none
+
+  type(network) :: net
+  character(*), parameter :: test_data_path = 'keras_dense_mnist.h5'
+
+  logical :: file_exists
+  logical :: ok = .true.
+
+  inquire(file=test_data_path, exist=file_exists)
+  if (.not. file_exists) call download_and_unpack(keras_model_dense_mnist_url)
+
+  net = network(test_data_path)
+
+  if (.not. size(net % layers) == 3) then
+    write(stderr, '(a)') 'dense network should have 3 layers.. failed'
+    ok = .false.
+  end if
+
+  if (.not. net % layers(1) % name == 'input') then
+    write(stderr, '(a)') 'First layer should be an input layer.. failed'
+    ok = .false.
+  end if
+
+  if (.not. all(net % layers(1) % layer_shape == [784])) then
+    write(stderr, '(a)') 'First layer should have shape [784].. failed'
+    ok = .false.
+  end if
+
+  if (.not. net % layers(2) % name == 'dense') then
+    write(stderr, '(a)') 'Second layer should be a dense layer.. failed'
+    ok = .false.
+  end if
+
+  if (.not. all(net % layers(2) % layer_shape == [30])) then
+    write(stderr, '(a)') 'Second layer should have shape [30].. failed'
+    ok = .false.
+  end if
+
+  if (.not. net % layers(3) % name == 'dense') then
+    write(stderr, '(a)') 'Third layer should be a dense layer.. failed'
+    ok = .false.
+  end if
+
+  if (.not. all(net % layers(3) % layer_shape == [10])) then
+    write(stderr, '(a)') 'Third layer should have shape [10].. failed'
+    ok = .false.
+  end if
+
+  if (ok) then
+    print '(a)', 'test_dense_network_from_keras: All tests passed.'
+  else
+    write(stderr, '(a)') &
+      'test_dense_network_from_keras: One or more tests failed.'
+    stop 1
+  end if
+
+end program test_dense_network_from_keras