Rewrite handling of dependencies to use find_package

Moved all thirdparty handling code (or at least as much as possible) to
thirdparty/CMakeLists.txt. Now all dependencies are searched using
standard find_package() calls first, and if not found the config falls
back to use the appropiate submodule.

Also, updated gtest version (Latest gtest versions include a cmake
setup, which simplifies the config {no build external project script
needneeded}), and variant-lite to the latest release.

Author: Manu343726

CMakeLists.txt

@@ -29,9 +29,7 @@ else ()
 
 endif()
 
-set(BOOST_CMAKE_LIBRARIES filesystem algorithm variant optional CACHE INTERNAL "")
-add_subdirectory(thirdparty/boost EXCLUDE_FROM_ALL)
-add_subdirectory(thirdparty/nonstd EXCLUDE_FROM_ALL)
+add_subdirectory(thirdparty)
 
 if("${CMAKE_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_SOURCE_DIR}")
     set(JINJA2CPP_IS_MAIN_PROEJCT TRUE)
@@ -54,35 +52,18 @@ add_library(${LIB_TARGET_NAME} STATIC
     ${PublicHeaders}
     )
 
-target_link_libraries(${LIB_TARGET_NAME} PUBLIC ThirdParty::nonstd boost_variant boost_filesystem boost_algorithm)
+target_link_libraries(${LIB_TARGET_NAME} PUBLIC expected-lite variant-lite value-ptr-lite boost_variant boost_filesystem boost_algorithm)
 
 target_include_directories(${LIB_TARGET_NAME}
     PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/include)
 
 
 if(NOT MSVC)
-    # Enable -Werror and -Wall on jinja2cpp target, ignoring warning errors from thirdparty libs
-    include(CheckCXXCompilerFlag)
-    check_cxx_compiler_flag(-Wno-error=parentheses COMPILER_HAS_WNO_ERROR_PARENTHESES_FLAG)
-    check_cxx_compiler_flag(-Wno-error=deprecated-declarations COMPILER_HAS_WNO_ERROR_DEPRECATED_DECLARATIONS_FLAG)
-    check_cxx_compiler_flag(-Wno-error=maybe-uninitialized COMPILER_HAS_WNO_ERROR_MAYBE_UNINITIALIZED_FLAG)
-
-    if(COMPILER_HAS_WNO_ERROR_PARENTHESES_FLAG)
-        target_compile_options(boost_assert INTERFACE -Wno-error=parentheses)
-    endif()
-    if(COMPILER_HAS_WNO_ERROR_DEPRECATED_DECLARATIONS_FLAG)
-        target_compile_options(boost_filesystem PRIVATE -Wno-error=deprecated-declarations)
-    endif()
-    if(COMPILER_HAS_WNO_ERROR_MAYBE_UNINITIALIZED_FLAG)
-        target_compile_options(boost_variant INTERFACE -Wno-error=maybe-uninitialized)
-    endif()
-
     target_compile_options(${LIB_TARGET_NAME} PRIVATE -Wall -Werror)
 endif()
 
 if (JINJA2CPP_BUILD_TESTS)
     enable_testing()
-    add_subdirectory(thirdparty/gtest)
 
     CollectSources(TestSources TestHeaders ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/test)
     add_executable(jinja2cpp_tests ${TestSources} ${TestHeaders})

thirdparty/CMakeLists.txt

@@ -1,17 +1,85 @@
-cmake_minimum_required(VERSION 3.0)
 
-project (thirdparty)
-list (APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../cmake)
+find_package(expected-lite QUIET)
+if(expected-lite_FOUND)
+    add_library(expected-lite ALIAS expected-lite::expected-lite)
+else()
+    message(STATUS "expected-lite not found, using submodule")
+    add_subdirectory(nonstd/expected-light EXCLUDE_FROM_ALL)
+endif()
 
-include (build_thirdparty)
+find_package(variant-lite QUIET)
+if(variant-lite_FOUND)
+    add_library(variant-lite ALIAS variant-lite::variant-lite)
+else()
+    message(STATUS "variant-lite not found, using submodule")
+    add_subdirectory(nonstd/variant-light EXCLUDE_FROM_ALL)
+    # There's a bug in the lib, the target does not include the header include dirs.
+    # See https://github.com/martinmoene/variant-lite/issues/25
+    target_include_directories(variant-lite INTERFACE "${CMAKE_CURRENT_SOURCE_DIR}/nonstd/variant-light/include")
+endif()
 
