Overlay.qll: Streamline discardable entities into one Discardable superclass

Author: d10c

python/ql/lib/semmle/python/Overlay.qll

@@ -14,30 +14,71 @@ overlay[local]
 predicate isOverlay() { databaseMetadata("isOverlay", "true") }
 
 overlay[local]
-private string getRawPathForLocation(@location loc) {
+private string getPathForLocation(@location loc) {
   exists(@file file | locations_default(loc, file, _, _, _, _) | files(file, result))
   or
-  exists(@py_Module mod | locations_ast(loc, mod, _, _, _, _) | result = getRawPathForModule(mod))
+  exists(@py_Module mod | locations_ast(loc, mod, _, _, _, _) | result = getPathForModule(mod))
 }
 
 overlay[local]
-private string getRawPathForModule(@py_Module mod) {
+private string getPathForModule(@py_Module mod) {
   exists(@container fileOrFolder | py_module_path(mod, fileOrFolder) |
-    result = getRawPathForContainer(fileOrFolder)
+    result = getPathForContainer(fileOrFolder)
   )
 }
 
 overlay[local]
-private string getRawPathForContainer(@container fileOrFolder) {
+private string getPathForContainer(@container fileOrFolder) {
   files(fileOrFolder, result) or folders(fileOrFolder, result)
 }
 
-/*- Source elements -*/
+/*- Discardable entities and their discard predicates -*/
+overlay[local]
+private class Discardable_ = @py_source_element or @py_flow_node or @py_base_var or @location;
+
+overlay[discard_entity]
+private predicate discardEntity(@py_source_element el) {
+  // Within `@py_source_element`, only `@py_Module` and `@container`
+  // use named IDs; the rest use *-ids.
+  exists(Discardable d | d = el |
+    overlayChangedFiles(d.getPath()) and
+    d.existsInBase() and
+    not d.existsInOverlay()
+  )
+}
+
+overlay[discard_entity]
+private predicate discardCfgNode(@py_flow_node n) {
+  // `@py_flow_node`s use *-ids, so cannot exist both in base and overlay.
+  exists(Discardable d | d = n |
+    overlayChangedFiles(d.getPath()) and
+    d.existsInBase()
+  )
+}
+
+overlay[discard_entity]
+private predicate discardVar(@py_base_var n) {
+  // `@py_base_var`s use *-ids, so cannot exist both in base and overlay.
+  exists(Discardable d | d = n |
+    overlayChangedFiles(d.getPath()) and
+    d.existsInBase()
+  )
+}
+
+overlay[discard_entity]
+private predicate discardLocation(@location loc) {
+  // Locations use *-ids, so cannot exist both in base and overlay.
+  exists(Discardable d | d = loc |
+    overlayChangedFiles(d.getPath()) and
+    d.existsInBase()
+  )
+}
+
 /**
  * An abstract base class for all elements that can be discarded from the base.
  */
 overlay[local]
-abstract private class Discardable extends @py_source_element {
+abstract private class Discardable extends Discardable_ {
   /** Gets the path to the file in which this element occurs. */
   abstract string getPath();
 
@@ -51,98 +92,51 @@ abstract private class Discardable extends @py_source_element {
   string toString() { none() }
 }
 
-overlay[discard_entity]
-private predicate discardEntity(@py_source_element el) {
-  exists(Discardable d | d = el |
-    overlayChangedFiles(d.getPath()) and
-    d.existsInBase() and
-    not d.existsInOverlay()
-  )
-}
-
 /**
- * Discard all locatable AST nodes (`@py_location_parent`) in modified files
- * since they use *-ids and hence cannot be referenced across TRAP files.
+ * Discardable locatable AST nodes (`@py_location_parent`).
  */
 overlay[local]
 final private class DiscardableLocatable extends Discardable instanceof @py_location_parent {
   override string getPath() {
-    exists(@location loc | py_locations(loc, this) | result = getRawPathForLocation(loc))
+    exists(@location loc | py_locations(loc, this) | result = getPathForLocation(loc))
   }
 }
 
 /**
- * Discard scopes (classes, functions, modules) that were deleted in the overlay.
+ * Discardable scopes (classes, functions, modules).
  */
 overlay[local]
 final private class DiscardableScope extends Discardable instanceof @py_scope {
   override string getPath() {
-    exists(@location loc | py_scope_location(loc, this) | result = getRawPathForLocation(loc))
+    exists(@location loc | py_scope_location(loc, this) | result = getPathForLocation(loc))
     or
-    result = getRawPathForModule(this)
+    result = getPathForModule(this)
   }
 }
 
 /**
- * Discard files and folders that were deleted in the overlay.
+ * Discardable files and folders.
  */
 overlay[local]
 final private class DiscardableContainer extends Discardable instanceof @container {
-  override string getPath() { result = getRawPathForContainer(this) }
+  override string getPath() { result = getPathForContainer(this) }
 }
 
-/*- CFG Nodes -*/
 /** Discardable control flow nodes */
 overlay[local]
-final private class DiscardableCfgNode instanceof @py_flow_node {
-  string getPath() {
+final private class DiscardableCfgNode extends Discardable instanceof @py_flow_node {
+  override string getPath() {
     exists(Discardable d | result = d.getPath() |
       py_flow_bb_node(this, d.(@py_ast_node), _, _)
       or
       py_scope_flow(this, d.(@py_scope), _)
     )
   }
-
-  predicate existsInBase() { not isOverlay() and exists(this) }
-
-  predicate existsInOverlay() { isOverlay() and exists(this) }
-
-  string toString() { none() }
-}
-
-overlay[discard_entity]
-private predicate discardCfgNode(@py_flow_node n) {
-  exists(DiscardableCfgNode d | d = n |
-    overlayChangedFiles(d.getPath()) and
-    d.existsInBase() and
-    not d.existsInOverlay()
-  )
-}
-
-/*- Variables -*/
-/** Discardable (normal and SSA) variables */
-overlay[local]
-abstract private class DiscardableBaseVar instanceof @py_base_var {
-  abstract string getPath();
-
-  predicate existsInBase() { not isOverlay() and exists(this) }
-
-  predicate existsInOverlay() { isOverlay() and exists(this) }
-
-  string toString() { none() }
-}
-
-overlay[discard_entity]
-private predicate discardVar(@py_base_var n) {
-  exists(DiscardableVar d | d = n |
-    overlayChangedFiles(d.getPath()) and
-    d.existsInBase() and
-    not d.existsInOverlay()
-  )
 }
 
+/** Discardable Python variables. */
 overlay[local]
-final private class DiscardableVar extends DiscardableBaseVar instanceof @py_variable {
+final private class DiscardableVar extends Discardable instanceof @py_variable {
   override string getPath() {
     exists(Discardable parent | result = parent.getPath() |
       variable(this, parent.(@py_scope), _)
@@ -152,8 +146,9 @@ final private class DiscardableVar extends DiscardableBaseVar instanceof @py_var
   }
 }
 
+/** Discardable SSA variables. */
 overlay[local]
-final private class DiscardableSsaVar extends DiscardableBaseVar instanceof @py_ssa_var {
+final private class DiscardableSsaVar extends Discardable instanceof @py_ssa_var {
   override string getPath() {
     exists(DiscardableSsaVar other | result = other.getPath() |
       py_ssa_phi(this, other.(@py_ssa_var))
@@ -169,18 +164,10 @@ final private class DiscardableSsaVar extends DiscardableBaseVar instanceof @py_
   }
 }
 
-/*- Locations -*/
+/** Discardable locations. */
 overlay[local]
-private predicate locationExistsInBase(@location loc) { not isOverlay() and exists(loc) }
-
-overlay[local]
-private predicate locationExistsInOverlay(@location loc) { isOverlay() and exists(loc) }
-
-overlay[discard_entity]
-private predicate discardLocation(@location loc) {
-  overlayChangedFiles(getRawPathForLocation(loc)) and
-  locationExistsInBase(loc) and
-  not locationExistsInOverlay(loc)
+final private class DiscardableLocation extends Discardable instanceof @location {
+  override string getPath() { result = getPathForLocation(this) }
 }
 
 /*- XML -*/