[#30] Add bootstrap server to run init and cleanup jobs

Author: cabol

lib/nebulex_redis_adapter.ex

@@ -304,8 +304,6 @@ defmodule NebulexRedisAdapter do
 
   alias Nebulex.Adapter
   alias Nebulex.Adapter.Stats
-  alias Nebulex.Telemetry
-  alias Nebulex.Telemetry.StatsHandler
   alias NebulexRedisAdapter.{ClientCluster, Command, Connection, RedisCluster}
 
   ## Nebulex.Adapter
@@ -369,14 +367,7 @@ defmodule NebulexRedisAdapter do
     # init stats
     stats_counter = Stats.init(opts)
 
-    child_spec =
-      Nebulex.Adapters.Supervisor.child_spec(
-        name: normalize_module_name([name, Supervisor]),
-        strategy: :rest_for_one,
-        children: children
-      )
-
-    meta = %{
+    adapter_meta = %{
       name: name,
       mode: mode,
       keyslot: keyslot,
@@ -389,20 +380,14 @@ defmodule NebulexRedisAdapter do
       telemetry_prefix: Keyword.fetch!(opts, :telemetry_prefix)
     }
 
-    _ = maybe_attach_stats_handler(meta)
-
-    {:ok, child_spec, meta}
-  end
-
-  defp maybe_attach_stats_handler(%{stats_counter: nil}), do: :ok
+    child_spec =
+      Nebulex.Adapters.Supervisor.child_spec(
+        name: normalize_module_name([name, Supervisor]),
+        strategy: :rest_for_one,
+        children: [{NebulexRedisAdapter.BootstrapServer, adapter_meta} | children]
+      )
 
-  defp maybe_attach_stats_handler(%{stats_counter: stats_counter} = meta) do
-    Telemetry.attach_many(
-      stats_counter,
-      [meta.telemetry_prefix ++ [:command, :stop]],
-      &StatsHandler.handle_event/4,
-      stats_counter
-    )
+    {:ok, child_spec, adapter_meta}
   end
 
   defp do_init(:standalone, name, pool_size, opts) do

lib/nebulex_redis_adapter/bootstrap_server.ex

@@ -0,0 +1,53 @@
+defmodule NebulexRedisAdapter.BootstrapServer do
+  @moduledoc """
+  This server takes care of initialization and cleanup jobs. For example,
+  attaching the stats handler when the cache starts and detaching it when
+  it terminates.
+  """
+  use GenServer
+
+  import Nebulex.Helpers
+
+  alias Nebulex.Telemetry
+  alias Nebulex.Telemetry.StatsHandler
+
+  ## API
+
+  @spec start_link(Nebulex.Adapter.adapter_meta()) :: GenServer.on_start()
+  def start_link(adapter_meta) do
+    name = normalize_module_name([Map.fetch!(adapter_meta, :name), BootstrapServer])
+    GenServer.start_link(__MODULE__, adapter_meta, name: name)
+  end
+
+  ## GenServer Callbacks
+
+  @impl true
+  def init(adapter_meta) do
+    _ = Process.flag(:trap_exit, true)
+    {:ok, adapter_meta, {:continue, :attach_stats_handler}}
+  end
+
+  @impl true
+  def handle_continue(:attach_stats_handler, adapter_meta) do
+    _ = maybe_attach_stats_handler(adapter_meta)
+    {:noreply, adapter_meta}
+  end
+
+  @impl true
+  def terminate(_reason, adapter_meta) do
+    if ref = adapter_meta.stats_counter, do: Telemetry.detach(ref)
+  end
+
+  ## Private Functions
+
+  defp maybe_attach_stats_handler(adapter_meta) do
+    if ref = adapter_meta.stats_counter do
+      Telemetry.attach_many(
+        ref,
+        [adapter_meta.telemetry_prefix ++ [:command, :stop]],
+        &StatsHandler.handle_event/4,
+        ref
+      )
+    end
+  end
+end