Add support for MySQL/MariaDB (#89)

This PR adds support for the Exto adapter `Ecto.Adapters.MyXQL`.

Closes #85.

Author: phihos

.github/workflows/elixir.yml

@@ -35,6 +35,16 @@ jobs:
           --health-interval 10s
           --health-timeout 5s
           --health-retries 5
+      mariadb:
+        image: mariadb:11
+        ports: ["3306:3306"]
+        env:
+          MARIADB_ROOT_PASSWORD: root
+        options: >-
+          --health-cmd "healthcheck.sh --connect --innodb_initialized"
+          --health-interval 10s
+          --health-timeout 5s
+          --health-retries 5
     name: Elixir v${{ matrix.elixir }}, Erlang v${{ matrix.erlang }}
     steps:
       - uses: actions/checkout@v4
@@ -83,3 +93,8 @@ jobs:
         run: mix test
         env:
           DB: postgres
+
+      - name: Run Tests - MySQL/MariaDB
+        run: mix test
+        env:
+          DB: mysql

config/dev.example.exs

@@ -29,6 +29,16 @@ config :error_tracker, :ecto_adapter, :postgres
 config :error_tracker, ErrorTrackerDev.Repo,
   url: "ecto://postgres:postgres@127.0.0.1/error_tracker_dev"
 
+# MySQL/MariaDB adapter
+#
+# To use MySQL/MariaDB on your local development machine uncomment these lines and
+# comment the lines of other adapters.
+
+# config :error_tracker, :ecto_adapter, :mysql
+
+# config :error_tracker, ErrorTrackerDev.Repo,
+#   url: "ecto://root:root@127.0.0.1/error_tracker_dev"
+
 # SQLite3 adapter
 #
 # To use SQLite3 on your local development machine uncomment these lines and

config/test.example.exs

@@ -5,6 +5,13 @@ config :error_tracker, ErrorTracker.Test.Repo,
   pool: Ecto.Adapters.SQL.Sandbox,
   log: false
 
+config :error_tracker, ErrorTracker.Test.MySQLRepo,
+  url: "ecto://root:root@127.0.0.1/error_tracker_test",
+  pool: Ecto.Adapters.SQL.Sandbox,
+  log: false,
+  # Use the same migrations as the PostgreSQL repo
+  priv: "priv/repo"
+
 config :error_tracker, ErrorTracker.Test.LiteRepo,
   database: "priv/lite_repo/test.db",
   pool: Ecto.Adapters.SQL.Sandbox,

dev.exs

@@ -16,6 +16,7 @@ Config.Reader.read!("config/config.exs", env: :dev)
 adapter =
   case Application.get_env(:error_tracker, :ecto_adapter) do
     :postgres -> Ecto.Adapters.Postgres
+    :mysql -> Ecto.Adapters.MyXQL
     :sqlite3 -> Ecto.Adapters.SQLite3
   end
 

guides/Getting Started.md

@@ -4,7 +4,7 @@ This guide is an introduction to ErrorTracker, an Elixir-based built-in error tr
 
 In this guide we will learn how to install ErrorTracker in an Elixir project so you can start reporting errors as soon as possible. We will also cover more advanced topics such as how to report custom errors and how to add extra context to reported errors.
 
-**This guide requires you to have set up Ecto with PostgreSQL or SQLite3 beforehand.**
+**This guide requires you to have set up Ecto with PostgreSQL, MySQL/MariaDB or SQLite3 beforehand.**
 
 ## Installing ErrorTracker as a dependency
 

lib/error_tracker.ex

@@ -17,7 +17,7 @@ defmodule ErrorTracker do
   ## Requirements
 
   ErrorTracker requires Elixir 1.15+, Ecto 3.11+, Phoenix LiveView 0.19+, and
-  PostgreSQL or SQLite3 as database.
+  PostgreSQL, MySQL/MariaDB or SQLite3 as database.
 
   ## Integrations
 
@@ -230,10 +230,18 @@ defmodule ErrorTracker do
     {:ok, {error, occurrence}} =
       Repo.transaction(fn ->
         error =
-          Repo.insert!(error,
-            on_conflict: [set: [status: :unresolved, last_occurrence_at: DateTime.utc_now()]],
-            conflict_target: :fingerprint
-          )
+          ErrorTracker.Repo.with_adapter(fn
+            :mysql ->
+              Repo.insert!(error,
+                on_conflict: [set: [status: :unresolved, last_occurrence_at: DateTime.utc_now()]]
+              )
+
+            _other ->
+              Repo.insert!(error,
+                on_conflict: [set: [status: :unresolved, last_occurrence_at: DateTime.utc_now()]],
+                conflict_target: :fingerprint
+              )
+          end)
 
         occurrence =
           error

lib/error_tracker/migration.ex

@@ -114,6 +114,7 @@ defmodule ErrorTracker.Migration do
   defp migrator do
     ErrorTracker.Repo.with_adapter(fn
       :postgres -> ErrorTracker.Migration.Postgres
+      :mysql -> ErrorTracker.Migration.MySQL
       :sqlite -> ErrorTracker.Migration.SQLite
       adapter -> raise "ErrorTracker does not support #{adapter}"
     end)

lib/error_tracker/migration/mysql.ex

@@ -0,0 +1,33 @@
+defmodule ErrorTracker.Migration.MySQL do
+  @moduledoc false
+
+  @behaviour ErrorTracker.Migration
+
+  use Ecto.Migration
+  alias ErrorTracker.Migration.SQLMigrator
+
+  @initial_version 3
+  @current_version 3
+
+  @impl ErrorTracker.Migration
+  def up(opts) do
+    opts = with_defaults(opts, @current_version)
+    SQLMigrator.migrate_up(__MODULE__, opts, @initial_version)
+  end
+
+  @impl ErrorTracker.Migration
+  def down(opts) do
+    opts = with_defaults(opts, @initial_version)
+    SQLMigrator.migrate_down(__MODULE__, opts, @initial_version)
+  end
+
+  @impl ErrorTracker.Migration
+  def current_version(opts) do
+    opts = with_defaults(opts, @initial_version)
+    SQLMigrator.current_version(opts)
+  end
+
+  defp with_defaults(opts, version) do
+    Enum.into(opts, %{version: version})
+  end
+end

lib/error_tracker/migration/mysql/v03.ex

@@ -0,0 +1,47 @@
+defmodule ErrorTracker.Migration.MySQL.V03 do
+  @moduledoc false
+
+  use Ecto.Migration
+
+  def up(_opts) do
+    create table(:error_tracker_meta, primary_key: [name: :key, type: :string]) do
+      add :value, :string, null: false
+    end
+
+    create table(:error_tracker_errors, primary_key: [name: :id, type: :bigserial]) do
+      add :kind, :string, null: false
+      add :reason, :text, null: false
+      add :source_line, :text, null: false
+      add :source_function, :text, null: false
+      add :status, :string, null: false
+      add :fingerprint, :string, null: false
+      add :last_occurrence_at, :utc_datetime_usec, null: false
+
+      timestamps(type: :utc_datetime_usec)
+    end
+
+    create unique_index(:error_tracker_errors, [:fingerprint])
+
+    create table(:error_tracker_occurrences, primary_key: [name: :id, type: :bigserial]) do
+      add :context, :map, null: false
+      add :reason, :text, null: false
+      add :stacktrace, :map, null: false
+
+      add :error_id,
+          references(:error_tracker_errors, on_delete: :delete_all, column: :id, type: :bigserial),
+          null: false
+
+      timestamps(type: :utc_datetime_usec, updated_at: false)
+    end
+
+    create index(:error_tracker_occurrences, [:error_id])
+
+    create index(:error_tracker_errors, [:last_occurrence_at])
+  end
+
+  def down(_opts) do
+    drop table(:error_tracker_occurrences)
+    drop table(:error_tracker_errors)
+    drop table(:error_tracker_meta)
+  end
+end

lib/error_tracker/migration/sql_migrator.ex

@@ -73,6 +73,13 @@ defmodule ErrorTracker.Migration.SQLMigrator do
         ON CONFLICT (key) DO UPDATE SET value = EXCLUDED.value
         """
 
+      :mysql ->
+        execute """
+        INSERT INTO error_tracker_meta (`key`, value)
+        VALUES ('migration_version', '#{version}'), ('migration_timestamp', '#{timestamp}')
+        ON DUPLICATE KEY UPDATE value = VALUES(value)
+        """
+
       _other ->
         execute """
         INSERT INTO error_tracker_meta (key, value)