Add ws2812 example (#742)

Author: Grazfather

examples/wch/ch32v/build.zig

@@ -31,6 +31,7 @@ pub fn build(b: *std.Build) void {
         .{ .target = mb.ports.ch32v.chips.ch32v203x6, .name = "blinky_ch32v203", .file = "src/blinky.zig" },
         .{ .target = mb.ports.ch32v.chips.ch32v203x6, .name = "blinky_systick_ch32v203", .file = "src/blinky_systick.zig" },
         .{ .target = mb.ports.ch32v.boards.ch32v203.suzuduino_uno_v1b, .name = "suzuduino_blinky", .file = "src/board_blinky.zig" },
+        .{ .target = mb.ports.ch32v.boards.ch32v203.lana_tny, .name = "lana_tny_ws2812", .file = "src/ws2812.zig" },
 
         // CH32V30x
         .{ .target = mb.ports.ch32v.chips.ch32v303xb, .name = "empty_ch32v303", .file = "src/empty.zig" },

examples/wch/ch32v/src/ws2812.zig

@@ -0,0 +1,114 @@
+const microzig = @import("microzig");
+const board = microzig.board;
+const hal = microzig.hal;
+const cpu = microzig.cpu;
+
+// Taken from https://github.com/robinjanssens/WCH-Toolchain
+
+pub fn main() !void {
+    // Board brings up clocks and time
+    board.init();
+
+    const pins = board.pin_config.apply();
+    const ws2812_pin = pins.ws2812;
+
+    var i: u8 = 0;
+    while (true) {
+        const col: u32 = wheel(i);
+        set_led(0, red(col), green(col), blue(col));
+        write(ws2812_pin);
+        hal.time.sleep_ms(33);
+        // Allow overflow to wrap around
+        i +%= 1;
+    }
+}
+
+// Board has a single LED
+const NUM_LEDS = 1;
+
+fn color(r: u8, g: u8, b: u8) u32 {
+    return (@as(u32, r) << 16) | (@as(u32, g) << 8) | b;
+}
+
+fn red(col: u32) u8 {
+    return @truncate((col >> 16) & 0xFF);
+}
+
+fn green(col: u32) u8 {
+    return @truncate((col >> 8) & 0xFF);
+}
+
+fn blue(col: u32) u8 {
+    return @truncate(col & 0xFF);
+}
+
+fn wheel(wheel_pos: u8) u32 {
+    var pos = 255 -% wheel_pos;
+    if (pos < 85) {
+        return color(255 -% pos *% 3, 0, pos *% 3);
+    } else if (pos < 170) {
+        pos -%= 85;
+        return color(0, pos *% 3, 255 -% pos *% 3);
+    } else {
+        pos -%= 170;
+        return color(pos *% 3, 255 -% pos *% 3, 0);
+    }
+}
+
+var rgb_array: [3 * NUM_LEDS]u8 = undefined; // Each color is 3 bytes
+
+inline fn nops(comptime n: usize) void {
+    inline for (0..n) |_| asm volatile ("nop");
+}
+
+// Compact timing-accurate bit send using pin.put + NOP sequences
+fn led_send_bit(pin: anytype, bit: u1) void {
+    if (bit != 0) {
+        // T1H ≈ 800 ns @ 48 MHz
+        pin.put(1);
+        nops(34);
+        pin.put(0);
+        // T1L ≈ 400Ns, taken up by other functions
+        return;
+    }
+    // T0H ≈ 400 ns
+    pin.put(1);
+    nops(14);
+    pin.put(0);
+    // T0L ≈ 850 ns, 400 ns is taken up by other functions
+    nops(20);
+}
+
+// Send a single color for a single LED
+// WS2812B LEDs want 24 bits per led in the string
+fn led_send_color(pin: anytype, r: u8, g: u8, b: u8) void {
+    // Send the green component first (MSB)
+    var i: i32 = 7;
+    while (i >= 0) : (i -= 1) {
+        led_send_bit(pin, @truncate((g >> @intCast(i)) & 1));
+    }
+    // Send the red component next
+    i = 7;
+    while (i >= 0) : (i -= 1) {
+        led_send_bit(pin, @truncate((r >> @intCast(i)) & 1));
+    }
+    // Send the blue component last (LSB)
+    i = 7;
+    while (i >= 0) : (i -= 1) {
+        led_send_bit(pin, @truncate((b >> @intCast(i)) & 1));
+    }
+}
+
+fn write(pin: anytype) void {
+    var i: usize = 0;
+    while (i < NUM_LEDS) : (i += 1) {
+        led_send_color(pin, rgb_array[i * 3], rgb_array[i * 3 + 1], rgb_array[i * 3 + 2]);
+    }
+    hal.time.sleep_ms(1);
+}
+
+fn set_led(i: usize, r: u8, g: u8, b: u8) void {
+    rgb_array[i * 3] = r;
+    rgb_array[i * 3 + 1] = g;
+    rgb_array[i * 3 + 2] = b;
+}

port/wch/ch32v/src/boards/LANA_TNY.zig

@@ -18,7 +18,6 @@ pub const pin_config = ch32v.pins.GlobalConfiguration{
         .PIN0 = .{
             .name = "ws2812",
             .mode = .{ .output = .general_purpose_push_pull },
-            .speed = .max_50MHz,
         },
     },
 };

port/wch/ch32v/src/hals/pins.zig

@@ -185,6 +185,25 @@ pub const GlobalConfiguration = struct {
     }
 
     pub fn apply(comptime config: GlobalConfiguration) Pins(config) {
+        // Check if we need to enable AFIO for GPIOD PD0/PD1 remapping
+        comptime var needs_pd01_remap = false;
+        if (config.GPIOD) |gpiod_config| {
+            if (gpiod_config.PIN0 != null or gpiod_config.PIN1 != null) {
+                needs_pd01_remap = true;
+            }
+        }
+
+        // Enable clocks first for PD0/PD1 remapping (must be done before remap)
+        if (needs_pd01_remap) {
+            // Enable AFIO and GPIOD clocks
+            RCC.APB2PCENR.modify(.{ .AFIOEN = 1, .IOPDEN = 1 });
+
+            // Remap PD0/PD1 from OSCIN/OSCOUT to GPIO
+            // On CH32V20x, AFIO.PCFR1.PD01_RM = 1 selects PD0/PD1 as GPIO pins.
+            const AFIO = microzig.chip.peripherals.AFIO;
+            AFIO.PCFR1.modify(.{ .PD01_RM = 1 });
+        }
+
         inline for (@typeInfo(GlobalConfiguration).@"struct".fields) |port_field| {
             if (@field(config, port_field.name)) |port_config| {
                 comptime var input_gpios: u16 = 0;