Swift: Add model for URL.resourceBytes and URL.lines.

Author: geoffw0

swift/ql/lib/codeql/swift/dataflow/ExternalFlow.qll

@@ -79,6 +79,7 @@ private import internal.FlowSummaryImplSpecific
  */
 private module Frameworks {
   private import codeql.swift.frameworks.StandardLibrary.String
+  private import codeql.swift.frameworks.StandardLibrary.Url
 }
 
 /**

swift/ql/lib/codeql/swift/frameworks/StandardLibrary/Url.qll

@@ -0,0 +1,27 @@
+import swift
+private import codeql.swift.dataflow.FlowSources
+
+/**
+ * Model certain members of `URL` as sources of remote flow.
+ */
+class UrlRemoteFlowSource extends RemoteFlowSource {
+  UrlRemoteFlowSource() {
+    exists(StructDecl urlClass, ConcreteVarDecl memberDecl |
+      urlClass.getName() = "URL" and
+      (
+        urlClass.getAMember() = memberDecl and
+        memberDecl.getName() = ["resourceBytes", "lines"]
+        or
+        exists(StructDecl asyncBytesClass |
+          urlClass.getAMember() = asyncBytesClass and
+          asyncBytesClass.getName() = "AsyncBytes" and
+          asyncBytesClass.getAMember() = memberDecl and
+          memberDecl.getName() = "lines"
+        )
+      ) and
+      this.asExpr().(MemberRefExpr).getMember() = memberDecl
+    )
+  }
+
+  override string getSourceType() { result = "external" }
+}

swift/ql/test/library-tests/dataflow/flowsources/FlowSources.expected

@@ -1,2 +1,5 @@
 | string.swift:27:21:27:21 | call to init(contentsOf:) | external |
 | string.swift:27:21:27:44 | call to init(contentsOf:) | external |
+| url.swift:53:15:53:19 | .resourceBytes | external |
+| url.swift:60:15:60:19 | .lines | external |
+| url.swift:67:16:67:22 | .lines | external |