Refactor TRichEditHelper as a class helper

Added new ClassHelpers.RichEdit unit to the project.

Converted TRichEditHelper into a "class helper for TRichEdit" and
moved it from URTFUtils into ClassHelpers.RichEdit.

Updated all affected code.

Author: delphidabbler

Src/ClassHelpers.RichEdit.pas

@@ -0,0 +1,53 @@
+{
+ * This Source Code Form is subject to the terms of the Mozilla Public License,
+ * v. 2.0. If a copy of the MPL was not distributed with this file, You can
+ * obtain one at https://mozilla.org/MPL/2.0/
+ *
+ * Copyright (C) 2025, Peter Johnson (gravatar.com/delphidabbler).
+ *
+ * Class helper for TRichEdit.
+}
+
+unit ClassHelpers.RichEdit;
+
+interface
+
+uses
+  // Delphi
+  ComCtrls,
+  // Project
+  URTFUtils;
+
+type
+  TRichEditHelper = class helper for TRichEdit
+  public
+    procedure Load(const ARTF: TRTF);
+  end;
+
+implementation
+
+uses
+  // Delphi
+  SysUtils,
+  Classes;
+
+{ TRichEditHelper }
+
+procedure TRichEditHelper.Load(const ARTF: TRTF);
+var
+  Stream: TStream;
+begin
+  PlainText := False;
+  Stream := TMemoryStream.Create;
+  try
+    ARTF.ToStream(Stream);
+    Stream.Position := 0;
+    // must set MaxLength or long documents may not display
+    MaxLength := Stream.Size;
+    Lines.LoadFromStream(Stream, TEncoding.ASCII);
+  finally
+    Stream.Free;
+  end;
+end;
+
+end.

Src/CodeSnip.dpr

@@ -375,7 +375,8 @@ uses
   FmRegisterCompilersDlg in 'FmRegisterCompilersDlg.pas' {RegisterCompilersDlg},
   ClassHelpers.UGraphics in 'ClassHelpers.UGraphics.pas',
   ClassHelpers.UActions in 'ClassHelpers.UActions.pas',
-  USaveInfoMgr in 'USaveInfoMgr.pas';
+  USaveInfoMgr in 'USaveInfoMgr.pas',
+  ClassHelpers.RichEdit in 'ClassHelpers.RichEdit.pas';
 
 // Include resources
 {$Resource ExternalObj.tlb}       // Type library file

Src/CodeSnip.dproj

@@ -582,6 +582,7 @@
 			<DCCReference Include="ClassHelpers.UGraphics.pas"/>
 			<DCCReference Include="ClassHelpers.UActions.pas"/>
 			<DCCReference Include="USaveInfoMgr.pas"/>
+			<DCCReference Include="ClassHelpers.RichEdit.pas"/>
 			<None Include="CodeSnip.todo"/>
 			<BuildConfiguration Include="Base">
 				<Key>Base</Key>

Src/FrHiliterPrefs.pas

@@ -178,6 +178,7 @@ implementation
   // Delphi
   SysUtils, ExtCtrls, Windows, Graphics, Dialogs,
   // Project
+  ClassHelpers.RichEdit,
   FmPreferencesDlg, FmNewHiliterNameDlg, FmUserHiliterMgrDlg, Hiliter.UAttrs,
   IntfCommon, UCtrlArranger, UFontHelper, UIStringList, UMessageBox,
   URTFBuilder, URTFStyles, UUtils;
@@ -614,7 +615,7 @@ procedure THiliterPrefsFrame.UpdatePopupMenu;
 
 procedure THiliterPrefsFrame.UpdatePreview;
 begin
-  TRichEditHelper.Load(frmExample.RichEdit, GenerateRTF);
+  frmExample.RichEdit.Load(GenerateRTF);
 end;
 
 initialization

Src/FrPrintingPrefs.pas

@@ -101,9 +101,10 @@ implementation
   // Delphi
   SysUtils, Windows, Graphics, Math, ComCtrls,
   // Project
+  ClassHelpers.RichEdit,
   FmPreferencesDlg, Hiliter.UAttrs, Hiliter.UHiliters, IntfCommon, UColours,
   UConsts, UEncodings, UFontHelper, UKeysHelper, UPrintInfo, URTFBuilder,
-  URTFStyles, URTFUtils, UStrUtils, UUtils;
+  URTFStyles, UStrUtils, UUtils;
 
 
 {$R *.dfm}
