Enhancements to pico_flash task

UncleGrumpy · UncleGrumpy · commit ec4fd6d16ee3 · 2025-07-11T19:14:37.000Z
Improves compatibility with RP2350 devices, detecting path and reset devices correctly so setting explicit path to the mount point is no longer necessary for these devices. The provider also now confirms that the target is an RP2 device before resetting to `BOOTSEL` mode, preventing interference with non RP2 devices that may be attached to the host system. Closes #44 Signed-off-by: Winford <winford@object.stream>
diff --git a/CHANGELOG.md b/CHANGELOG.md
@@ -15,10 +15,13 @@ and this project adheres to [Semantic Versioning](https://semver.org/spec/v2.0.0
 
 ### Added
 - Added dialyzer task to simplify running dialyzer on AtomVM applications.
+- Added support for rp2350 devices to allow for default detection of the device mount path.
 
 ### Changed
 - The `uf2create` task now creates `universal` format uf2 files by default, suitable for both
 rp2040 or rp2350 devices.
+- The `pico_flash` task now checks that a device is an RP2 platform before resetting to `BOOTSEL`
+mode, preventing interference with other MCUs that may be attached to the host system.
 
 ## [0.7.5] (2025.05.27)
 
diff --git a/src/atomvm_pico_flash_provider.erl b/src/atomvm_pico_flash_provider.erl
@@ -104,11 +104,11 @@ env_opts() ->
     #{
         path => os:getenv(
             "ATOMVM_REBAR3_PLUGIN_PICO_MOUNT_PATH",
-            get_default_mount()
+            os:getenv("ATOMVM_PICO_MOUNT_PATH", "")
         ),
         reset => os:getenv(
             "ATOMVM_REBAR3_PLUGIN_PICO_RESET_DEV",
-            get_reset_base()
+            get_reset_dev()
         )
     }.
 
@@ -123,78 +123,103 @@ get_stty_file_flag() ->
     end.
 
 %% @private
-get_reset_base() ->
+get_reset_dev() ->
     {_Fam, System} = os:type(),
     Base =
         case System of
             linux ->
-                "/dev/ttyACM*";
+                filelib:wildcard("/dev/serial/by-id/usb-Raspberry_Pi_Pico_????????????????-if00");
             darwin ->
-                "/dev/cu.usbmodem14*";
+                Bin = darwin_ioreg:pico_callout_devices(),
+                lists:foldl(fun(Path, Acc) -> [binary_to_list(Path) | Acc] end, [], Bin);
             _Other ->
-                ""
+                []
         end,
     os:getenv("ATOMVM_PICO_RESET_DEV", Base).
 
-%% @private
-get_default_mount() ->
+%%% @private
+find_mounted_pico() ->
     {_Fam, System} = os:type(),
-    Default =
+    Wildcard =
         case System of
             linux ->
-                "/run/media/" ++ os:getenv("USER") ++ "/RPI-RP2";
+                "/run/media/" ++ os:getenv("USER") ++ "/{RPI-RP2,RP2350}";
             darwin ->
-                "/Volumes/RPI-RP2";
+                "/Volumes/{RPI-RP2,RP2350}";
             _Other ->
                 ""
         end,
-    os:getenv("ATOMVM_PICO_MOUNT_PATH", Default).
+    case filelib:wildcard(Wildcard) of
+        [Pico | _] = Path ->
+            rebar_api:debug("Found pico device, using ~p from devices list: ~p", [Pico, Path]),
+            {ok, Pico};
+        _ ->
+            not_found
+    end.
 
 %% @private
 wait_for_mount(Mount, Count) when Count < 30 ->
