Ruby: use new dataflow api in Faraday.qll

Author: alexrford

ruby/ql/lib/codeql/ruby/frameworks/http_clients/Faraday.qll

@@ -7,7 +7,6 @@ private import codeql.ruby.CFG
 private import codeql.ruby.Concepts
 private import codeql.ruby.ApiGraphs
 private import codeql.ruby.DataFlow
-private import codeql.ruby.dataflow.internal.DataFlowImplForHttpClientLibraries as DataFlowImplForHttpClientLibraries
 
 /**
  * A call that makes an HTTP request using `Faraday`.
@@ -78,32 +77,29 @@ class FaradayHttpRequest extends Http::Client::Request::Range, DataFlow::CallNod
   override predicate disablesCertificateValidation(
     DataFlow::Node disablingNode, DataFlow::Node argumentOrigin
   ) {
-    any(FaradayDisablesCertificateValidationConfiguration config)
-        .hasFlow(argumentOrigin, disablingNode) and
+    FaradayDisablesCertificateValidationFlow::flow(argumentOrigin, disablingNode) and
     disablingNode = this.getCertificateValidationControllingValue(_)
   }
 
   override string getFramework() { result = "Faraday" }
 }
 
 /** A configuration to track values that can disable certificate validation for Faraday. */
-private class FaradayDisablesCertificateValidationConfiguration extends DataFlowImplForHttpClientLibraries::Configuration
-{
-  FaradayDisablesCertificateValidationConfiguration() {
-    this = "FaradayDisablesCertificateValidationConfiguration"
-  }
+private module FaradayDisablesCertificateValidationConfig implements DataFlow::StateConfigSig {
+  class FlowState = string;
 
-  override predicate isSource(
-    DataFlow::Node source, DataFlowImplForHttpClientLibraries::FlowState state
-  ) {
+  predicate isSource(DataFlow::Node source, FlowState state) {
     source.asExpr().getExpr().(BooleanLiteral).isFalse() and
     state = "verify"
     or
     source = API::getTopLevelMember("OpenSSL").getMember("SSL").getMember("VERIFY_NONE").asSource() and
     state = "verify_mode"
   }
 
-  override predicate isSink(DataFlow::Node sink, DataFlowImplForHttpClientLibraries::FlowState state) {
+  predicate isSink(DataFlow::Node sink, FlowState state) {
     sink = any(FaradayHttpRequest req).getCertificateValidationControllingValue(state)
   }
 }
+
+private module FaradayDisablesCertificateValidationFlow =
+  DataFlow::GlobalWithState<FaradayDisablesCertificateValidationConfig>;