Added feature to automatically find Sketchbook location if option is enabled.

Author: MrPointer

cmake/Platform/System/BuildSystemInitializer.cmake

@@ -2,6 +2,7 @@ include(AvrToolsFinder)
 include(VersionDetector)
 include(PlatformInitializer)
 include(LinuxDistDetector)
+include(SketchbookFinder)
 
 function(find_required_platform_tools)
 
@@ -23,6 +24,9 @@ function(initialize_build_system)
     if (CMAKE_HOST_UNIX AND NOT CMAKE_HOST_APPLE) # Detect host's Linux distribution
         detect_host_linux_distribution()
     endif ()
+    if (AUTO_SET_SKETCHBOOK_PATH)
+        find_sketchbook_path()
+    endif ()
 
     initialize_arduino_platform()
 

cmake/Platform/System/DefaultsManager.cmake

@@ -39,15 +39,21 @@ endfunction()
 function(set_default_arduino_cmake_options)
 
     option(USE_DEFAULT_PLATFORM_IF_NONE_EXISTING
-            "Whether to use Arduino as default platform if none is supplied" ON)
+            "Whether to use Arduino as default platform if none is supplied"
+            ON)
     option(USE_CUSTOM_PLATFORM_HEADER
             "Whether to expect and use a custom-supplied platform header, \
-            skipping the selection algorithm" OFF)
+            skipping the selection algorithm"
+            OFF)
     option(USE_ARCHLINUX_BUILTIN_SUPPORT
-            "Whether to use Arduino CMake's built-in support for the archlinux distribution" ON)
+            "Whether to use Arduino CMake's built-in support for the archlinux distribution"
+            ON)
     option(CONVERT_SKETCHES_IF_CONVERTED_SOURCES_EXISTS
             "Whether to convert sketches to source files even if converted sources already exist"
             OFF)
+    option(AUTO_SET_SKETCHBOOK_PATH
+            "Whether Arduino IDE's Sketchbook Location should be automatically found"
+            ON)
 
 endfunction()
 

cmake/Platform/System/SketchbookFinder.cmake

@@ -0,0 +1,51 @@
+#=============================================================================#
+# Gets the path of the user's Arduino IDE preferences file, usually located in a hidden directory
+# under the home directory.
+#       _return_var - Name of variable in parent-scope holding the return value.
+#       Returns - Filtered list of architectures.
+#=============================================================================#
+function(_get_user_preferences_file_path _return_var)
+
+    set(preferences_file_name preferences.txt)
+
+    if (${CMAKE_HOST_UNIX})
+        if (${CMAKE_HOST_APPLE}) # Mac OS X
+            set(dir_path "$ENV{HOME}/Library/Processing/${preferences_file_name}")
+        else () # Linux
+            set(dir_path "$ENV{HOME}/.processing/${preferences_file_name}")
+        endif ()
+    else () # Windows
+        string(REPLACE "\\" "/" home_path $ENV{HOMEPATH})
+        string(REPLACE "\\" "/" home_drive $ENV{HOMEDRIVE})
+        string(CONCAT home_path ${home_drive} ${home_path})
+        set(dir_path "${home_path}/AppData/Local/arduino15/${preferences_file_name}")
+    endif ()
+
+    set(${_return_var} ${dir_path} PARENT_SCOPE)
+
+endfunction()
+
+#=============================================================================#
+# Finds the location of Arduino IDE's Sketchbook directory, where all libraries and sketches
+# are downloaded to.
+#=============================================================================#
+function(find_sketchbook_path)
+
+    _get_user_preferences_file_path(arduino_ide_preferences_file)
+    if (NOT EXISTS "${arduino_ide_preferences_file}")
+        string(CONCAT error_message
+                "Arduino IDE preferences file couldn't be found at "
+                "${arduino_ide_preferences_file}.\n"
+                "ARDUINO_CMAKE_SKETCHBOOK_PATH should be manually set to the real Sketchbook path")
+        message(WARNING ${error_message})
+        return()
+    endif ()
+
+    file(STRINGS "${arduino_ide_preferences_file}" arduino_ide_preferences)
+    list(FILTER arduino_ide_preferences INCLUDE REGEX "sketchbook")
+    _get_property_value(${arduino_ide_preferences} sketchbook_path)
+
+    set(ARDUINO_CMAKE_SKETCHBOOK_PATH "${sketchbook_path}" CACHE PATH
+            "Arduino IDE's Sketchbook Path")
+
+endfunction()