EssentialTypes: Implement Rule 10.8

Adds a query to check for inappropriate casts of composite expressions
to wider essential types.

Author: lcartey

c/misra/src/rules/RULE-10-8/InappropriateCastOfCompositeExpression.ql

@@ -0,0 +1,38 @@
+/**
+ * @id c/misra/inappropriate-cast-of-composite-expression
+ * @name RULE-10-8: The value of a composite expression shall not be cast to a different essential type category or a
+ * @description The value of a composite expression shall not be cast to a different essential type
+ *              category or a wider essential type
+ * @kind problem
+ * @precision very-high
+ * @problem.severity error
+ * @tags external/misra/id/rule-10-8
+ *       external/misra/obligation/required
+ */
+
+import cpp
+import codingstandards.c.misra
+import codingstandards.c.misra.EssentialTypes
+import codingstandards.c.misra.MisraExpressions
+
+from
+  Cast c, CompositeExpression ce, Type castEssentialType, Type compositeExprEssentialType,
+  EssentialTypeCategory castTypeCategory, EssentialTypeCategory compositeTypeCategory,
+  string message
+where
+  not isExcluded(ce, EssentialTypesPackage::inappropriateCastOfCompositeExpressionQuery()) and
+  c = ce.getExplicitlyConverted() and
+  compositeExprEssentialType = getEssentialTypeBeforeConversions(ce) and
+  castEssentialType = c.getType() and
+  castTypeCategory = getEssentialTypeCategory(castEssentialType) and
+  compositeTypeCategory = getEssentialTypeCategory(compositeExprEssentialType) and
+  (
+    not castTypeCategory = compositeTypeCategory and
+    message =
+      "Cast from " + compositeTypeCategory + " to " + castTypeCategory + " changes type category."
+    or
+    castTypeCategory = compositeTypeCategory and
+    castEssentialType.getSize() > compositeExprEssentialType.getSize() and
+    message = "Cast from " + compositeTypeCategory + " to " + castTypeCategory + " widens type."
+  )
+select ce, message

c/misra/test/rules/RULE-10-8/InappropriateCastOfCompositeExpression.expected

@@ -0,0 +1,4 @@
+| test.c:4:16:4:20 | ... + ... | Cast from essentially Unsigned type to essentially Signed type changes type category. |
+| test.c:5:18:5:22 | ... + ... | Cast from essentially Signed type to essentially Unsigned type changes type category. |
+| test.c:14:18:14:24 | ... + ... | Cast from essentially Unsigned type to essentially Unsigned type widens type. |
+| test.c:20:16:20:22 | ... + ... | Cast from essentially Signed type to essentially Signed type widens type. |

c/misra/test/rules/RULE-10-8/InappropriateCastOfCompositeExpression.qlref

@@ -0,0 +1 @@
+rules/RULE-10-8/InappropriateCastOfCompositeExpression.ql

c/misra/test/rules/RULE-10-8/test.c

@@ -0,0 +1,22 @@
+void testDifferentEssentialType() {
+  unsigned int u = 1;
+  signed int s = 1;
+  (signed int)(u + u);   // NON_COMPLIANT
+  (unsigned int)(s + s); // NON_COMPLIANT
+  (signed int)(s + s);   // COMPLIANT
+  (unsigned int)(u + u); // COMPLIANT
+}
+
+void testWiderType() {
+  unsigned short us = 1;
+  unsigned int u = 1;
+
+  (unsigned int)(us + us); // NON_COMPLIANT
+  (unsigned short)(u + u); // COMPLIANT
+
+  signed short ss = 1;
+  signed int s = 1;
+
+  (signed int)(ss + ss); // NON_COMPLIANT
+  (signed short)(s + s); // COMPLIANT
+}