cmake: select precision(s) to build

Author: scivision

BLACS/CMakeLists.txt

@@ -1,4 +1,5 @@
 add_subdirectory(SRC)
-if(${SCALAPACK_BUILD_TESTS})
+
+if(SCALAPACK_BUILD_TESTS)
   add_subdirectory(TESTING)
 endif()

BLACS/SRC/CMakeLists.txt

@@ -1,18 +1,22 @@
 #  --------------------------
 #  The communication routines
 #  --------------------------
-set (comm
-       igesd2d_.c sgesd2d_.c dgesd2d_.c cgesd2d_.c zgesd2d_.c 	
-       itrsd2d_.c strsd2d_.c dtrsd2d_.c ctrsd2d_.c ztrsd2d_.c 
-       igerv2d_.c sgerv2d_.c dgerv2d_.c cgerv2d_.c zgerv2d_.c 
-       itrrv2d_.c strrv2d_.c dtrrv2d_.c ctrrv2d_.c ztrrv2d_.c 
-       igebs2d_.c sgebs2d_.c dgebs2d_.c cgebs2d_.c zgebs2d_.c 
-       igebr2d_.c sgebr2d_.c dgebr2d_.c cgebr2d_.c zgebr2d_.c 
-       itrbs2d_.c strbs2d_.c dtrbs2d_.c ctrbs2d_.c ztrbs2d_.c 
-       itrbr2d_.c strbr2d_.c dtrbr2d_.c ctrbr2d_.c ztrbr2d_.c 
-       igsum2d_.c sgsum2d_.c dgsum2d_.c cgsum2d_.c zgsum2d_.c 
-       igamx2d_.c sgamx2d_.c dgamx2d_.c cgamx2d_.c zgamx2d_.c 
-       igamn2d_.c sgamn2d_.c dgamn2d_.c cgamn2d_.c zgamn2d_.c)
+set(comm
+igesd2d_.c itrsd2d_.c igerv2d_.c itrrv2d_.c igebs2d_.c igebr2d_.c itrbs2d_.c itrbr2d_.c igsum2d_.c igamx2d_.c igamn2d_.c
+dgsum2d_.c dgamx2d_.c dgamn2d_.c
+)
+if(BUILD_SINGLE)
+  list(APPEND comm sgesd2d_.c strsd2d_.c sgerv2d_.c strrv2d_.c sgebs2d_.c sgebr2d_.c strbs2d_.c strbr2d_.c sgsum2d_.c sgamx2d_.c sgamn2d_.c)
+endif()
+if(BUILD_DOUBLE)
+  list(APPEND comm dgesd2d_.c dtrsd2d_.c dgerv2d_.c dtrrv2d_.c dgebs2d_.c dgebr2d_.c dtrbs2d_.c dtrbr2d_.c dgamx2d_.c)
+endif()
+if(BUILD_COMPLEX)
+  list(APPEND comm cgesd2d_.c ctrsd2d_.c cgerv2d_.c ctrrv2d_.c cgebs2d_.c cgebr2d_.c ctrbs2d_.c ctrbr2d_.c cgsum2d_.c cgamx2d_.c cgamn2d_.c)
+endif()
+if(BUILD_COMPLEX16)
+  list(APPEND comm zgesd2d_.c ztrsd2d_.c zgerv2d_.c ztrrv2d_.c zgebs2d_.c zgebr2d_.c ztrbs2d_.c ztrbr2d_.c zgsum2d_.c zgamx2d_.c zgamn2d_.c)
+endif()
 
 #  --------------------
 #  The support routines