-if (${CMAKE_CXX_COMPILER_ID} STREQUAL "MSVC")
-    if (MSVC_RUNTIME_TYPE STREQUAL "/MD" OR NOT MSVC_RUNTIME_TYPE)
-        set (GTEST_EXTRA_OPTIONS "-Dgtest_force_shared_crt=TRUE")
-    else ()
-        set (GTEST_EXTRA_OPTIONS "-Dgtest_force_shared_crt=TRUE")
-    endif ()
-endif ()
+find_package(value-ptr-lite QUIET)
+if(value-ptr-lite_FOUND)
+    add_library(value-ptr-lite ALIAS value-ptr-lite::value-ptr-lite)
+else()
+    message(STATUS "value-ptr-lite not found, using submodule")
+    add_subdirectory(nonstd/value-ptr-lite EXCLUDE_FROM_ALL)
+    add_library(value-ptr-lite ALIAS value_ptr-lite)
+endif()
 
-BuildThirdparty(gtest ${CMAKE_CURRENT_SOURCE_DIR}/gtest include/gmock/gmock.h "${GTEST_EXTRA_OPTIONS}")
-add_subdirectory (nonstd)
+find_package(boost_filesystem QUIET)
+find_package(boost_algorithm  QUIET)
+find_package(boost_variant    QUIET)
+find_package(boost_optional   QUIET)
+
+if(boost_filesystem_FOUND AND
+   boost_algorithm_FOUND  AND
+   boost_variant_FOUND    AND
+   boost_optional_FOUND)
+   add_library(boost_filesystem ALIAS boost_filesystem::boost_filesystem)
+   add_library(boost_algorithm  ALIAS boost_algorithm::boost_algorithm)
+   add_library(boost_variant    ALIAS boost_variant::boost_variant)
+   add_library(boost_optional   ALIAS boost_optional::boost_optional)
+else()
+    message(STATUS "One or more boost modules not found, using submodule")
+    set(BOOST_CMAKE_LIBRARIES filesystem algorithm variant optional CACHE INTERNAL "")
+    add_subdirectory(boost EXCLUDE_FROM_ALL)
+
+    if(NOT MSVC)
+        # Enable -Werror and -Wall on jinja2cpp target, ignoring warning errors from thirdparty libs
+        include(CheckCXXCompilerFlag)
+        check_cxx_compiler_flag(-Wno-error=parentheses COMPILER_HAS_WNO_ERROR_PARENTHESES_FLAG)
+        check_cxx_compiler_flag(-Wno-error=deprecated-declarations COMPILER_HAS_WNO_ERROR_DEPRECATED_DECLARATIONS_FLAG)
+        check_cxx_compiler_flag(-Wno-error=maybe-uninitialized COMPILER_HAS_WNO_ERROR_MAYBE_UNINITIALIZED_FLAG)
+
+        if(COMPILER_HAS_WNO_ERROR_PARENTHESES_FLAG)
+            target_compile_options(boost_assert INTERFACE -Wno-error=parentheses)
+        endif()
+        if(COMPILER_HAS_WNO_ERROR_DEPRECATED_DECLARATIONS_FLAG)
+            target_compile_options(boost_filesystem PRIVATE -Wno-error=deprecated-declarations)
+        endif()
+        if(COMPILER_HAS_WNO_ERROR_MAYBE_UNINITIALIZED_FLAG)
+            target_compile_options(boost_variant INTERFACE -Wno-error=maybe-uninitialized)
+        endif()
+    endif()
+endif()
+
+if(JINJA2CPP_BUILD_TESTS)
+    find_package(gtest QUIET)
+
+    if(gtest_FOUND)
+        add_library(gtest ALIAS gtest::gtest)
+    else()
+        message(STATUS "expected-lite not found, using submodule")
+
+        if(MSVC)
+            if (MSVC_RUNTIME_TYPE STREQUAL "/MD" OR NOT MSVC_RUNTIME_TYPE)
+                set (GTEST_EXTRA_OPTIONS "-Dgtest_force_shared_crt=TRUE" CACHE INTERNAL "")
+            else ()
+                set (GTEST_EXTRA_OPTIONS "-Dgtest_force_shared_crt=TRUE" CACHE INTERNAL "")
+            endif ()
+        endif ()
+
+        add_subdirectory(gtest EXCLUDE_FROM_ALL)
+    endif()
+endif()