|
| 1 | +# Equality of extensions of dependent maps |
| 2 | + |
| 3 | +```agda |
| 4 | +module orthogonal-factorization-systems.equality-extensions-dependent-maps where |
| 5 | +``` |
| 6 | + |
| 7 | +<details><summary>Imports</summary> |
| 8 | + |
| 9 | +```agda |
| 10 | +open import foundation.dependent-pair-types |
| 11 | +open import foundation.equivalences |
| 12 | +open import foundation.fundamental-theorem-of-identity-types |
| 13 | +open import foundation.homotopies |
| 14 | +open import foundation.homotopy-induction |
| 15 | +open import foundation.identity-types |
| 16 | +open import foundation.structure-identity-principle |
| 17 | +open import foundation.universe-levels |
| 18 | +open import foundation.whiskering-homotopies-composition |
| 19 | +
|
| 20 | +open import foundation-core.torsorial-type-families |
| 21 | +
|
| 22 | +open import orthogonal-factorization-systems.extensions-dependent-maps |
| 23 | +``` |
| 24 | + |
| 25 | +</details> |
| 26 | + |
| 27 | +## Idea |
| 28 | + |
| 29 | +We characterize equality of |
| 30 | +[extensions](orthogonal-factorization-systems.extensions-dependent-maps.md) of |
| 31 | +dependent maps. |
| 32 | + |
| 33 | +## Definition |
| 34 | + |
| 35 | +### Homotopies of extensions of dependent maps |
| 36 | + |
| 37 | +```agda |
| 38 | +module _ |
| 39 | + {l1 l2 l3 : Level} {A : UU l1} {B : UU l2} (i : A → B) |
| 40 | + {P : B → UU l3} (f : (x : A) → P (i x)) |
| 41 | + where |
| 42 | +
|
| 43 | + coherence-htpy-extension-dependent-map : |
| 44 | + (e e' : extension-dependent-map i P f) → |
| 45 | + map-extension-dependent-map e ~ map-extension-dependent-map e' → |
| 46 | + UU (l1 ⊔ l3) |
| 47 | + coherence-htpy-extension-dependent-map e e' K = |
| 48 | + ( is-extension-map-extension-dependent-map e ∙h (K ·r i)) ~ |
| 49 | + ( is-extension-map-extension-dependent-map e') |
| 50 | +
|
| 51 | + htpy-extension-dependent-map : |
| 52 | + (e e' : extension-dependent-map i P f) → UU (l1 ⊔ l2 ⊔ l3) |
| 53 | + htpy-extension-dependent-map e e' = |
| 54 | + Σ ( map-extension-dependent-map e ~ map-extension-dependent-map e') |
| 55 | + ( coherence-htpy-extension-dependent-map e e') |
| 56 | +
|
| 57 | + refl-htpy-extension-dependent-map : |
| 58 | + (e : extension-dependent-map i P f) → htpy-extension-dependent-map e e |
| 59 | + pr1 (refl-htpy-extension-dependent-map e) = refl-htpy |
| 60 | + pr2 (refl-htpy-extension-dependent-map e) = right-unit-htpy |
| 61 | +``` |
| 62 | + |
| 63 | +### Homotopies of extensions with homotopies going the other way |
| 64 | + |
| 65 | +```agda |
| 66 | +module _ |
| 67 | + {l1 l2 l3 : Level} {A : UU l1} {B : UU l2} (i : A → B) |
| 68 | + {P : B → UU l3} (f : (x : A) → P (i x)) |
| 69 | + where |
| 70 | +
|
| 71 | + coherence-htpy-extension-dependent-map' : |
| 72 | + (e e' : extension-dependent-map' i P f) → |
| 73 | + map-extension-dependent-map' e ~ map-extension-dependent-map' e' → |
| 74 | + UU (l1 ⊔ l3) |
| 75 | + coherence-htpy-extension-dependent-map' e e' K = |
| 76 | + ( is-extension-map-extension-dependent-map' e) ~ |
| 77 | + ( K ·r i ∙h is-extension-map-extension-dependent-map' e') |
| 78 | +
|
| 79 | + htpy-extension-dependent-map' : |
| 80 | + (e e' : extension-dependent-map' i P f) → UU (l1 ⊔ l2 ⊔ l3) |
| 81 | + htpy-extension-dependent-map' e e' = |
| 82 | + Σ ( map-extension-dependent-map' e ~ map-extension-dependent-map' e') |
| 83 | + ( coherence-htpy-extension-dependent-map' e e') |
| 84 | +
|
| 85 | + refl-htpy-extension-dependent-map' : |
| 86 | + (e : extension-dependent-map' i P f) → htpy-extension-dependent-map' e e |
| 87 | + pr1 (refl-htpy-extension-dependent-map' e) = refl-htpy |
| 88 | + pr2 (refl-htpy-extension-dependent-map' e) = refl-htpy |
| 89 | +``` |
| 90 | + |
| 91 | +## Properties |
| 92 | + |
| 93 | +### Homotopies characterize equality |
| 94 | + |
| 95 | +```agda |
| 96 | +module _ |
| 97 | + {l1 l2 l3 : Level} {A : UU l1} {B : UU l2} (i : A → B) |
| 98 | + {P : B → UU l3} (f : (x : A) → P (i x)) |
| 99 | + where |
| 100 | +
|
| 101 | + htpy-eq-extension-dependent-map : |
| 102 | + (e e' : extension-dependent-map i P f) → |
| 103 | + e ＝ e' → htpy-extension-dependent-map i f e e' |
| 104 | + htpy-eq-extension-dependent-map e .e refl = |
| 105 | + refl-htpy-extension-dependent-map i f e |
| 106 | +
|
| 107 | + abstract |
| 108 | + is-torsorial-htpy-extension-dependent-map : |
| 109 | + (e : extension-dependent-map i P f) → |
| 110 | + is-torsorial (htpy-extension-dependent-map i f e) |
| 111 | + is-torsorial-htpy-extension-dependent-map e = |
| 112 | + is-torsorial-Eq-structure |
| 113 | + ( is-torsorial-htpy (map-extension-dependent-map e)) |
| 114 | + ( map-extension-dependent-map e , refl-htpy) |
| 115 | + ( is-torsorial-htpy |
| 116 | + ( is-extension-map-extension-dependent-map e ∙h |
| 117 | + refl-htpy)) |
| 118 | +
|
| 119 | + abstract |
| 120 | + is-equiv-htpy-eq-extension-dependent-map : |
| 121 | + (e e' : extension-dependent-map i P f) → |
| 122 | + is-equiv (htpy-eq-extension-dependent-map e e') |
| 123 | + is-equiv-htpy-eq-extension-dependent-map e = |
| 124 | + fundamental-theorem-id |
| 125 | + ( is-torsorial-htpy-extension-dependent-map e) |
| 126 | + ( htpy-eq-extension-dependent-map e) |
| 127 | +
|
| 128 | + extensionality-extension-dependent-map : |
| 129 | + (e e' : extension-dependent-map i P f) → |
| 130 | + (e ＝ e') ≃ htpy-extension-dependent-map i f e e' |
| 131 | + pr1 (extensionality-extension-dependent-map e e') = |
| 132 | + htpy-eq-extension-dependent-map e e' |
| 133 | + pr2 (extensionality-extension-dependent-map e e') = |
| 134 | + is-equiv-htpy-eq-extension-dependent-map e e' |
| 135 | +
|
| 136 | + eq-htpy-extension-dependent-map : |
| 137 | + (e e' : extension-dependent-map i P f) → |
| 138 | + htpy-extension-dependent-map i f e e' → e ＝ e' |
| 139 | + eq-htpy-extension-dependent-map e e' = |
| 140 | + map-inv-equiv (extensionality-extension-dependent-map e e') |
| 141 | +``` |
| 142 | + |
| 143 | +### Characterizing equality of extensions of dependent maps with homotopies going the other way |
| 144 | + |
| 145 | +```agda |
| 146 | +module _ |
| 147 | + {l1 l2 l3 : Level} {A : UU l1} {B : UU l2} (i : A → B) |
| 148 | + {P : B → UU l3} (f : (x : A) → P (i x)) |
| 149 | + where |
| 150 | +
|
| 151 | + htpy-eq-extension-dependent-map' : |
| 152 | + (e e' : extension-dependent-map' i P f) → |
| 153 | + e ＝ e' → htpy-extension-dependent-map' i f e e' |
| 154 | + htpy-eq-extension-dependent-map' e .e refl = |
| 155 | + refl-htpy-extension-dependent-map' i f e |
| 156 | +
|
| 157 | + abstract |
| 158 | + is-torsorial-htpy-extension-dependent-map' : |
| 159 | + (e : extension-dependent-map' i P f) → |
| 160 | + is-torsorial (htpy-extension-dependent-map' i f e) |
| 161 | + is-torsorial-htpy-extension-dependent-map' e = |
| 162 | + is-torsorial-Eq-structure |
| 163 | + ( is-torsorial-htpy (map-extension-dependent-map' e)) |
| 164 | + ( map-extension-dependent-map' e , refl-htpy) |
| 165 | + ( is-torsorial-htpy |
| 166 | + ( is-extension-map-extension-dependent-map' e)) |
| 167 | +
|
| 168 | + abstract |
| 169 | + is-equiv-htpy-eq-extension-dependent-map' : |
| 170 | + (e e' : extension-dependent-map' i P f) → |
| 171 | + is-equiv (htpy-eq-extension-dependent-map' e e') |
| 172 | + is-equiv-htpy-eq-extension-dependent-map' e = |
| 173 | + fundamental-theorem-id |
| 174 | + ( is-torsorial-htpy-extension-dependent-map' e) |
| 175 | + ( htpy-eq-extension-dependent-map' e) |
| 176 | +
|
| 177 | + extensionality-extension-dependent-map' : |
| 178 | + (e e' : extension-dependent-map' i P f) → |
| 179 | + (e ＝ e') ≃ (htpy-extension-dependent-map' i f e e') |
| 180 | + pr1 (extensionality-extension-dependent-map' e e') = |
| 181 | + htpy-eq-extension-dependent-map' e e' |
| 182 | + pr2 (extensionality-extension-dependent-map' e e') = |
| 183 | + is-equiv-htpy-eq-extension-dependent-map' e e' |
| 184 | +
|
| 185 | + eq-htpy-extension-dependent-map' : |
| 186 | + (e e' : extension-dependent-map' i P f) → |
| 187 | + htpy-extension-dependent-map' i f e e' → e ＝ e' |
| 188 | + eq-htpy-extension-dependent-map' e e' = |
| 189 | + map-inv-equiv (extensionality-extension-dependent-map' e e') |
| 190 | +``` |
0 commit comments