@@ -39,18 +43,32 @@ set (internal
            BI_BuffIsFree.c BI_imvcopy.c BI_smvcopy.c BI_dmvcopy.c
            BI_ivmcopy.c BI_svmcopy.c BI_dvmcopy.c
            BI_Pack.c BI_Unpack.c BI_GetMpiGeType.c BI_GetMpiTrType.c
-           BI_ivvsum.c BI_svvsum.c BI_dvvsum.c BI_cvvsum.c BI_zvvsum.c
-           BI_ivvamx.c BI_svvamx.c BI_dvvamx.c BI_cvvamx.c BI_zvvamx.c
-           BI_ivvamx2.c BI_svvamx2.c BI_dvvamx2.c BI_cvvamx2.c BI_zvvamx2.c
-           BI_ivvamn.c BI_svvamn.c BI_dvvamn.c BI_cvvamn.c BI_zvvamn.c
-           BI_ivvamn2.c BI_svvamn2.c BI_dvvamn2.c BI_cvvamn2.c BI_zvvamn2.c
-           BI_iMPI_amx.c BI_sMPI_amx.c BI_dMPI_amx.c BI_cMPI_amx.c
-           BI_zMPI_amx.c BI_iMPI_amx2.c BI_sMPI_amx2.c BI_dMPI_amx2.c
-           BI_cMPI_amx2.c BI_zMPI_amx2.c BI_iMPI_amn.c BI_sMPI_amn.c
-           BI_dMPI_amn.c BI_cMPI_amn.c BI_zMPI_amn.c BI_iMPI_amn2.c
-           BI_sMPI_amn2.c BI_dMPI_amn2.c BI_cMPI_amn2.c BI_zMPI_amn2.c
-           BI_cMPI_sum.c BI_zMPI_sum.c BI_ContxtNum.c BI_GlobalVars.c
-           BI_TransUserComm.c )
+           BI_ivvsum.c BI_ivvamx.c BI_ivvamx2.c BI_ivvamn.c BI_ivvamn2.c
+           BI_iMPI_amx.c BI_iMPI_amx2.c BI_iMPI_amn.c BI_iMPI_amn2.c
+           BI_ContxtNum.c BI_GlobalVars.c BI_TransUserComm.c
+           BI_dvvsum.c BI_dvvamx.c BI_dvvamx2.c BI_dvvamn.c BI_dvvamn2.c
+           BI_dMPI_amx.c BI_dMPI_amx2.c BI_dMPI_amn.c BI_dMPI_amn2.c
+           BI_dmvcopy.c BI_dvmcopy.c
+)
+if(BUILD_SINGLE)
+  list(APPEND internal
+       BI_svvsum.c BI_svvamx.c BI_svvamx2.c BI_svvamn.c BI_svvamn2.c
+       BI_sMPI_amx.c BI_sMPI_amx2.c BI_sMPI_amn.c BI_sMPI_amn2.c
+       BI_smvcopy.c BI_svmcopy.c
+       )
+endif()
+if(BUILD_COMPLEX)
+  list(APPEND internal
+       BI_cvvsum.c BI_cvvamx.c BI_cvvamx2.c BI_cvvamn.c BI_cvvamn2.c
+       BI_cMPI_amx.c BI_cMPI_amx2.c BI_cMPI_amn.c BI_cMPI_amn2.c BI_cMPI_sum.c
+       )
+endif()
+if(BUILD_COMPLEX16)
+  list(APPEND internal
+       BI_zvvsum.c BI_zvvamx.c BI_zvvamx2.c BI_zvvamn.c BI_zvvamn2.c
+       BI_zMPI_amx.c BI_zMPI_amx2.c BI_zMPI_amn.c BI_zMPI_amn2.c BI_zMPI_sum.c
+       )
+endif()
 
 
 #
@@ -81,4 +99,3 @@ endforeach()
 set(blacs ${srcs} ${srcs_C} ${internal})
 #add_library(scalapack ${srcs} ${srcs_C} ${internal})
 #scalapack_install_library(scalapack)
-

BLACS/TESTING/CMakeLists.txt

@@ -1,12 +1,18 @@
+if(NOT (BUILD_SINGLE AND BUILD_DOUBLE AND BUILD_COMPLEX AND BUILD_COMPLEX16))
+  return()
+endif()
+
+set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
+
 set(FTestObj
    blacstest.f btprim.f tools.f)
 
-if ("${CMAKE_Fortran_COMPILER_ID}" STREQUAL "GNU" AND CMAKE_Fortran_COMPILER_VERSION VERSION_GREATER_EQUAL 10)
-    set_source_files_properties(blacstest.f PROPERTIES COMPILE_FLAGS "-std=legacy")
+if (CMAKE_Fortran_COMPILER_ID STREQUAL "GNU" AND CMAKE_Fortran_COMPILER_VERSION VERSION_GREATER_EQUAL 10)
+  set_source_files_properties(blacstest.f PROPERTIES COMPILE_FLAGS "-std=legacy")
 endif()
 
 add_executable(xFbtest ${FTestObj})
-target_link_libraries(xFbtest scalapack MPI::MPI_Fortran)
+target_link_libraries(xFbtest PRIVATE scalapack MPI::MPI_Fortran)
 
 set(CTestObj
    Cbt.c)
@@ -17,39 +23,30 @@ set_property(
    )
 
 add_executable(xCbtest ${CTestObj} ${FTestObj})
