Adds initial logic for packaging the C++ libraries with open source

Adds logic to zip the firebase libraries using cpack, and their desktop dependencies for blastdoor. Needed for moving to use the open source build logic for the prebuilt version.

PiperOrigin-RevId: 288796467

Author: a-maurice

CMakeLists.txt

@@ -44,9 +44,20 @@ option(FIREBASE_CPP_BUILD_TESTS
        "Enable the Firebase C++ Build Tests." OFF)
 option(FIREBASE_FORCE_FAKE_SECURE_STORAGE
        "Disable use of platform secret store and use fake impl." OFF)
+option(FIREBASE_CPP_BUILD_PACKAGE
+       "Bundle the Firebase C++ libraries into a zip file." OFF)
+
+# Define this directory to be the root of the C++ SDK, which the libraries can
+# then refer to.
+set(FIREBASE_CPP_SDK_ROOT_DIR ${CMAKE_CURRENT_LIST_DIR})
+
+project (firebase NONE)
+enable_language(C)
+enable_language(CXX)
 
 list(INSERT CMAKE_MODULE_PATH 0 ${CMAKE_CURRENT_LIST_DIR}/cmake)
 include(external_rules)
+include(cpp_pack)
 
 if(FIREBASE_CPP_BUILD_TESTS)
   enable_testing()
@@ -68,10 +79,6 @@ set(FIREBASE_GEN_FILE_DIR ${CMAKE_BINARY_DIR}/generated)
 # Directory for any shared scripts.
 set(FIREBASE_SCRIPT_DIR ${CMAKE_CURRENT_LIST_DIR})
 
-project (firebase NONE)
-enable_language(C)
-enable_language(CXX)
-
 if (FIREBASE_CPP_BUILD_TESTS AND MSVC)
   # Googletest requires MSVC to compile with the static version of the runtime
   # library, so define the appropriate runtime flag, before adding libraries.
@@ -258,10 +265,6 @@ else()
   set(FIREBASE_FLATBUFFERS_DEPENDENCIES "")
 endif()
 
-# Define this directory to be the root of the C++ SDK, which the libraries can
-# then refer to.
-set(FIREBASE_CPP_SDK_ROOT_DIR ${CMAKE_CURRENT_LIST_DIR})
-
 include(binary_to_array)
 include(firebase_cpp_gradle)
 
@@ -305,3 +308,10 @@ endif()
 if (FIREBASE_INCLUDE_STORAGE)
   add_subdirectory(storage)
 endif()
+
+# Place the CMake and gradle build files provided to easily link against the
+# prebuilt libraries at the root of the package.
+cpp_pack_dir(
+  "${CMAKE_CURRENT_LIST_DIR}/release_build_files/"
+  .
+)

admob/CMakeLists.txt

@@ -120,3 +120,5 @@ elseif(IOS)
   # accomplish that.
   symlink_pod_headers(firebase_admob Google-Mobile-Ads-SDK GoogleMobileAds)
 endif()
+
+cpp_pack_library(firebase_admob "")

analytics/CMakeLists.txt

@@ -133,3 +133,5 @@ if(FIREBASE_CPP_BUILD_TESTS)
   # Add the tests subdirectory
   add_subdirectory(tests)
 endif()
+
+cpp_pack_library(firebase_analytics "")

app/CMakeLists.txt

@@ -365,3 +365,8 @@ if(FIREBASE_CPP_BUILD_TESTS)
   # Add the tests subdirectory
   add_subdirectory(tests)
 endif()
+
+cpp_pack_library(firebase_app "")
+if (NOT ANDROID AND NOT IOS)
+  cpp_pack_library(flatbuffers "deps/app/external")
+endif()

app/instance_id/CMakeLists.txt

@@ -58,3 +58,5 @@ target_compile_definitions(firebase_instance_id_desktop_impl
   PRIVATE
     -DINTERNAL_EXPERIMENTAL=1
 )
+
+cpp_pack_library(firebase_instance_id_desktop_impl "deps/app")

app/rest/CMakeLists.txt

@@ -126,3 +126,9 @@ if(FIREBASE_CPP_BUILD_TESTS)
   # Add the tests subdirectory
   add_subdirectory(tests)
 endif()
+
+cpp_pack_library(firebase_rest_lib "deps/app")
+cpp_pack_library(libcurl "deps/app/external")
+cpp_pack_library(zlibstatic "deps/app/external")
+cpp_pack_library_file(${OPENSSL_SSL_LIBRARY} "deps/app/external")
+cpp_pack_library_file(${OPENSSL_CRYPTO_LIBRARY} "deps/app/external")

