Update example programs

Author: milancurcic

example/example_mnist.f90

@@ -0,0 +1,63 @@
+program mnist
+  use nf, only: dense, input, network
+  use nf_datasets_mnist, only: label_digits, load_mnist
+  use nf_optimizers, only: sgd
+
+  implicit none
+
+  type(network) :: net
+  real, allocatable :: training_images(:,:), training_labels(:)
+  real, allocatable :: validation_images(:,:), validation_labels(:)
+  integer :: n, num_epochs
+
+  call load_mnist(training_images, training_labels, &
+                  validation_images, validation_labels)
+
+  print '("MNIST")'
+  print '(60("="))'
+
+  net = network([ &
+    input(784), &
+    dense(30), &
+    dense(10) &
+  ])
+  num_epochs = 10
+
+  call net % print_info()
+
+  if (this_image() == 1) &
+    print '(a,f5.2,a)', 'Initial accuracy: ', accuracy( &
+      net, validation_images, label_digits(validation_labels)) * 100, ' %'
+
+  epochs: do n = 1, num_epochs
+
+    call net % train( &
+      training_images, &
+      label_digits(training_labels), &
+      batch_size=100, &
+      epochs=1, &
+      optimizer=sgd(learning_rate=3.) &
+    )
+
+    if (this_image() == 1) &
+      print '(a,i2,a,f5.2,a)', 'Epoch ', n, ' done, Accuracy: ', accuracy( &
+        net, validation_images, label_digits(validation_labels)) * 100, ' %'
+
+  end do epochs
+
+contains
+
+  real function accuracy(net, x, y)
+    type(network), intent(in out) :: net
+    real, intent(in) :: x(:,:), y(:,:)
+    integer :: i, good
+    good = 0
+    do i = 1, size(x, dim=2)
+      if (all(maxloc(net % output(x(:,i))) == maxloc(y(:,i)))) then
+        good = good + 1
+      end if
+    end do
+    accuracy = real(good) / size(x, dim=2)
+  end function accuracy
+
+end program mnist

example/example_mnist_epochs.f90

@@ -0,0 +1,34 @@
+program simple
+  use nf, only: dense, input, network
+  implicit none
+  type(network) :: net
+  real, allocatable :: x(:), y(:)
+  integer, parameter :: num_iterations = 500
+  integer :: n
+
+  print '("Simple")'
+  print '(60("="))'
+
+  net = network([ &
+    input(3), &
+    dense(5), &
+    dense(2) &
+  ])
+
+  call net % print_info()
+
+  x = [0.2, 0.4, 0.6]
+  y = [0.123456, 0.246802]
+
+  do n = 0, num_iterations
+
+    call net % forward(x)
+    call net % backward(y)
+    call net % update(1.)
+
+    if (mod(n, 50) == 0) &
+      print '(i4,2(3x,f8.6))', n, net % output(x)
+
+  end do
+
+end program simple

example/example_save_and_load.f90

@@ -0,0 +1,43 @@
+program sine
+  use nf, only: dense, input, network
+  implicit none
+  type(network) :: net
+  real :: x(1), y(1)
+  real, parameter :: pi = 4 * atan(1.)
+  integer, parameter :: num_iterations = 100000
+  integer, parameter :: test_size = 30
+  real :: xtest(test_size), ytest(test_size), ypred(test_size)
+  integer :: i, n
+
+  print '("Sine training")'
+  print '(60("="))'
+
+  net = network([ &
+    input(1), &
+    dense(5), &
+    dense(1) &
+  ])
+
+  call net % print_info()
+
+  xtest = [((i - 1) * 2 * pi / test_size, i = 1, test_size)]
+  ytest = (sin(xtest) + 1) / 2
+
+  do n = 0, num_iterations
+
+    call random_number(x)
+    x = x * 2 * pi
+    y = (sin(x) + 1) / 2
+
+    call net % forward(x)
+    call net % backward(y)
+    call net % update(1.)
+
+    if (mod(n, 10000) == 0) then
+      ypred = [(net % output([xtest(i)]), i = 1, test_size)]
+      print '(i0,1x,f9.6)', n, sum((ypred - ytest)**2) / size(ypred)
+    end if
+
+  end do
+
+end program sine