|
| 1 | +/** Provides classes and predicates to reason about XML external entities (XXE) vulnerabilities. */ |
| 2 | + |
| 3 | +import swift |
| 4 | +private import codeql.swift.dataflow.DataFlow |
| 5 | + |
| 6 | +/** A data flow sink for XML external entities (XXE) vulnerabilities. */ |
| 7 | +abstract class XxeSink extends DataFlow::Node { } |
| 8 | + |
| 9 | +/** A sanitizer for XML external entities (XXE) vulnerabilities. */ |
| 10 | +abstract class XxeSanitizer extends DataFlow::Node { } |
| 11 | + |
| 12 | +/** |
| 13 | + * A unit class for adding additional taint steps. |
| 14 | + * |
| 15 | + * Extend this class to add additional taint steps that should apply to paths related to |
| 16 | + * XML external entities (XXE) vulnerabilities. |
| 17 | + */ |
| 18 | +class XxeAdditionalTaintStep extends Unit { |
| 19 | + abstract predicate step(DataFlow::Node n1, DataFlow::Node n2); |
| 20 | +} |
| 21 | + |
| 22 | +/** The XML argument of a `XMLParser` vulnerable to XXE. */ |
| 23 | +private class DefaultXxeSink extends XxeSink { |
| 24 | + DefaultXxeSink() { |
| 25 | + this.asExpr() = any(Argument a | a.getApplyExpr() instanceof VulnerableParser).getExpr() |
| 26 | + } |
| 27 | +} |
| 28 | + |
| 29 | +/** The construction of a `XMLParser` that enables external entities. */ |
| 30 | +private class VulnerableParser extends CallExpr { |
| 31 | + VulnerableParser() { |
| 32 | + resolvesExternalEntities(this) and this.getFunction() instanceof ConstructorRefCallExpr |
| 33 | + } |
| 34 | +} |
| 35 | + |
| 36 | +/** Holds if there is an access of `ref` that sets `shouldResolveExternalEntities` to `true`. */ |
| 37 | +private predicate resolvesExternalEntities(XmlParserRef ref) { |
| 38 | + exists(XmlParserRef base | |
| 39 | + DataFlow::localExprFlow(ref, base) or DataFlow::localExprFlow(base, ref) |
| 40 | + | |
| 41 | + exists(AssignExpr assign, ShouldResolveExternalEntities s, BooleanLiteralExpr b | |
| 42 | + s.getBase() = base and |
| 43 | + assign.getDest() = s and |
| 44 | + b.getValue() = true and |
| 45 | + DataFlow::localExprFlow(b, assign.getSource()) |
| 46 | + ) |
| 47 | + ) |
| 48 | +} |
| 49 | + |
| 50 | +/** A reference to the field `XMLParser.shouldResolveExternalEntities`. */ |
| 51 | +private class ShouldResolveExternalEntities extends MemberRefExpr { |
| 52 | + ShouldResolveExternalEntities() { |
| 53 | + this.getMember().(FieldDecl).getName() = "shouldResolveExternalEntities" and |
| 54 | + this.getBase() instanceof XmlParserRef |
| 55 | + } |
| 56 | +} |
| 57 | + |
| 58 | +/** An expression of type `XMLParser`. */ |
| 59 | +private class XmlParserRef extends Expr { |
| 60 | + XmlParserRef() { |
| 61 | + this.getType() instanceof XmlParserType or |
| 62 | + this.getType() = any(OptionalType t | t.getBaseType() instanceof XmlParserType) |
| 63 | + } |
| 64 | +} |
| 65 | + |
| 66 | +/** The type `XMLParser`. */ |
| 67 | +private class XmlParserType extends NominalType { |
| 68 | + XmlParserType() { this.getFullName() = "XMLParser" } |
| 69 | +} |
0 commit comments