Add functions to convert integer/logical values to character values

- use fypp in stdlib_ascii to generate functions for all kind values

Author: awvwgk

doc/specs/stdlib_ascii.md

@@ -169,3 +169,42 @@ program demo_reverse
     print'(a)', reverse("Hello, World!") ! returns "!dlroW ,olleH"
 end program demo_reverse
 ```
+
+
+### `char_value`
+
+#### Status
+
+Experimental
+
+#### Description
+
+Create a character string representing the value of the provided variable.
+
+#### Syntax
+
+`res = [[stdlib_ascii(module):char_value(interface)]] (string)`
+
+#### Class
+
+Pure function.
+
+#### Argument
+
+`val`: shall be an intrinsic integer or logical type. It is an `intent(in)` argument.
+
+#### Result value
+
+The result is an intrinsic character type.
+
+#### Example
+
+```fortran
+program demo_char_value
+    use stdlib_ascii, only : char_value
+    implicit none
+    print'(a)', char_value(-3) ! returns "-3"
+    print'(a)', char_value(.true.) ! returns "T"
+    print'(a)', char_value(42) ! returns "42"
+end program demo_char_value
+```

src/CMakeLists.txt

@@ -2,6 +2,7 @@
 
 # Create a list of the files to be preprocessed
 set(fppFiles
+    stdlib_ascii.fypp
     stdlib_bitsets.fypp
     stdlib_bitsets_64.fypp
     stdlib_bitsets_large.fypp
@@ -37,7 +38,6 @@ endif()
 fypp_f90("${fyppFlags}" "${fppFiles}" outFiles)
 
 set(SRC
-    stdlib_ascii.f90
     stdlib_error.f90
     stdlib_kinds.f90
     stdlib_logger.f90

src/Makefile.manual

@@ -1,4 +1,5 @@
 SRCFYPP =\
+        stdlib_ascii.fypp \
         stdlib_bitsets_64.fypp \
         stdlib_bitsets_large.fypp \
         stdlib_bitsets.fypp \
@@ -21,7 +22,6 @@ SRCFYPP =\
 	stdlib_stats_distribution_PRNG.fypp
 
 SRC = f18estop.f90 \
-      stdlib_ascii.f90 \
       stdlib_error.f90 \
       stdlib_kinds.f90 \
       stdlib_logger.f90 \

src/stdlib_ascii.f90 renamed to src/stdlib_ascii.fypp

@@ -1,8 +1,11 @@
+#:include "common.fypp"
+
 !> The `stdlib_ascii` module provides procedures for handling and manipulating
 !> intrinsic character variables and constants.
 !>
 !> The specification of this module is available [here](../page/specs/stdlib_ascii.html).
 module stdlib_ascii
+    use stdlib_kinds, only : int8, int16, int32, int64
 
     implicit none
     private
@@ -17,6 +20,17 @@ module stdlib_ascii
 
     ! Character conversion functions
     public :: to_lower, to_upper, to_title, reverse
+    public :: char_value
+
+    !> Version: experimental
+    !>
+    !> Create a character string representing the value of the provided variable.
+    interface char_value
+    #:for kind in INT_KINDS
+        module procedure :: integer_${kind}$_to_char
+        module procedure :: logical_${kind}$_to_char
+    #:endfor
+    end interface char_value
 
     ! All control characters in the ASCII table (see www.asciitable.com).
     character(len=1), public, parameter :: NUL = achar(int(z'00')) !! Null
@@ -312,4 +326,51 @@ pure function reverse(string) result(reverse_string)
 
     end function reverse
 
+    #:for kind in INT_KINDS
+    !> Represent an integer of kind ${kind}$ as character sequence
+    pure function integer_${kind}$_to_char(val) result(string)
+        integer, parameter :: ik = ${kind}$
+        integer(ik), intent(in) :: val
+        character(len=:), allocatable :: string
+        integer, parameter :: buffer_len = range(val)+2
+        character(len=buffer_len) :: buffer
+        integer :: pos
+        integer(ik) :: n
+        character(len=1), parameter :: numbers(0:9) = &
+            ["0", "1", "2", "3", "4", "5", "6", "7", "8", "9"]
+
+        if (val == 0_ik) then
+            string = numbers(0)
+            return
+        end if
+
+        n = abs(val)
+        buffer = ""
+
+        pos = buffer_len+1
+        do while (n > 0_ik)
+            pos = pos - 1
+            buffer(pos:pos) = numbers(mod(n, 10_ik))
+            n = n/10_ik
+        end do
+        if (val < 0_ik) then
+            pos = pos - 1
+            buffer(pos:pos) = '-'
+        end if
+
+        string = buffer(pos:)
+    end function integer_${kind}$_to_char
+    #:endfor
+
+    #:for kind in INT_KINDS
+    !> Represent an logical of kind ${kind}$ as character sequence
+    pure function logical_${kind}$_to_char(val) result(string)
+        integer, parameter :: ik = ${kind}$
+        logical(ik), intent(in) :: val
+        character(len=1) :: string
+
+        string = merge("T", "F", val)
+    end function logical_${kind}$_to_char
+    #:endfor
+
 end module stdlib_ascii

src/tests/ascii/test_ascii.f90

@@ -6,7 +6,9 @@ program test_ascii
         whitespace, letters, is_alphanum, is_alpha, is_lower, is_upper, &
         is_digit, is_octal_digit, is_hex_digit, is_white, is_blank, &
         is_control, is_punctuation, is_graphical, is_printable, is_ascii, &
-        to_lower, to_upper, to_title, reverse, LF, TAB, NUL, DEL
+        to_lower, to_upper, to_title, reverse, LF, TAB, NUL, DEL, &
+        char_value
+     use stdlib_kinds, only : int8, int16, int32, int64
 
     implicit none
 
@@ -73,6 +75,8 @@ program test_ascii
     call test_to_title_string
     call test_reverse_string
 
+    call test_char_value
+
 contains
 
     subroutine test_is_alphanum_short
@@ -613,4 +617,47 @@ subroutine test_reverse_string
         call check(trim(adjustl(dlc)) == "desrever")
     end subroutine test_reverse_string
 
+    subroutine test_char_value
+       character(len=128) :: flc
+
+       write(flc, '(g0)') 1026192
+       call check(char_value(1026192) == trim(flc))
+
+       write(flc, '(g0)') -124784
+       call check(char_value(-124784) == trim(flc))
+
+       write(flc, '(g0)') 1_int8
+       call check(char_value(1_int8) == trim(flc))
+
+       write(flc, '(g0)') -3_int8
+       call check(char_value(-3_int8) == trim(flc))
+
+       write(flc, '(g0)') 80_int16
+       call check(char_value(80_int16) == trim(flc))
+
+       write(flc, '(g0)') 8924890_int32
+       call check(char_value(8924890_int32) == trim(flc))
+
+       write(flc, '(g0)') -2378401_int32
+       call check(char_value(-2378401_int32) == trim(flc))
+
+       write(flc, '(g0)') -921092378401_int64
+       call check(char_value(-921092378401_int64) == trim(flc))
+
+       write(flc, '(g0)') 1272835771_int64
+       call check(char_value(1272835771_int64) == trim(flc))
+
+       write(flc, '(g0)') .true.
+       call check(char_value(.true.) == trim(flc))
+
+       write(flc, '(g0)') .false.
+       call check(char_value(.false.) == trim(flc))
+
+       write(flc, '(g0)') .true._int8
+       call check(char_value(.true._int8) == trim(flc))
+
+       write(flc, '(g0)') .false._int64
+       call check(char_value(.false._int64) == trim(flc))
+    end subroutine test_char_value
+
 end program test_ascii