-target_link_libraries(xCbtest scalapack MPI::MPI_Fortran)
-
-file(COPY bsbr.dat DESTINATION ${SCALAPACK_BINARY_DIR}/BLACS/TESTING)
-file(COPY bt.dat DESTINATION ${SCALAPACK_BINARY_DIR}/BLACS/TESTING)
-file(COPY comb.dat DESTINATION ${SCALAPACK_BINARY_DIR}/BLACS/TESTING)
-file(COPY sdrv.dat DESTINATION ${SCALAPACK_BINARY_DIR}/BLACS/TESTING)
+target_link_libraries(xCbtest PRIVATE scalapack MPI::MPI_Fortran)
 
 # We could run the BLACS TESTING the following way
 # But BLACS TESTING are TESTING anormal exit so even if they pass,
 # CTest will determine they fail
 #add_test(xFbtest0 ${MPIEXEC} ${MPIEXEC_NUMPROC_FLAG} 4 ${MPIEXEC_PREFLAGS} ./xFbtest)
 #add_test(xCbtest0 ${MPIEXEC} ${MPIEXEC_NUMPROC_FLAG} 4 ${MPIEXEC_PREFLAGS} ./xCbtest)
 
-add_test(xCbtest
-     ${CMAKE_COMMAND}
-    -DMPIEXEC=${MPIEXEC}
+add_test(NAME xCbtest
+  COMMAND ${CMAKE_COMMAND}
+    -DMPIEXEC_EXECUTABLE=${MPIEXEC_EXECUTABLE}
     -DMPIEXEC_NUMPROC_FLAG=${MPIEXEC_NUMPROC_FLAG}
     -DMPIEXEC_PREFLAGS=${MPIEXEC_PREFLAGS}
-    -DTEST_PROG=xCbtest
-    -DOUTPUTDIR=${SCALAPACK_BINARY_DIR}/BLACS/TESTING
-    -DRUNTIMEDIR=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
-    -DSOURCEDIR=${CMAKE_CURRENT_SOURCE_DIR}
+    -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
+    -DEXE=$<TARGET_FILE:xCbtest>
     -P ${CMAKE_CURRENT_SOURCE_DIR}/runtest.cmake
     )
 
-add_test(xFbtest
-     ${CMAKE_COMMAND}
-    -DMPIEXEC=${MPIEXEC}
+add_test(NAME xFbtest
+  COMMAND ${CMAKE_COMMAND}
+    -DMPIEXEC_EXECUTABLE=${MPIEXEC_EXECUTABLE}
     -DMPIEXEC_NUMPROC_FLAG=${MPIEXEC_NUMPROC_FLAG}
     -DMPIEXEC_PREFLAGS=${MPIEXEC_PREFLAGS}
-    -DTEST_PROG=xFbtest
-    -DOUTPUTDIR=${SCALAPACK_BINARY_DIR}/BLACS/TESTING
-    -DRUNTIMEDIR=${CMAKE_RUNTIME_OUTPUT_DIRECTORY}
-    -DSOURCEDIR=${CMAKE_CURRENT_SOURCE_DIR}
+    -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}
+    -DEXE=$<TARGET_FILE:xFbtest>
     -P ${CMAKE_CURRENT_SOURCE_DIR}/runtest.cmake
     )

BLACS/TESTING/runtest.cmake

@@ -1,22 +1,28 @@
-message("Running BLACS TESTS")
-message(STATUS "${MPIEXEC} ${MPIEXEC_NUMPROC_FLAG} 4 ${MPIEXEC_PREFLAGS} ./${TEST_PROG}")
-message(STATUS "Output out_${TEST_PROG}.txt")
-file(COPY ${RUNTIMEDIR}/${TEST_PROG} DESTINATION ${OUTPUTDIR})
+get_filename_component(OUTPUTDIR ${EXE} DIRECTORY)
+get_filename_component(name ${EXE} NAME_WE)
 
-execute_process(COMMAND ${MPIEXEC} ${MPIEXEC_NUMPROC_FLAG} 4 ${MPIEXEC_PREFLAGS} ./${TEST_PROG}
-                OUTPUT_FILE "out_${TEST_PROG}.txt"
-                ERROR_FILE "error_${TEST_PROG}.txt"
-                RESULT_VARIABLE HAD_ERROR)
+set(cmd ${MPIEXEC_EXECUTABLE} ${MPIEXEC_NUMPROC_FLAG} 4 ${MPIEXEC_PREFLAGS} ${EXE})
+set(outfile ${OUTPUTDIR}/out_${name}.txt)
+set(errfile ${OUTPUTDIR}/err_${name}.txt)
+message(STATUS "Output/Error log files: ${outfile} ${errfile}")
+set(CMAKE_EXECUTE_PROCESS_COMMAND_ECHO STDOUT)
 
-if(HAD_ERROR)
+execute_process(COMMAND ${cmd}
+OUTPUT_FILE ${outfile}
+ERROR_FILE ${errfile}
+RESULT_VARIABLE HAD_ERROR
+WORKING_DIRECTORY ${SOURCE_DIR}
+)
+
+if(NOT HAD_ERROR EQUAL 0)
     # This is normal to exit in Error (good behaviour)
     # So we are going to check that the output have the last line of the testing : DONE BLACS_GRIDEXIT
-    file(READ "out_${TEST_PROG}.txt" TESTSTRING)
+    file(READ ${outfile} TESTSTRING)
 
-    STRING(REPLACE "DONE BLACS_GRIDEXIT" "BLACS OK" tmp ${TESTSTRING})
+    STRING(REPLACE "DONE BLACS_GRIDEXIT" "BLACS OK" tmp "${TESTSTRING}")
 
 if("${tmp}" STREQUAL "${TESTSTRING}")
-       message( STATUS "Error in error_${TEST_PROG}.txt")
+       message( STATUS "Error in ${errfile}")
        message(FATAL_ERROR "Test failed - Test did not reach DONE BLACS_GRIDEXIT")
 else()
        message( STATUS "Test Passed")

CMAKE/CheckBLACSCompilerFlags.cmake

@@ -1,10 +1,10 @@
 # This module checks against various known compilers and thier respective
 # flags to determine any specific flags needing to be set.
-# 
+#
 #  1.  If FPE traps are enabled either abort or disable them
 #  2.  Specify fixed form if needed
 #  3.  Ensure that Release builds use O2 instead of O3
-# 
+#
 #=============================================================================
 # Author: Chuck Atkins
 # Copyright 2011
@@ -16,7 +16,7 @@ set( FPE_EXIT FALSE )
 
 # GNU Fortran
 if( CMAKE_Fortran_COMPILER_ID STREQUAL "GNU" )
-  if( "${CMAKE_Fortran_FLAGS}" MATCHES "-ffpe-trap=[izoupd]") 
+  if( "${CMAKE_Fortran_FLAGS}" MATCHES "-ffpe-trap=[izoupd]")
     set( FPE_EXIT TRUE )
   endif()
 
@@ -55,12 +55,12 @@ elseif( CMAKE_Fortran_COMPILER_ID STREQUAL "HP" )
   if( "${CMAKE_Fortran_FLAGS}" MATCHES "\\+fp_exception" )
     set( FPE_EXIT TRUE )
   endif()
-  
+
   if( NOT ("${CMAKE_Fortran_FLAGS}" MATCHES "\\+fltconst_strict") )
     message( STATUS "Enabling strict float conversion with +fltconst_strict" )
     set( CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} +fltconst_strict"
          CACHE STRING "Flags for Fortran compiler." FORCE )
