Merge pull request github#6003 from hvitved/csharp/external-summaries

C#: CSV-based flow summaries

Author: hvitved

csharp/change-notes/2021-06-16-qualified-names.md

@@ -0,0 +1,9 @@
+lgtm,codescanning
+* The following has changed in `Type::getQualifiedName`/`Type::hasQualifiedName`:
+  - Type parameters now have the qualified name which is simply the name of the type
+    parameter itself. Example: in `class C<T> { }`, `T` has qualified name `T`.
+  - Constructed types now use qualified names for type arguments. For example, the
+    qualified name of `C<int>` is `C<System.Int32>`. This also includes array types
+    and pointer types.
+  - Nested types are now delimited by `+` instead of `.`. For example, the qualified
+    name of `Inner` in `class Outer { class Inner { } }` is `Outer+Inner`.

csharp/ql/src/semmle/code/csharp/Generics.qll

@@ -185,6 +185,11 @@ class TypeParameter extends DotNet::TypeParameter, Type, @type_parameter {
   /** Gets the generic that defines this type parameter. */
   UnboundGeneric getGeneric() { type_parameters(this, _, result, _) }
 
+  final override predicate hasQualifiedName(string qualifier, string name) {
+    qualifier = "" and
+    name = this.getName()
+  }
+
   override string getAPrimaryQlClass() { result = "TypeParameter" }
 }
 

csharp/ql/src/semmle/code/csharp/Member.qll

@@ -34,7 +34,12 @@ class Declaration extends DotNet::Declaration, Element, @declaration {
    * ```
    */
   string getQualifiedNameWithTypes() {
-    result = this.getDeclaringType().getQualifiedName() + "." + this.toStringWithTypes()
+    exists(string qual |
+      qual = this.getDeclaringType().getQualifiedName() and
+      if this instanceof NestedType
+      then result = qual + "+" + this.toStringWithTypes()
+      else result = qual + "." + this.toStringWithTypes()
+    )
   }
 
   /**
@@ -326,6 +331,7 @@ class Virtualizable extends Member, @virtualizable {
    *   (An example where `getOverridee*().getImplementee()` would be incorrect.)
    * - If this member is `D.M` then `I.M = getAnUltimateImplementee()`.
    */
+  pragma[nomagic]
   Virtualizable getAnUltimateImplementee() {
     exists(Virtualizable implementation, ValueOrRefType implementationType |
       implements(implementation, result, implementationType)

csharp/ql/src/semmle/code/csharp/Type.qll

@@ -55,17 +55,50 @@ private predicate isObjectClass(Class c) { c instanceof ObjectType }
  * Either a value type (`ValueType`) or a reference type (`RefType`).
  */
 class ValueOrRefType extends DotNet::ValueOrRefType, Type, Attributable, @value_or_ref_type {
+  /** Gets the name of this type without `<...>` brackets, in case it is a constructed type. */
+  private string getNameWithoutBrackets() {
+    exists(UnboundGenericType unbound, string name |
+      unbound = this.(ConstructedType).getUnboundDeclaration() and
+      name = unbound.getName() and
+      result = name.prefix(name.length() - unbound.getNumberOfTypeParameters() - 1)
+    )
+    or
+    not this instanceof ConstructedType and
+    result = this.getName()
+  }
+
+  language[monotonicAggregates]
+  private string getQualifiedTypeArguments() {
+    result =
+      strictconcat(Type t, int i |
+        t = this.(ConstructedType).getTypeArgument(i)
+      |
+        t.getQualifiedName(), "," order by i
+      )
+  }
+
   /**
    * Holds if this type has the qualified name `qualifier`.`name`.
    *
    * For example the class `System.IO.IOException` has
    * `qualifier`=`System.IO` and `name`=`IOException`.
    */
   override predicate hasQualifiedName(string qualifier, string name) {
-    name = this.getName() and
-    if exists(this.getDeclaringType())
-    then qualifier = this.getDeclaringType().getQualifiedName()
-    else qualifier = this.getNamespace().getQualifiedName()
+    exists(string name0 |
+      not this instanceof ConstructedType and
+      name = name0
+      or
+      name = name0 + "<" + this.getQualifiedTypeArguments() + ">"
+    |
+      exists(string enclosing |
+        this.getDeclaringType().hasQualifiedName(qualifier, enclosing) and
+        name0 = enclosing + "+" + this.getNameWithoutBrackets()
+      )
+      or
+      not exists(this.getDeclaringType()) and
+      qualifier = this.getNamespace().getQualifiedName() and
+      name0 = this.getNameWithoutBrackets()
+    )
   }
 
   /** Gets the namespace containing this type. */
@@ -994,6 +1027,13 @@ class ArrayType extends DotNet::ArrayType, RefType, @array_type {
     not type_location(this, _) and
     result = this.getElementType().getALocation()
   }
+
+  final override predicate hasQualifiedName(string qualifier, string name) {
+    exists(Type elementType, string name0 |
+      elementType.hasQualifiedName(qualifier, name0) and
+      name = name0 + this.getDimensionString(elementType)
+    )
+  }
 }
 
 /**
@@ -1013,6 +1053,13 @@ class PointerType extends DotNet::PointerType, Type, @pointer_type {
   override string toString() { result = DotNet::PointerType.super.toString() }
 
   override string getAPrimaryQlClass() { result = "PointerType" }
+
+  final override predicate hasQualifiedName(string qualifier, string name) {
+    exists(string name0 |
+      this.getReferentType().hasQualifiedName(qualifier, name0) and
+      name = name0 + "*"
+    )
+  }
 }
 
 /**
@@ -1083,6 +1130,10 @@ class TupleType extends ValueType, @tuple_type {
   override string getLabel() { result = getUnderlyingType().getLabel() }
 
   override Type getChild(int i) { result = this.getUnderlyingType().getChild(i) }
+
+  final override predicate hasQualifiedName(string qualifier, string name) {
+    this.getUnderlyingType().hasQualifiedName(qualifier, name)
+  }
 }
 
 /**