-    try
-        case file:read_link_info(Mount) of
-            {ok, #file_info{type = directory} = _Info} ->
-                ok;
-            _ ->
-                timer:sleep(1000),
-                wait_for_mount(Mount, Count + 1)
-        end
-    catch
-        _ ->
-            timer:sleep(1000),
-            wait_for_mount(Mount, Count + 1)
+    case Mount of
+        "" ->
+            case find_mounted_pico() of
+                not_found ->
+                    timer:sleep(1000),
+                    wait_for_mount(Mount, Count + 1);
+                {ok, Pico} ->
+                    case file:read_link_info(Pico) of
+                        {ok, #file_info{type = directory} = _Info} ->
+                            {ok, Pico};
+                        Err ->
+                            rebar_api:abort("Pico mount point is not a directory (~p)", [Err])
+                    end
+            end;
+        Path ->
+            case file:read_link_info(Path) of
+                {ok, #file_info{type = directory} = _Info} ->
+                    {ok, Path};
+                _ ->
+                    timer:sleep(1000),
+                    wait_for_mount(Mount, Count + 1)
+            end
     end;
-wait_for_mount(Mount, 30) ->
-    rebar_api:error("Pico not mounted at ~s after 30 seconds. giving up...", [Mount]),
-    erlang:throw(mount_error).
+wait_for_mount(_Mount, 30) ->
+    rebar_api:abort("Pico not mounted after 30 seconds. giving up...", []).
 
 %% @private
-check_pico_mount(Mount) ->
-    try
-        case file:read_link_info(Mount) of
-            {ok, #file_info{type = directory} = _Info} ->
-                rebar_api:debug("Pico mounted at ~s.", [Mount]),
-                ok;
-            _ ->
-                rebar_api:error("Pico not mounted at ~s.", [Mount]),
-                erlang:throw(no_device)
-        end
-    catch
-        _ ->
-            rebar_api:error("Pico not mounted at ~s.", [Mount]),
-            erlang:throw(no_device)
+get_pico_mount(Mount) ->
+    case Mount of
+        "" ->
+            case find_mounted_pico() of
+                not_found ->
+                    rebar_api:info("Waiting for an RP2 device to mount...", []),
+                    wait_for_mount(Mount, 0);
+                {ok, Pico} ->
+                    {ok, Pico}
+            end;
+        Path ->
+            case file:read_link_info(Path) of
+                {ok, #file_info{type = directory} = _Info} ->
+                    rebar_api:debug("Pico mounted at ~s.", [Mount]),
+                    {ok, Path};
+                _ ->
+                    rebar_api:info("Waiting for the device at path ~s to mount...", [
+                        string:trim(Mount)
+                    ]),
+                    wait_for_mount(Mount, 0)
+            end
     end.
 
 %% @private
-needs_reset(ResetBase) ->
-    case filelib:wildcard(ResetBase) of
+needs_reset(ResetDev) ->
+    case ResetDev of
         [] ->
             false;
         [ResetPort | _T] ->
             case file:read_link_info(ResetPort) of
                 {ok, #file_info{type = device} = _Info} ->
                     {true, ResetPort};
+                {ok, #file_info{type = symlink} = _Info} ->
+                    {true, ResetPort};
                 _ ->
                     false
             end;
@@ -208,7 +233,7 @@ do_reset(ResetPort) ->
     BootselMode = lists:join(" ", [
         "stty", Flag, ResetPort, "1200"
     ]),
-    rebar_api:debug("Resetting device at path ~s", [ResetPort]),
+    rebar_api:info("Resetting device at path ~s", [ResetPort]),
     ResetStatus = os:cmd(BootselMode),
     case ResetStatus of
         "" ->
@@ -259,31 +284,29 @@ get_uf2_appname(ProjectApps) ->
     binary_to_list(rebar_app_info:name(App)).
 
 %% @private
-do_flash(ProjectApps, PicoPath, ResetBase) ->
-    case needs_reset(ResetBase) of
+do_flash(ProjectApps, PicoPath, ResetDev) ->
+    case needs_reset(ResetDev) of
         false ->
-            rebar_api:debug("No Pico found matching ~s.", [ResetBase]),
+            rebar_api:debug("No Pico reset device found matching ~s.", [ResetDev]),
             ok;
         {true, ResetPort} ->
             rebar_api:debug("Pico at ~s needs reset...", [ResetPort]),
             do_reset(ResetPort),
-            rebar_api:info("Waiting for the device at path ~s to settle and mount...", [
-                string:trim(PicoPath)
-            ]),
+            rebar_api:info("Waiting for the device at path ~s to settle and mount...", [PicoPath]),
             wait_for_mount(PicoPath, 0)
     end,
-    check_pico_mount(PicoPath),
+    {ok, Path} = get_pico_mount(PicoPath),
     TargetUF2 = get_uf2_file(ProjectApps),
     App = get_uf2_appname(ProjectApps),
     File = App ++ ".uf2",
-    Dest = filename:join(PicoPath, File),
-    rebar_api:info("Copying ~s", [File]),
+    Dest = filename:join(Path, File),
+    rebar_api:info("Copying ~s to ~s", [File, Path]),
     case file:copy(TargetUF2, Dest) of
         {ok, _Size} ->
             ok;
         CopyError ->
             rebar_api:error("Failed to copy application file ~s to pico: ~s", [File, CopyError]),
             erlang:throw(picoflash_copy_error)
     end,
-    rebar_api:info("Successfully loaded ~s application to device at path ~s.", [App, PicoPath]),
+    rebar_api:info("Successfully loaded ~s application to the device.", [App]),
     ok.
diff --git a/src/darwin_ioreg.erl b/src/darwin_ioreg.erl
@@ -0,0 +1,70 @@
+%
+% This file is part of atomvm_rebar3_plugin.
+%
+% Copyright 2025 Paul Guyot <pguyot@kallisys.net>
+%
+% Licensed under the Apache License, Version 2.0 (the "License");
+% you may not use this file except in compliance with the License.
+% You may obtain a copy of the License at
+%
+%    http://www.apache.org/licenses/LICENSE-2.0
+%
+% Unless required by applicable law or agreed to in writing, software
+% distributed under the License is distributed on an "AS IS" BASIS,
+% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+% See the License for the specific language governing permissions and
+% limitations under the License.
+%
+% SPDX-License-Identifier: Apache-2.0 OR LGPL-2.1-or-later
+%
+
+-module(darwin_ioreg).
+
+-export([
+    pico_callout_devices/0
+]).
+
+% Parse ioreg output to find out the callout devices attached to Pico.
+% No pico connected:
+% 1> darwin_ioreg:pico_callout_devices().
+% []
+% One pico connected:
+% 2> darwin_ioreg:pico_callout_devices().
+% [<<"/dev/cu.usbmodem14401">>]
+% Two picos connected:
+% 3> darwin_ioreg:pico_callout_devices().
+% [<<"/dev/cu.usbmodem14401">>,<<"/dev/cu.usbmodem14301">>]
+-spec pico_callout_devices() -> [unicode:unicode_binary()].
+pico_callout_devices() ->
+    ResultStr = os:cmd("ioreg -r -n IOSerialBSDClient -t"),
+    ResultBin = list_to_binary(ResultStr),
+    ResultLines = binary:split(ResultBin, <<"\n">>, [global]),
+    parse(ResultLines, []).
+
+parse([<<"+-o Root  ", _/binary>> | T], Acc) ->
+    parse_tree(T, root, Acc);
+parse([<<" ", Rest/binary>> | T], Acc) ->
+    parse([Rest | T], Acc);
+parse([<<>> | T], Acc) ->
+    parse(T, Acc);
+parse([], Acc) ->
+    Acc.
+
+parse_tree([<<" ", Rest/binary>> | T], IsPico, Acc) ->
+    parse_tree([Rest | T], IsPico, Acc);
+parse_tree([<<"+-o Pico@", _/binary>> | T], root, Acc) ->
+    parse_tree(T, true, Acc);
+parse_tree([<<"+-o IOSerialBSDClient ", _/binary>> | T], IsPico, Acc) ->
+    parse_ioserialbsdclient(T, IsPico, Acc);
+parse_tree([<<"+-o ", _/binary>> | T], IsPico, Acc) ->
+    parse_tree(T, IsPico, Acc).
+
+parse_ioserialbsdclient([<<" ", Rest/binary>> | T], IsPico, Acc) ->
+    parse_ioserialbsdclient([Rest | T], IsPico, Acc);
+parse_ioserialbsdclient([<<"\"IOCalloutDevice\" = \"", Rest/binary>> | T], true, Acc) ->
+    [CallOut | _] = binary:split(Rest, <<"\"">>),
+    parse_ioserialbsdclient(T, true, [CallOut | Acc]);
+parse_ioserialbsdclient([<<"}">> | T], _IsPico, Acc) ->
+    parse(T, Acc);
+parse_ioserialbsdclient([_Other | T], IsPico, Acc) ->
+    parse_ioserialbsdclient(T, IsPico, Acc).