@@ -379,7 +380,7 @@ procedure TPrintingPrefsPreview.Generate(const UseColor, SyntaxPrint: Boolean);
     HiliteSource(UseColor, SyntaxPrint, Builder);
     Builder.EndPara;
     // Load document into rich edit
-    TRichEditHelper.Load(fRe, Builder.Render);
+    fRe.Load(Builder.Render);
   finally
     FreeAndNil(Builder);
   end;

Src/FrRTFPreview.pas

@@ -59,6 +59,7 @@ implementation
 
 uses
   // Project
+  ClassHelpers.RichEdit,
   URTFUtils;
 
 
@@ -80,7 +81,7 @@ procedure TRTFPreviewFrame.LoadContent(const DocContent: TEncodedData);
     @param DocContent [in] Valid RTF document to be displayed.
   }
 begin
-  TRichEditHelper.Load(reView, TRTF.Create(DocContent));
+  reView.Load(TRTF.Create(DocContent));
 end;
 
 procedure TRTFPreviewFrame.SetPopupMenu(const Menu: TPopupMenu);

Src/FrSourcePrefs.pas

@@ -112,6 +112,7 @@ implementation
   // Delphi
   SysUtils, Math,
   // Project
+  ClassHelpers.RichEdit,
   FmPreferencesDlg, Hiliter.UAttrs, Hiliter.UFileHiliter, Hiliter.UHiliters,
   IntfCommon, UConsts, UCtrlArranger, URTFUtils;
 
@@ -358,8 +359,7 @@ procedure TSourcePrefsFrame.UpdatePreview;
   // Generate and display preview with required comment style
   Preview := TSourcePrefsPreview.Create(GetCommentStyle, fHiliteAttrs);
   try
-    // Display preview
-    TRichEditHelper.Load(frmPreview.RichEdit, Preview.Generate);
+    frmPreview.RichEdit.Load(Preview.Generate);
   finally
     Preview.Free;
   end;

Src/UPrintEngine.pas

@@ -63,6 +63,7 @@ implementation
   // Delphi
   Printers,
   // Project
+  ClassHelpers.RichEdit,
   UMeasurement, UPrintInfo;
 
 
@@ -102,7 +103,7 @@ procedure TPrintEngine.Print(const Document: TRTF);
   sDefTitle = 'CodeSnip document';  // default document title
 begin
   // Load document into engine
-  TRichEditHelper.Load(RichEdit, Document);
+  RichEdit.Load(Document);
   // Set up page margins
   PrintMargins := GetPrintMargins;
   RichEdit.PageRect := Rect(

Src/URTFUtils.pas

@@ -17,7 +17,7 @@ interface
 
 uses
   // Delphi
-  SysUtils, Classes, ComCtrls,
+  SysUtils, Classes,
   // Project
   UEncodings;
 
@@ -130,20 +130,6 @@   TRTF = record
   ///  <summary>Class of exception raised by TRTF</summary>
   ERTF = class(Exception);
 
-type
-  ///  <summary>Static method record that assists in working with rich edit
-  ///  VCL controls.</summary>
-  TRichEditHelper = record
-  public
-    ///  <summary>Loads RTF code into a rich edit control, replacing existing
-    ///  content.</summary>
-    ///  <param name="RE">TRichEdit [in] Rich edit control.</param>
-    ///  <param name="RTF">TRTF [in] Contains rich text code to be loaded.
-    ///  </param>
-    class procedure Load(const RE: TRichEdit; const RTF: TRTF); static;
-  end;
-
-
 ///  <summary>Returns a parameterless RTF control word of given kind.</summary>
 function RTFControl(const Ctrl: TRTFControl): ASCIIString; overload;
 
@@ -184,8 +170,6 @@ implementation
 
 
 uses
-  // Delphi
-  Windows, RichEdit,
   // Project
   UExceptions;
 
@@ -372,24 +356,5 @@ function TRTF.ToString: UnicodeString;
   Result := TEncoding.ASCII.GetString(fData);
 end;
 
-{ TRichEditHelper }
-
-class procedure TRichEditHelper.Load(const RE: TRichEdit; const RTF: TRTF);
-var
-  Stream: TStream;
-begin
-  RE.PlainText := False;
-  Stream := TMemoryStream.Create;
-  try
-    RTF.ToStream(Stream);
-    Stream.Position := 0;
-    // must set MaxLength or long documents may not display
-    RE.MaxLength := Stream.Size;
-    RE.Lines.LoadFromStream(Stream, TEncoding.ASCII);
-  finally
-    Stream.Free;
-  end;
-end;
-
 end.