Add function to read an HDF5 varying-length string attribute

Author: milancurcic

src/nf/nf_io_hdf5.f90

@@ -0,0 +1,25 @@
+module nf_io_hdf5
+
+  !! This module provides convenience functions to read HDF5 files.
+
+  implicit none
+
+  private
+  public :: get_h5_attribute_string
+
+  interface
+
+    module function get_h5_attribute_string( &
+      filename, object_name, attribute_name) result(res)
+      character(*), intent(in) :: filename
+        !! HDF5 file name
+      character(*), intent(in) :: object_name
+        !! Object (group, dataset) name
+      character(*), intent(in) :: attribute_name
+        !! Name of the attribute to read
+      character(:), allocatable :: res
+    end function get_h5_attribute_string
+
+  end interface
+
+end module nf_io_hdf5

src/nf/nf_io_hdf5_submodule.f90

@@ -0,0 +1,46 @@
+submodule(nf_io_hdf5) nf_io_hdf5_submodule
+
+  use hdf5, only: H5F_ACC_RDONLY_F, HID_T, &
+                  h5aget_type_f, h5aopen_by_name_f, h5aread_f, &
+                  h5fclose_f, h5fopen_f
+  use iso_c_binding, only: c_char, c_f_pointer, c_loc, c_null_char, c_ptr
+
+  implicit none
+
+contains
+
+  module function get_h5_attribute_string( &
+    filename, object_name, attribute_name) result(res)
+
+    character(*), intent(in) :: filename
+    character(*), intent(in) :: object_name
+    character(*), intent(in) :: attribute_name
+    character(:), allocatable :: res
+
+    ! Make sufficiently large to hold most attributes
+    integer, parameter :: BUFLEN = 10000
+
+    type(c_ptr) :: f_ptr
+    type(c_ptr), target :: buffer
+    character(len=BUFLEN, kind=c_char), pointer :: string => null()
+    integer(HID_T) :: fid, aid, atype
+    integer :: hdferr
+
+    ! Open the file and get the type of the attribute
+    call h5fopen_f(filename, H5F_ACC_RDONLY_F, fid, hdferr)
+    call h5aopen_by_name_f(fid, object_name, attribute_name, aid, hdferr)
+    call h5aget_type_f(aid, atype, hdferr)
+
+    ! Read the data
+    f_ptr = c_loc(buffer)
+    call h5aread_f(aid, atype, f_ptr, hdferr)
+    call c_f_pointer(buffer, string)
+
+    ! Close the file 
+    call h5fclose_f(fid, hdferr)
+    
+    res = string(:index(string, c_null_char))
+
+  end function get_h5_attribute_string
+
+end submodule nf_io_hdf5_submodule

test/test_io_h5.f90

@@ -0,0 +1,9 @@
+program test_io_hdf5
+
+  use nf_io_hdf5, only: get_h5_attribute_string
+  implicit none
+
+  print *, get_h5_attribute_string('test/data/mnist_dense.h5', '.', 'model_config')
+  print *, get_h5_attribute_string('test/data/mnist_dense.h5', 'model_weights', 'layer_names')
+
+end program test_io_hdf5