CLJS-2349: Port reset-vals! and swap-vals! over from Clojure

Author: anmonteiro

src/main/cljs/cljs/core.cljs

@@ -4423,27 +4423,57 @@ reduces them without incurring seq initialization"
         new-value))
     (-reset! a new-value)))
 
+(defn reset-vals!
+  "Sets the value of atom to newval. Returns [old new], the value of the
+   atom before and after the reset."
+  {:added "1.9"}
+  [a new-value]
+  (let [validate (.-validator a)]
+    (when-not (nil? validate)
+      (when-not (validate new-value)
+        (throw (js/Error. "Validator rejected reference state"))))
+    (let [old-value (.-state a)]
+      (set! (.-state a) new-value)
+      (when-not (nil? (.-watches a))
+        (-notify-watches a old-value new-value))
+      [old-value new-value])))
+
 (defn swap!
   "Atomically swaps the value of atom to be:
   (apply f current-value-of-atom args). Note that f may be called
   multiple times, and thus should be free of side effects.  Returns
   the value that was swapped in."
   ([a f]
-     (if (instance? Atom a)
-       (reset! a (f (.-state a)))
-       (-swap! a f)))
+   (if (instance? Atom a)
+     (reset! a (f (.-state a)))
+     (-swap! a f)))
+  ([a f x]
+   (if (instance? Atom a)
+     (reset! a (f (.-state a) x))
+     (-swap! a f x)))
+  ([a f x y]
+   (if (instance? Atom a)
+     (reset! a (f (.-state a) x y))
+     (-swap! a f x y)))
+  ([a f x y & more]
+   (if (instance? Atom a)
+     (reset! a (apply f (.-state a) x y more))
+     (-swap! a f x y more))))
+
+(defn swap-vals!
+  "Atomically swaps the value of atom to be:
+  (apply f current-value-of-atom args). Note that f may be called
+  multiple times, and thus should be free of side effects.
+  Returns [old new], the value of the atom before and after the swap."
+  {:added "1.9"}
+  ([a f]
+   (reset-vals! a (f (.-state a))))
   ([a f x]
-     (if (instance? Atom a)
-       (reset! a (f (.-state a) x))
-       (-swap! a f x)))
+   (reset-vals! a (f (.-state a) x)))
   ([a f x y]
-     (if (instance? Atom a)
-       (reset! a (f (.-state a) x y))
-       (-swap! a f x y)))
+   (reset-vals! a (f (.-state a) x y)))
   ([a f x y & more]
-     (if (instance? Atom a)
-       (reset! a (apply f (.-state a) x y more))
-       (-swap! a f x y more))))
+   (reset-vals! a (apply f (.-state a) x y more))))
 
 (defn compare-and-set!
   "Atomically sets the value of atom to newval if and only if the

src/test/cljs/cljs/core_test.cljs

@@ -1448,6 +1448,31 @@
   (is (= "#js {:_abc 1}" (pr-str #js {"_abc" 1})))
   (is (= "#js {:*compiler* 1}" (pr-str #js {"*compiler*" 1}))))
 
+(deftest swap-vals-returns-old-value
+  (let [a (atom 0)]
+    (is (= [0 1] (swap-vals! a inc)))
+    (is (= [1 2] (swap-vals! a inc)))
+    (is (= 2 @a))))
+
+(deftest deref-swap-arities
+  (binding [*warn-on-reflection* true]
+    (let [a (atom 0)]
+      (is (= [0 1] (swap-vals! a + 1)))
+      (is (= [1 3] (swap-vals! a + 1 1)))
+      (is (= [3 6] (swap-vals! a + 1 1 1)))
+      (is (= [6 10] (swap-vals! a + 1 1 1 1)))
+      (is (= 10 @a)))))
+
+(deftest deref-reset-returns-old-value
+  (let [a (atom 0)]
+    (is (= [0 :b] (reset-vals! a :b)))
+    (is (= [:b 45M] (reset-vals! a 45M)))
+    (is (= 45M @a))))
+
+(deftest reset-on-deref-reset-equality
+  (let [a (atom :usual-value)]
+    (is (= :usual-value (reset! a (first (reset-vals! a :almost-never-seen-value)))))))
+
 (comment
   ;; ObjMap
   ;; (let [ks (map (partial str "foo") (range 500))