Simplify test interface in FlowSummaryImpl.qll

Author: hvitved

csharp/ql/test/library-tests/dataflow/library/FlowSummaries.ql

@@ -2,32 +2,20 @@ import shared.FlowSummaries
 import semmle.code.csharp.dataflow.internal.ExternalFlow
 import External
 
-module TestSummaryInput implements TestSummaryInputSig {
-  class RelevantSummarizedCallable = IncludeSummarizedCallable;
-}
-
-module TestNeutralInput implements TestNeutralInputSig {
-  class RelevantNeutralCallable instanceof NeutralCallable {
-    final string getCallableCsv() { result = asPartialNeutralModel(this) }
+final private class NeutralCallableFinal = NeutralCallable;
 
-    string toString() { result = super.toString() }
-  }
+class RelevantNeutralCallable extends NeutralCallableFinal {
+  final string getCallableCsv() { result = asPartialNeutralModel(this) }
 }
 
-module TestSourceSinkInput implements TestSourceSinkInputSig {
-  class RelevantSourceCallable instanceof SourceCallable {
-    string getCallableCsv() { result = asPartialModel(this) }
-
-    string toString() { result = super.toString() }
-  }
-
-  class RelevantSinkCallable instanceof SinkCallable {
-    string getCallableCsv() { result = asPartialModel(this) }
+class RelevantSourceCallable extends SourceCallable {
+  string getCallableCsv() { result = asPartialModel(this) }
+}
 
-    string toString() { result = super.toString() }
-  }
+class RelevantSinkCallable extends SinkCallable {
+  string getCallableCsv() { result = asPartialModel(this) }
 }
 
-import TestSummaryOutput<TestSummaryInput>
-import TestNeutralOutput<TestNeutralInput>
-import TestSourceSinkOutput<TestSourceSinkInput>
+import TestSummaryOutput<IncludeSummarizedCallable>
+import TestNeutralOutput<RelevantNeutralCallable>
+import TestSourceSinkOutput<RelevantSourceCallable, RelevantSinkCallable>

csharp/ql/test/library-tests/dataflow/library/FlowSummariesFiltered.ql

@@ -1,13 +1,7 @@
 import shared.FlowSummaries
 private import semmle.code.csharp.dataflow.internal.ExternalFlow
 
-module TestSummaryInput implements TestSummaryInputSig {
-  class RelevantSummarizedCallable = IncludeSummarizedCallable;
-}
-
-import TestSummaryOutput<TestSummaryInput>
-
-class IncludeFilteredSummarizedCallable extends RelevantSummarizedCallable {
+class IncludeFilteredSummarizedCallable extends IncludeSummarizedCallable {
   /**
    * Holds if flow is propagated between `input` and `output` and
    * if there is no summary for a callable in a `base` class or interface
@@ -16,11 +10,13 @@ class IncludeFilteredSummarizedCallable extends RelevantSummarizedCallable {
   override predicate relevantSummary(
     SummaryComponentStack input, SummaryComponentStack output, boolean preservesValue
   ) {
-    this.(SummarizedCallableImpl).propagatesFlow(input, output, preservesValue) and
+    this.propagatesFlow(input, output, preservesValue) and
     not exists(IncludeSummarizedCallable rsc |
       isBaseCallableOrPrototype(rsc) and
       rsc.(SummarizedCallableImpl).propagatesFlow(input, output, preservesValue) and
       this.(UnboundCallable).overridesOrImplementsUnbound(rsc)
     )
   }
 }
+
+import TestSummaryOutput<IncludeFilteredSummarizedCallable>

csharp/ql/test/shared/FlowSummaries.qll

@@ -2,13 +2,21 @@ import semmle.code.csharp.dataflow.internal.FlowSummaryImpl::Private
 import semmle.code.csharp.dataflow.internal.FlowSummaryImpl::Public
 private import semmle.code.csharp.dataflow.internal.ExternalFlow
 
-class IncludeSummarizedCallable instanceof SummarizedCallableImpl {
+final private class SummarizedCallableImplFinal = SummarizedCallableImpl;
+
+class IncludeSummarizedCallable extends SummarizedCallableImplFinal {
   IncludeSummarizedCallable() {
     [this.(Modifiable), this.(Accessor).getDeclaration()].isEffectivelyPublic()
   }
 
   /** Gets a string representing the callable in semi-colon separated format for use in flow summaries. */
   final string getCallableCsv() { result = asPartialModel(this) }
 
+  predicate relevantSummary(
+    SummaryComponentStack input, SummaryComponentStack output, boolean preservesValue
+  ) {
+    this.propagatesFlow(input, output, preservesValue)
+  }
+
   string toString() { result = super.toString() }
 }

shared/dataflow/codeql/dataflow/internal/FlowSummaryImpl.qll

@@ -1692,39 +1692,27 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
           )
         }
 
-        signature module TestSourceSinkInputSig {
-          /**
-           * A class or source elements relevant for testing.
-           */
-          class RelevantSourceCallable instanceof SourceOrSinkElement {
-            /** Gets the string representation of this callable used by `source/1`. */
-            string getCallableCsv();
-          }
-
-          /**
-           * A class or sink elements relevant for testing.
-           */
-          class RelevantSinkCallable instanceof SourceOrSinkElement {
-            /** Gets the string representation of this callable used by `source/1`. */
-            string getCallableCsv();
-          }
+        /** A source or sink relevant for testing. */
+        signature class RelevantSourceOrSinkElementSig extends SourceOrSinkElement {
+          /** Gets the string representation of this callable used by `source/1` or `sink/1`. */
+          string getCallableCsv();
         }
 
         /** Provides query predicates for outputting a set of relevant sources and sinks. */
-        module TestSourceSinkOutput<TestSourceSinkInputSig TestSourceSinkInput> {
-          private import TestSourceSinkInput
-
+        module TestSourceSinkOutput<
+          RelevantSourceOrSinkElementSig RelevantSource, RelevantSourceOrSinkElementSig RelevantSink>
+        {
           /**
            * Holds if there exists a relevant source callable with information roughly corresponding to `csv`.
            * Used for testing.
            * The syntax is: "namespace;type;overrides;name;signature;ext;outputspec;kind;provenance",
            * ext is hardcoded to empty.
            */
           query predicate source(string csv) {
-            exists(RelevantSourceCallable c, string output, string kind, Provenance provenance |
-              sourceElement(c, output, kind, provenance) and
+            exists(RelevantSource s, string output, string kind, Provenance provenance |
+              sourceElement(s, output, kind, provenance) and
               csv =
-                c.getCallableCsv() // Callable information
+                s.getCallableCsv() // Callable information
                   + output + ";" // output
                   + kind + ";" // kind
                   + provenance // provenance
@@ -1738,10 +1726,10 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
            * ext is hardcoded to empty.
            */
           query predicate sink(string csv) {
-            exists(RelevantSinkCallable c, string input, string kind, Provenance provenance |
-              sinkElement(c, input, kind, provenance) and
+            exists(RelevantSink s, string input, string kind, Provenance provenance |
+              sinkElement(s, input, kind, provenance) and
               csv =
-                c.getCallableCsv() // Callable information
+                s.getCallableCsv() // Callable information
                   + input + ";" // input
                   + kind + ";" // kind
                   + provenance // provenance
@@ -1751,35 +1739,18 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
       }
     }
 
-    signature module TestSummaryInputSig {
-      /**
-       * A class of callables where the flow summary should be included
-       * in the `summary/1` query predicate.
-       */
-      class RelevantSummarizedCallable instanceof SummarizedCallableImpl {
-        /** Gets the string representation of this callable used by `summary/1`. */
-        string getCallableCsv();
-      }
+    /** A summarized callable relevant for testing. */
+    signature class RelevantSummarizedCallableSig extends SummarizedCallableImpl {
+      /** Gets the string representation of this callable used by `summary/1`. */
+      string getCallableCsv();
+
+      predicate relevantSummary(
+        SummaryComponentStack input, SummaryComponentStack output, boolean preservesValue
+      );
     }
 
     /** Provides a query predicate for outputting a set of relevant flow summaries. */
-    module TestSummaryOutput<TestSummaryInputSig TestInput> {
-      private import TestInput
-
-      final class RelevantSummarizedCallableFinal = TestInput::RelevantSummarizedCallable;
-
-      class RelevantSummarizedCallable extends RelevantSummarizedCallableFinal instanceof SummarizedCallableImpl
-      {
-        /** Holds if flow is propagated between `input` and `output`. */
-        predicate relevantSummary(
-          SummaryComponentStack input, SummaryComponentStack output, boolean preservesValue
-        ) {
-          super.propagatesFlow(input, output, preservesValue)
-        }
-
-        string toString() { result = super.toString() }
-      }
-
+    module TestSummaryOutput<RelevantSummarizedCallableSig RelevantSummarizedCallable> {
       /** Render the kind in the format used in flow summaries. */
       private string renderKind(boolean preservesValue) {
         preservesValue = true and result = "value"
@@ -1816,31 +1787,13 @@ module Make<DF::InputSig DataFlowLang, InputSig<DataFlowLang> Input> {
       }
     }
 
-    signature module TestNeutralInputSig {
-      /**
-       * A class of callables where the neutral model should be included
-       * in the `neutral/1` query predicate.
-       */
-      class RelevantNeutralCallable instanceof NeutralCallable {
-        /** Gets the string representation of this callable used by `neutral/1`. */
-        string getCallableCsv();
-      }
+    /** A summarized callable relevant for testing. */
+    signature class RelevantNeutralCallableSig extends NeutralCallable {
+      /** Gets the string representation of this callable used by `neutral/1`. */
+      string getCallableCsv();
     }
 
-    module TestNeutralOutput<TestNeutralInputSig TestInput> {
-      private import TestInput
-
-      final class RelevantNeutralCallableFinal = TestInput::RelevantNeutralCallable;
-
-      class RelevantNeutralCallable extends RelevantNeutralCallableFinal instanceof NeutralCallable {
-        /**
-         * Gets the kind of the neutral.
-         */
-        string getKind() { result = super.getKind() }
-
-        string toString() { result = super.toString() }
-      }
-
+    module TestNeutralOutput<RelevantNeutralCallableSig RelevantNeutralCallable> {
       private string renderProvenance(NeutralCallable c) {
         exists(Provenance p | p.isManual() and c.hasProvenance(p) and result = p.toString())
         or