Highlight field access differently from calls (#73)

Author: jonatanklosko

queries/highlights.scm

@@ -94,15 +94,30 @@
 
 ; Calls
 
-; * function call
+; * local function call
 (call
-  target: [
-    ; local
-    (identifier) @function
-    ; remote
-    (dot
-      right: (identifier) @function)
-  ])
+  target: (identifier) @function)
+
+; * remote function call
+(call
+  target: (dot
+    right: (identifier) @function))
+
+; * field without parentheses or block
+(call
+  target: (dot
+    right: (identifier) @property)
+  .)
+
+; * remote call without parentheses or block (overrides above)
+(call
+  target: (dot
+    left: [
+      (alias)
+      (atom)
+    ]
+    right: (identifier) @function)
+  .)
 
 ; * definition keyword
 (call
@@ -140,6 +155,13 @@
       right: (identifier) @variable))
   (#match? @keyword "^(def|defdelegate|defguard|defguardp|defmacro|defmacrop|defn|defnp|defp)$"))
 
+; * pipe into field without parentheses (function call)
+(binary_operator
+  operator: "|>"
+  right: (call
+    target: (dot
+      right: (identifier) @function)))
+
 ; Operators
 
 ; * capture operand

test/highlight/calls.ex

@@ -88,3 +88,37 @@ end)
 #           ^ operator
 #            ^ number
 #             ^ punctuation.bracket
+
+map.key1
+# ^ variable
+#    ^ property
+
+map.key1.key2
+# ^ variable
+#    ^ property
+#         ^ property
+
+DateTime.utc_now.day
+# ^ module
+#         ^ function
+#                 ^ property
+
+arg |> mod.func
+# ^ variable
+#   ^ operator
+#       ^ variable
+#           ^ function
+
+Mod.fun do
+# ^ module
+#   ^ function
+#       ^ keyword
+end
+# ^ keyword
+
+mod.fun do
+# ^ variable
+#   ^ function
+#       ^ keyword
+end
+# ^ keyword

test/highlight/kernel.ex

@@ -92,7 +92,7 @@ case __ENV__.line do
 # ^ keyword
 #    ^ constant.builtin
 #           ^ operator
-#            ^ function
+#            ^ property
 #                 ^ keyword
   x when is_integer(x) -> x
   # <- variable