DeadCode: Add MISRA C 2012 Rule 2.6

Adds a query to find unused labels. We consider a label unused if we
never "goto" the label and never take the address of the label.

Author: lcartey

c/misra/src/rules/RULE-2-6/UnusedLabelDeclaration.ql

@@ -0,0 +1,25 @@
+/**
+ * @id c/misra/unused-label-declaration
+ * @name RULE-2-6: A function should not contain unused label declarations
+ * @description Unused label declarations are either redundant or indicate a possible mistake on the
+ *              part of the programmer.
+ * @kind problem
+ * @precision very-high
+ * @problem.severity warning
+ * @tags external/misra/id/rule-2-6
+ *       readability
+ *       maintainability
+ *       external/misra/obligation/advisory
+ */
+
+import cpp
+import codingstandards.c.misra
+
+from LabelStmt label
+where
+  not isExcluded(label, DeadCodePackage::unusedLabelDeclarationQuery()) and
+  // No GotoStmt jumps to this label
+  not exists(GotoStmt gs | gs.hasName() and gs.getTarget() = label) and
+  // The address of the label is never taken
+  not exists(LabelLiteral literal | literal.getLabel() = label)
+select label, "Label " + label.getName() + " is unused."

c/misra/test/rules/RULE-2-6/UnusedLabelDeclaration.expected

@@ -0,0 +1,3 @@
+| test.c:2:1:2:13 | label ...: | Label dead_label_1 is unused. |
+| test.c:6:1:6:13 | label ...: | Label dead_label_2 is unused. |
+| test.c:8:1:8:13 | label ...: | Label dead_label_3 is unused. |

c/misra/test/rules/RULE-2-6/UnusedLabelDeclaration.qlref

@@ -0,0 +1 @@
+rules/RULE-2-6/UnusedLabelDeclaration.ql

c/misra/test/rules/RULE-2-6/test.c

@@ -0,0 +1,17 @@
+void test1(int p1) {
+dead_label_1: // NON_COMPLIANT
+live_label_1: // COMPLIANT
+  int x = 0;
+live_label_2: // COMPLIANT
+dead_label_2: // NON_COMPLIANT
+  int y = 0;
+dead_label_3: // NON_COMPLIANT
+  int z = 0;
+
+  if (p1 > 1) {
+    goto live_label_1;
+  }
+
+  // Taking the address of a label is sufficient to make it "live"
+  void *label_ptr = &&live_label_2;
+}