-  endif() 
+  endif()
 
   # Most versions of cmake don't have good default options for the HP compiler
   set( CMAKE_Fortran_FLAGS_DEBUG "${CMAKE_Fortran_FLAGS_DEBUG} -g"
@@ -76,13 +76,13 @@ endif()
 
 if( "${CMAKE_Fortran_FLAGS_RELEASE}" MATCHES "O[3-9]" )
   message( STATUS "Reducing RELEASE optimization level to O2" )
-  string( REGEX REPLACE "O[3-9]" "O2" CMAKE_Fortran_FLAGS_RELEASE 
+  string( REGEX REPLACE "O[3-9]" "O2" CMAKE_Fortran_FLAGS_RELEASE
           "${CMAKE_Fortran_FLAGS_RELEASE}" )
   set( CMAKE_Fortran_FLAGS_RELEASE "${CMAKE_Fortran_FLAGS_RELEASE}"
        CACHE STRING "Flags used by the compiler during release builds" FORCE )
 elseif ( "${CMAKE_Fortran_FLAGS_RELEASE}" MATCHES "Ofast" )
   message( STATUS "Reducing RELEASE optimization level to O2" )
-  string( REGEX REPLACE "Ofast" "O2" CMAKE_Fortran_FLAGS_RELEASE 
+  string( REGEX REPLACE "Ofast" "O2" CMAKE_Fortran_FLAGS_RELEASE
           "${CMAKE_Fortran_FLAGS_RELEASE}" )
   set( CMAKE_Fortran_FLAGS_RELEASE "${CMAKE_Fortran_FLAGS_RELEASE}"
        CACHE STRING "Flags used by the compiler during release builds" FORCE )

CMakeLists.txt

@@ -2,6 +2,20 @@ cmake_minimum_required(VERSION 3.9)
 
 project(SCALAPACK VERSION 2.2.1 LANGUAGES C Fortran)
 
+# --------------------------------------------------
+# Precision to build
+# By default all precisions are generated
+option(BUILD_SINGLE "Build single precision real" ON)
+option(BUILD_DOUBLE "Build double precision real" ON)
+option(BUILD_COMPLEX "Build single precision complex" ON)
+option(BUILD_COMPLEX16 "Build double precision complex" ON)
+if(BUILD_COMPLEX)
+  set(BUILD_SINGLE true)
+endif()
+if(BUILD_COMPLEX16)
+  set(BUILD_DOUBLE true)
+endif()
+
 # Configure the warning and code coverage suppression file
 configure_file(
   "${SCALAPACK_SOURCE_DIR}/CMAKE/CTestCustom.cmake.in"
@@ -26,7 +40,7 @@ set(CMAKE_PREFIX_PATH "${MPI_BASE_DIR};${CMAKE_PREFIX_PATH}")
 find_package(MPI)
 if (MPI_FOUND)
    message(STATUS "Found MPI_LIBRARY : ${MPI_FOUND} ")
-   
+
    find_program(MPI_C_COMPILER
       NAMES mpicc
       HINTS "${MPI_BASE_DIR}"
@@ -89,9 +103,7 @@ endmacro()
 # Testing
 SET(DART_TESTING_TIMEOUT 600)
 
-enable_testing()
 include(CTest)
-enable_testing()
 # --------------------------------------------------
 
 # Organize output files.  On Windows this also keeps .dll files next
@@ -171,9 +183,15 @@ else(LAPACK_FOUND)
       include(ExternalProject)
       ExternalProject_Add(
         lapack
-        URL http://www.netlib.org/lapack/lapack.tgz
-        CMAKE_ARGS -DCMAKE_INSTALL_PREFIX:PATH=${SCALAPACK_BINARY_DIR}
+        URL https://www.netlib.org/lapack/lapack.tgz
+        CMAKE_ARGS
+          -DCMAKE_INSTALL_PREFIX:PATH=${SCALAPACK_BINARY_DIR}
+          -DBUILD_SINGLE:BOOL=${BUILD_SINGLE}
+          -DBUILD_DOUBLE:BOOL=${BUILD_DOUBLE}
+          -DBUILD_COMPLEX:BOOL=${BUILD_COMPLEX}
+          -DBUILD_COMPLEX16:BOOL=${BUILD_COMPLEX16}
         PREFIX ${SCALAPACK_BINARY_DIR}/dependencies
+        TLS_VERIFY true
       )
       if (NOT MSVC)
          SET(LAPACK_LIBRARIES ${SCALAPACK_BINARY_DIR}/lib/liblapack.a CACHE STRING "LAPACK library" FORCE)
@@ -266,7 +284,7 @@ if(TARGET lapack)
 endif()
 
 option(SCALAPACK_BUILD_TESTS "Build all tests of the ScaLAPACK library" ON)
-if(${SCALAPACK_BUILD_TESTS})
+if(SCALAPACK_BUILD_TESTS)
   add_subdirectory(TESTING)
 endif()
 
@@ -332,3 +350,15 @@ install(FILES
 
 install(EXPORT scalapack-targets
   DESTINATION lib/cmake/scalapack-${SCALAPACK_VERSION})
+
+
+include(FeatureSummary)
+
+add_feature_info(real32 ${BUILD_SINGLE} "Build with single precision")
+add_feature_info(real64 ${BUILD_DOUBLE} "Build with double precision")
+add_feature_info(complex32 ${BUILD_COMPLEX} "Build with complex precision")
+add_feature_info(complex64 ${BUILD_COMPLEX16} "Build with complex16 precision")
+add_feature_info(tests ${SCALAPACK_BUILD_TESTS} "Build tests")
+add_feature_info(shared ${BUILD_SHARED_LIBS} "Build shared libraries")
+message(STATUS "${PROJECT_NAME} features enabled:")
+feature_summary(WHAT ENABLED_FEATURES)

PBLAS/CMakeLists.txt

@@ -1,5 +1,6 @@
 add_subdirectory(SRC)
-if(${SCALAPACK_BUILD_TESTS})
+
+if(SCALAPACK_BUILD_TESTS)
   add_subdirectory(TESTING)
   add_subdirectory(TIMING)
 endif()