Declarations8: add rule DCL30-C

Author: knewbury01

.vscode/tasks.json

@@ -211,6 +211,7 @@
                 "Declarations5",
                 "Declarations6",
                 "Declarations7",
+                "Declarations8",
                 "Exceptions1",
                 "Exceptions2",
                 "Expressions",

c/cert/src/rules/DCL30-C/DeclareObjectsWithAppropriateStorageDurations.md

@@ -0,0 +1,18 @@
+# DCL30-C: Declare objects with appropriate storage durations
+
+This query implements the CERT-C rule DCL30-C:
+
+> Declare objects with appropriate storage durations
+
+
+## CERT
+
+** REPLACE THIS BY RUNNING THE SCRIPT `scripts/help/cert-help-extraction.py` **
+
+## Implementation notes
+
+The rule checks specifically for pointers to objects with automatic storage duration with respect to the following cases: returned by functions, assigned to function output parameters and assigned to static storage duration variables.
+
+## References
+
+* CERT-C: [DCL30-C: Declare objects with appropriate storage durations](https://wiki.sei.cmu.edu/confluence/display/c)

c/cert/src/rules/DCL30-C/DeclareObjectsWithAppropriateStorageDurations.ql

@@ -0,0 +1,58 @@
+/**
+ * @id c/cert/declare-objects-with-appropriate-storage-durations
+ * @name DCL30-C: Declare objects with appropriate storage durations
+ * @description When storage durations are not compatible between assigned pointers it can lead to
+ *              referring to objects outside of their lifetime, which is undefined behaviour.
+ * @kind problem
+ * @precision high
+ * @problem.severity error
+ * @tags external/cert/id/dcl30-c
+ *       correctness
+ *       external/cert/obligation/rule
+ */
+
+import cpp
+import codingstandards.c.cert
+import codingstandards.cpp.FunctionParameter
+import semmle.code.cpp.dataflow.DataFlow
+
+class Source extends StackVariable {
+  Source() { not this instanceof FunctionParameter }
+}
+
+abstract class Sink extends DataFlow::Node { }
+
+class FunctionSink extends Sink {
+  FunctionSink() {
+    //output parameter
+    exists(FunctionParameter f |
+      f.getAnAccess() = this.(DataFlow::PostUpdateNode).getPreUpdateNode().asExpr() and
+      f.getUnderlyingType() instanceof PointerType
+    )
+    or
+    //function returns pointer
+    exists(Function f, ReturnStmt r |
+      f.getType() instanceof PointerType and
+      r.getEnclosingFunction() = f and
+      r.getExpr() = this.asExpr()
+    )
+  }
+}
+
+class StaticSink extends Sink {
+  StaticSink() {
+    exists(StaticStorageDurationVariable s |
+      this.(DataFlow::PostUpdateNode).getPreUpdateNode().asExpr() = s.getAnAccess() and
+      s.getUnderlyingType() instanceof PointerType
+    )
+  }
+}
+
+from DataFlow::Node src, DataFlow::Node sink
+where
+  not isExcluded(sink.asExpr(),
+    Declarations8Package::declareObjectsWithAppropriateStorageDurationsQuery()) and
+  exists(Source s | src.asExpr() = s.getAnAccess()) and
+  sink instanceof Sink and
+  DataFlow::localFlow(src, sink)
+select sink, "$@ with automatic storage may be accessible outside of its lifetime.", src, src.toString()

c/cert/test/rules/DCL30-C/DeclareObjectsWithAppropriateStorageDurations.expected

@@ -0,0 +1,4 @@
+| test.c:3:10:3:10 | a | $@ with automatic storage may be accessible outside of its lifetime. | test.c:3:10:3:10 | a | a |
+| test.c:15:4:15:8 | param [inner post update] | $@ with automatic storage may be accessible outside of its lifetime. | test.c:15:12:15:13 | a2 | a2 |
+| test.c:21:3:21:3 | g [post update] | $@ with automatic storage may be accessible outside of its lifetime. | test.c:21:7:21:8 | a3 | a3 |
+| test.c:32:3:32:3 | g [post update] | $@ with automatic storage may be accessible outside of its lifetime. | test.c:32:7:32:8 | a5 | a5 |

c/cert/test/rules/DCL30-C/DeclareObjectsWithAppropriateStorageDurations.qlref

@@ -0,0 +1 @@
+rules/DCL30-C/DeclareObjectsWithAppropriateStorageDurations.ql

c/cert/test/rules/DCL30-C/test.c

@@ -0,0 +1,34 @@
+char *f(void) {
+  char a[1];
+  return a; // NON_COMPLIANT
+}
+
+char f1(void) {
+  char a1[1];
+  a1[0] = 'a';
+  return a1[0]; // COMPLIANT
+}
+
+void f2(char **param) {
+  char a2[1];
+  a2[0] = 'a';
+  *param = a2; // NON_COMPLIANT
+}
+
+const char *g;
+void f3(void) {
+  const char a3[] = "test";
+  g = a3; // NON_COMPLIANT
+}
+
+void f4(void) {
+  const char a4[] = "test";
+  const char *p = a4; // COMPLIANT
+}
+
+#include <stdlib.h>
+void f5(void) {
+  const char a5[] = "test";
+  g = a5; // COMPLIANT[FALSE_POSITIVE]
+  g = NULL;
+}

cpp/common/src/codingstandards/cpp/exclusions/c/Declarations8.qll

@@ -0,0 +1,26 @@
+//** THIS FILE IS AUTOGENERATED, DO NOT MODIFY DIRECTLY.  **/
+import cpp
+import RuleMetadata
+import codingstandards.cpp.exclusions.RuleMetadata
+
+newtype Declarations8Query = TDeclareObjectsWithAppropriateStorageDurationsQuery()
+
+predicate isDeclarations8QueryMetadata(Query query, string queryId, string ruleId, string category) {
+  query =
+    // `Query` instance for the `declareObjectsWithAppropriateStorageDurations` query
+    Declarations8Package::declareObjectsWithAppropriateStorageDurationsQuery() and
+  queryId =
+    // `@id` for the `declareObjectsWithAppropriateStorageDurations` query
+    "c/cert/declare-objects-with-appropriate-storage-durations" and
+  ruleId = "DCL30-C" and
+  category = "rule"
+}
+
+module Declarations8Package {
+  Query declareObjectsWithAppropriateStorageDurationsQuery() {
+    //autogenerate `Query` type
+    result =
+      // `Query` type for `declareObjectsWithAppropriateStorageDurations` query
+      TQueryC(TDeclarations8PackageQuery(TDeclareObjectsWithAppropriateStorageDurationsQuery()))
+  }
+}

cpp/common/src/codingstandards/cpp/exclusions/c/RuleMetadata.qll

@@ -22,6 +22,7 @@ import Declarations4
 import Declarations5
 import Declarations6
 import Declarations7
+import Declarations8
 import Expressions
 import IO1
 import IO2
@@ -67,6 +68,7 @@ newtype TCQuery =
   TDeclarations5PackageQuery(Declarations5Query q) or
   TDeclarations6PackageQuery(Declarations6Query q) or
   TDeclarations7PackageQuery(Declarations7Query q) or
+  TDeclarations8PackageQuery(Declarations8Query q) or
   TExpressionsPackageQuery(ExpressionsQuery q) or
   TIO1PackageQuery(IO1Query q) or
   TIO2PackageQuery(IO2Query q) or
@@ -112,6 +114,7 @@ predicate isQueryMetadata(Query query, string queryId, string ruleId, string cat
   isDeclarations5QueryMetadata(query, queryId, ruleId, category) or
   isDeclarations6QueryMetadata(query, queryId, ruleId, category) or
   isDeclarations7QueryMetadata(query, queryId, ruleId, category) or
+  isDeclarations8QueryMetadata(query, queryId, ruleId, category) or
   isExpressionsQueryMetadata(query, queryId, ruleId, category) or
   isIO1QueryMetadata(query, queryId, ruleId, category) or
   isIO2QueryMetadata(query, queryId, ruleId, category) or

rule_packages/c/Declarations8.json

@@ -0,0 +1,26 @@
+{
+  "CERT-C": {
+    "DCL30-C": {
+      "properties": {
+        "obligation": "rule"
+      },
+      "queries": [
+        {
+          "description": "When storage durations are not compatible between assigned pointers it can lead to referring to objects outside of their lifetime, which is undefined behaviour.",
+          "kind": "problem",
+          "name": "Declare objects with appropriate storage durations",
+          "precision": "high",
+          "severity": "error",
+          "short_name": "DeclareObjectsWithAppropriateStorageDurations",
+          "tags": [
+            "correctness"
+          ],
+          "implementation_scope": {
+            "description": "The rule checks specifically for pointers to objects with automatic storage duration with respect to the following cases: returned by functions, assigned to function output parameters and assigned to static storage duration variables."
+          }
+        }
+      ],
+      "title": "Declare objects with appropriate storage durations"
+    }
+  }
+}

rules.csv

@@ -498,7 +498,7 @@ c,CERT-C,CON39-C,Yes,Rule,,,Do not join or detach a thread that was previously j
 c,CERT-C,CON40-C,Yes,Rule,,,Do not refer to an atomic variable twice in an expression,,Concurrency5,Medium,
 c,CERT-C,CON41-C,Yes,Rule,,,Wrap functions that can fail spuriously in a loop,CON53-CPP,Concurrency3,Medium,
 c,CERT-C,CON43-C,OutOfScope,Rule,,,Do not allow data races in multithreaded code,,,,
-c,CERT-C,DCL30-C,Yes,Rule,,,Declare objects with appropriate storage durations,,Declarations,Hard,
+c,CERT-C,DCL30-C,Yes,Rule,,,Declare objects with appropriate storage durations,,Declarations8,Hard,
 c,CERT-C,DCL31-C,Yes,Rule,,,Declare identifiers before using them,,Declarations1,Medium,
 c,CERT-C,DCL36-C,No,Rule,,,Do not declare an identifier with conflicting linkage classifications,,,,
 c,CERT-C,DCL37-C,Yes,Rule,,,Do not declare or define a reserved identifier,,Declarations1,Easy,