auth/CMakeLists.txt

@@ -209,3 +209,5 @@ if(FIREBASE_CPP_BUILD_TESTS)
   # Add the tests subdirectory
   add_subdirectory(tests)
 endif()
+
+cpp_pack_library(firebase_auth "")

cmake/cpp_pack.cmake

@@ -0,0 +1,98 @@
+# Copyright 2019 Google
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+# Handles creation of the C++ package zip using cpack
+
+# All functions do nothing unless FIREBASE_CPP_BUILD_PACKAGE is enabled.
+if(${FIREBASE_CPP_BUILD_PACKAGE})
+  # Including CPack multiple times can cause it to break, so guard against that.
+  if(DEFINED CPACK_GENERATOR)
+    return()
+  endif()
+
+  # iOS will get the platform name of Darwin if we dont change it here
+  if(IOS)
+    set(CPACK_SYSTEM_NAME "iOS")
+  endif()
+
+  set(CPACK_GENERATOR "ZIP")
+  if(NOT DEFINED FIREBASE_CPP_VERSION OR FIREBASE_CPP_VERSION STREQUAL "")
+    # Parse the version number from the json file.
+    file(STRINGS ${FIREBASE_CPP_SDK_ROOT_DIR}/cpp_sdk_version.json version_file)
+    string(REGEX MATCH "[0-9\.]+" FIREBASE_CPP_VERSION "${version_file}")
+  endif()
+  set(CPACK_PACKAGE_VERSION "${FIREBASE_CPP_VERSION}")
+  set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0) # DO NOT pack the root directory.
+
+  include(CPack)
+
+  if(ANDROID)
+    set(FIREBASE_LIB_CONFIG_PATH "android")
+  elseif(IOS)
+    set(FIREBASE_LIB_CONFIG_PATH "ios")
+  elseif(MSVC)
+    set(FIREBASE_LIB_CONFIG_PATH "windows")
+  elseif(APPLE)
+    set(FIREBASE_LIB_CONFIG_PATH "darwin")
+  else()
+    set(FIREBASE_LIB_CONFIG_PATH "linux")
+  endif()
+endif()
+
+# Packs the given target library into the libs folder, under the correct config
+# and given subdirectory.
+function(cpp_pack_library TARGET SUBDIRECTORY)
+  if(NOT ${FIREBASE_CPP_BUILD_PACKAGE})
+    return()
+  endif()
+
+  install(
+    TARGETS "${TARGET}"
+    ARCHIVE DESTINATION "libs/${FIREBASE_LIB_CONFIG_PATH}/${SUBDIRECTORY}"
+  )
+endfunction()
+
+# Packs the given file into the libs folder, under the correct config
+# and given subdirectory.
+function(cpp_pack_library_file FILE_TO_PACK SUBDIRECTORY)
+  cpp_pack_file(${FILE_TO_PACK}
+                "libs/${FIREBASE_LIB_CONFIG_PATH}/${SUBDIRECTORY}")
+endfunction()
+
+# Packs the given file into the given destination.
+function(cpp_pack_file FILE_TO_PACK DESTINATION)
+  if(NOT ${FIREBASE_CPP_BUILD_PACKAGE})
+    return()
+  endif()
+
+  # Get the real file path, for cases like symlinks.
+  get_filename_component(path_to_file ${FILE_TO_PACK} REALPATH)
+
+  install(
+    FILES ${path_to_file}
+    DESTINATION ${DESTINATION}
+  )
+endfunction()
+
+# Packs the given directory into the given destination.
+function(cpp_pack_dir DIR_TO_PACK DESTINATION)
+  if(NOT ${FIREBASE_CPP_BUILD_PACKAGE})
+    return()
+  endif()
+
+  install(
+    DIRECTORY ${DIR_TO_PACK}
+    DESTINATION ${DESTINATION}
+  )
+endfunction()

database/CMakeLists.txt

@@ -209,3 +209,9 @@ if(FIREBASE_CPP_BUILD_TESTS)
   # Add the tests subdirectory
   add_subdirectory(tests)
 endif()
+
+cpp_pack_library(firebase_database "")
+if (NOT ANDROID AND NOT IOS)
+  cpp_pack_library(uv_a "deps/database/external")
+  cpp_pack_library(libuWS "deps/database/external")
+endif()

dynamic_links/CMakeLists.txt

@@ -86,3 +86,5 @@ elseif(IOS)
       FirebaseDynamicLinks
   )
 endif()
+
+cpp_pack_library(firebase_dynamic_links "")