Core: new "AllowInfix" enum for underscores

This paves the way for allowing people to use MACRO_CASE
or snake_case in their configurations.

Author: knocte

src/FSharpLint.Core/Framework/Rules.fs

@@ -58,6 +58,7 @@ type NamingUnderscores =
     | None = 0
     | AllowPrefix = 1
     | AllowAny = 2
+    | AllowInfix = 3
 
 type NamingConfig =
     { Naming:NamingCase option

src/FSharpLint.Core/Rules/Conventions/Naming/NamingHelper.fs

@@ -24,6 +24,25 @@ module QuickFixes =
         let toText = prefixingUnderscores + ident.idText.Replace("_", String.Empty)
         Some { FromText = ident.idText; FromRange = ident.idRange; ToText = toText })
 
+    let removePrefixingAndSuffixingUnderscores (ident:Ident) = lazy(
+        let rec removePrefixingUnderscores (str: string) =
+            if str.StartsWith "_" then
+                removePrefixingUnderscores(str.Substring 1)
+            else
+                str
+
+        let rec removeSuffixingUnderscores (str: string) =
+            if str.EndsWith "_" then
+                removeSuffixingUnderscores(str.Substring(0, str.Length - 1))
+            else
+                str
+
+        let toText =
+            ident.idText
+            |> removePrefixingUnderscores
+            |> removeSuffixingUnderscores
+        Some { FromText = ident.idText; FromRange = ident.idRange; ToText = toText })
+
     let addPrefix prefix (ident:Ident) = lazy(
         Some { FromText = ident.idText; FromRange = ident.idRange; ToText = prefix + ident.idText })
 
@@ -83,12 +102,17 @@ let private camelCaseRule (identifier:string) =
     if not (isCamelCase identifier) then Some "RulesNamingConventionsCamelCaseError"
     else None
 
-let private underscoreRule allowPrefix (identifier:string) =
-    if allowPrefix && identifier.TrimStart('_').Contains("_") then
-        Some "RulesNamingConventionsUnderscoreError"
-    else if not allowPrefix && identifier.Contains("_") then
-        Some "RulesNamingConventionsUnderscoreError"
-    else
+let private underscoreRule (underscoreMode: NamingUnderscores) (identifier:string) =
+    let errorKeyToRemoveUnderscores = "RulesNamingConventionsUnderscoreError"
+    let errorKeyToRemoveLeadingOrTrailingUnderscores = "RulesNamingConventionsNoInfixUnderscoreError"
+    match underscoreMode with
+    | NamingUnderscores.AllowPrefix when identifier.TrimStart('_').Contains '_' ->
+        Some errorKeyToRemoveUnderscores
+    | NamingUnderscores.None when identifier.Contains '_' ->
+        Some errorKeyToRemoveUnderscores
+    | NamingUnderscores.AllowInfix when (identifier.StartsWith '_' || identifier.EndsWith '_') ->
+        Some errorKeyToRemoveLeadingOrTrailingUnderscores
+    | _ ->
         None
 
 let private prefixRule (prefix:string) (identifier:string) =
@@ -120,12 +144,15 @@ let private checkIdentifierPart (config:NamingConfig) (identifier:Ident) (idText
 
     let underscoresError =
         match config.Underscores with
-        | Some NamingUnderscores.None ->
-            underscoreRule false idText
+        | Some (NamingUnderscores.None as nuCfg) ->
+            underscoreRule nuCfg idText
             |> Option.map (formatError >> tryAddFix QuickFixes.removeAllUnderscores)
-        | Some NamingUnderscores.AllowPrefix ->
-            underscoreRule true idText
+        | Some (NamingUnderscores.AllowPrefix as nuCfg) ->
+            underscoreRule nuCfg idText
             |> Option.map (formatError >> tryAddFix QuickFixes.removeNonPrefixingUnderscores)
+        | Some (NamingUnderscores.AllowInfix as nuCfg) ->
+            underscoreRule nuCfg idText
+            |> Option.map (formatError >> tryAddFix QuickFixes.removePrefixingAndSuffixingUnderscores)
         | _ -> None
 
     let prefixError =

src/FSharpLint.Core/Text.resx

@@ -174,6 +174,9 @@
   <data name="RulesNamingConventionsUnderscoreError" xml:space="preserve">
     <value>Consider changing `{0}` to remove any underscores.</value>
   </data>
+  <data name="RulesNamingConventionsNoInfixUnderscoreError" xml:space="preserve">
+    <value>Consider removing any leading or trailing underscore from `{0}`.</value>
+  </data>
   <data name="RulesAvoidTooShortNamesError" xml:space="preserve">
     <value>Consider using a longer name, as it is currently too short.</value>
   </data>

tests/FSharpLint.Core.Tests/Rules/Conventions/Naming/LiteralNames.fs

@@ -10,6 +10,7 @@ let config =
       Underscores = Some NamingUnderscores.None
       Prefix = None
       Suffix = None }
+
 [<TestFixture>]
 type TestConventionsLiteralNames() =
     inherit TestAstNodeRuleBase.TestAstNodeRuleBase(LiteralNames.rule config)
@@ -69,3 +70,57 @@ let cat = 5
 
         Assert.IsTrue(this.ErrorExistsAt(5, 4))
 
+let infixConfig =
+    { NamingConfig.Naming = Some NamingCase.PascalCase
+      Underscores = Some NamingUnderscores.AllowInfix
+      Prefix = None
+      Suffix = None }
+
+[<TestFixture>]
+type TestConventionsLiteralNamesInfix() =
+    inherit TestAstNodeRuleBase.TestAstNodeRuleBase(LiteralNames.rule infixConfig)
+
+    [<Test>]
+    member this.LiteralIsInfixUnderscore() =
+        this.Parse """
+module Program
+
+[<Literal>]
+let Super_Cat = 5
+"""
+
+        this.AssertNoWarnings()
+
+    [<Test>]
+    member this.LiteralIsUnderscorePrefix() =
+        this.Parse """
+module Program
+
+[<Literal>]
+let _Cat = 5
+"""
+
+        Assert.IsTrue(this.ErrorExistsOnLine 5)
+
+    [<Test>]
+    member this.LiteralIsUnderscoreSuffix() =
+        this.Parse """
+module Program
+
+[<Literal>]
+let Cat_ = 5
+"""
+
+        Assert.IsTrue(this.ErrorExistsOnLine 5)
+
+    [<Test>]
+    member this.LiteralIsNoUnderscore() =
+        this.Parse """
+module Program
+
+[<Literal>]
+let SuperCat = 5
+"""
+
+        this.AssertNoWarnings()
+