Added keys and key types implementation.

Added exceptions, updated definitions.

Author: Pan

ssh/c_ssh.pxd

@@ -392,15 +392,15 @@ cdef extern from "libssh/libssh.h" nogil:
                         char **value)
     int ssh_options_get_port(ssh_session session, unsigned int * port_target)
     int ssh_pcap_file_close(ssh_pcap_file pcap)
-    ssh_pcap_file_free(ssh_pcap_file pcap)
+    void ssh_pcap_file_free(ssh_pcap_file pcap)
     ssh_pcap_file ssh_pcap_file_new()
     int ssh_pcap_file_open(ssh_pcap_file pcap, const char *filename)
 
     ctypedef int (*ssh_auth_callback) (const char *prompt, char *buf, size_t len,
                                        int echo, int verify, void *userdata)
 
     ssh_key ssh_key_new()
-    ssh_key_free (ssh_key key)
+    void ssh_key_free (ssh_key key)
     ssh_keytypes_e ssh_key_type(const ssh_key key)
     const char *ssh_key_type_to_char(ssh_keytypes_e type)
     ssh_keytypes_e ssh_key_type_from_name(const char *name)
@@ -452,14 +452,14 @@ cdef extern from "libssh/libssh.h" nogil:
 
     const char *ssh_pki_key_ecdsa_name(const ssh_key key)
 
-    ssh_print_hexa(const char *descr, const unsigned char *what, size_t len)
+    void ssh_print_hexa(const char *descr, const unsigned char *what, size_t len)
     int ssh_send_ignore (ssh_session session, const char *data)
     int ssh_send_debug (ssh_session session, const char *message, int always_display)
-    ssh_gssapi_set_creds(ssh_session session, const ssh_gssapi_creds creds)
+    void ssh_gssapi_set_creds(ssh_session session, const ssh_gssapi_creds creds)
     int ssh_scp_accept_request(ssh_scp scp)
     int ssh_scp_close(ssh_scp scp)
     int ssh_scp_deny_request(ssh_scp scp, const char *reason)
-    ssh_scp_free(ssh_scp scp)
+    void ssh_scp_free(ssh_scp scp)
     int ssh_scp_init(ssh_scp scp)
     int ssh_scp_leave_directory(ssh_scp scp)
     ssh_scp ssh_scp_new(ssh_session session, int mode, const char *location)
@@ -522,11 +522,11 @@ cdef extern from "libssh/libssh.h" nogil:
     int ssh_write_knownhost(ssh_session session)
     char *ssh_dump_knownhost(ssh_session session)
 
-    ssh_string_burn(ssh_string str)
+    void ssh_string_burn(ssh_string str)
     ssh_string ssh_string_copy(ssh_string str)
     void *ssh_string_data(ssh_string str)
     int ssh_string_fill(ssh_string str, const void *data, size_t len)
-    ssh_string_free(ssh_string str)
+    void ssh_string_free(ssh_string str)
     ssh_string ssh_string_from_char(const char *what)
     size_t ssh_string_len(ssh_string str)
     ssh_string ssh_string_new(size_t size)
@@ -548,7 +548,7 @@ cdef extern from "libssh/libssh.h" nogil:
     int ssh_event_remove_fd(ssh_event event, socket_t fd)
     int ssh_event_remove_session(ssh_event event, ssh_session session)
     int ssh_event_remove_connector(ssh_event event, ssh_connector connector)
-    ssh_event_free(ssh_event event)
+    void ssh_event_free(ssh_event event)
     const char* ssh_get_clientbanner(ssh_session session)
     const char* ssh_get_serverbanner(ssh_session session)
     const char* ssh_get_kex_algo(ssh_session session)
@@ -557,7 +557,7 @@ cdef extern from "libssh/libssh.h" nogil:
     const char* ssh_get_hmac_in(ssh_session session)
     const char* ssh_get_hmac_out(ssh_session session)
     ssh_buffer ssh_buffer_new()
-    ssh_buffer_free(ssh_buffer buffer)
+    void ssh_buffer_free(ssh_buffer buffer)
     int ssh_buffer_reinit(ssh_buffer buffer)
     int ssh_buffer_add_data(ssh_buffer buffer, const void *data, uint32_t len)
     uint32_t ssh_buffer_get_data(ssh_buffer buffer, void *data, uint32_t requestedlen)

ssh/exceptions.pyx

@@ -41,3 +41,16 @@ class AuthenticationDenied(BaseSSHError):
 
 class AuthenticationError(BaseSSHError):
     """Raised on fatal errors authenticating"""
+
+
+class KeyExportError(BaseSSHError):
+    """Raised on errors exporting key"""
+
+
+class KeyImportError(BaseSSHError):
+    """Raised on errors importing key"""
+
+    
+class KeyGenerationError(BaseSSHError):
+    """Raised on errors generating key"""
+

ssh/key.pxd

@@ -0,0 +1,24 @@
+# This file is part of ssh-python.
+# Copyright (C) 2018 Panos Kittenis
+#
+# This library is free software; you can redistribute it and/or
+# modify it under the terms of the GNU Lesser General Public
+# License as published by the Free Software Foundation, version 2.1.
+#
+# This library is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+# Lesser General Public License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public
+# License along with this library; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-130
+
+cimport c_ssh
+
+
+cdef class SSHKey:
+    cdef c_ssh.ssh_key _key
+    
+    @staticmethod
+    cdef SSHKey from_ptr(c_ssh.ssh_key key)

ssh/key.pyx

@@ -0,0 +1,202 @@
+# This file is part of ssh-python.
+# Copyright (C) 2018 Panos Kittenis
+#
+# This library is free software; you can redistribute it and/or
+# modify it under the terms of the GNU Lesser General Public
+# License as published by the Free Software Foundation, version 2.1.
+#
+# This library is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+# Lesser General Public License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public
+# License along with this library; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-130
+
+from libc.string cimport const_char
+
+from keytypes cimport from_keytype, KeyType
+from utils cimport to_str, to_bytes
+
+from .exceptions import KeyExportError, KeyImportError, KeyGenerationError
+
+cimport c_ssh
+
+
+cdef class SSHKey:
+
+    @staticmethod
+    cdef SSHKey from_ptr(c_ssh.ssh_key key):
+        cdef SSHKey _key = SSHKey.__new__(SSHKey)
+        _key._key = key
+        return _key
+
+    def __cinit__(self):
+        self._key = c_ssh.ssh_key_new()
+        if self._key is NULL:
+            raise MemoryError
+
+    def __dealloc__(self):
+        if self._key is not NULL:
+            c_ssh.ssh_key_free(self._key)
+            self._key = NULL
+
+    def is_private(self):
+        cdef bint rc
+        with nogil:
+            rc = c_ssh.ssh_key_is_private(self._key)
+        return bool(rc)
+
+    def is_public(self):
+        cdef bint rc
+        with nogil:
+            rc = c_ssh.ssh_key_is_public(self._key)
+        return bool(rc)
+
+    def __eq__(self, SSHKey other):
+        cdef bint is_private
+        cdef bint equal
+        with nogil:
+            is_private = c_ssh.ssh_key_is_private(self._key)
+            equal = c_ssh.ssh_key_cmp(
+                self._key, other._key, c_ssh.ssh_keycmp_e.SSH_KEY_CMP_PRIVATE) \
+                if is_private else \
+                   c_ssh.ssh_key_cmp(
+                       self._key, other._key,
+                       c_ssh.ssh_keycmp_e.SSH_KEY_CMP_PUBLIC)
+        return bool(equal)
+
+    def key_type(self):
+        cdef c_ssh.ssh_keytypes_e _type
+        with nogil:
+            _type = c_ssh.ssh_key_type(self._key)
+        return from_keytype(_type)
+
+    def ecdsa_name(self):
+        cdef const_char *c_name
+        cdef bytes b_name
+        with nogil:
+            c_name = c_ssh.ssh_pki_key_ecdsa_name(self._key)
+        b_name = c_name
+        return to_str(b_name)
+
+    def export_privkey_file(self, filepath, passphrase=None):
+        cdef bytes b_passphrase
+        cdef bytes b_filepath = to_bytes(filepath)
+        cdef const_char *c_passphrase = NULL
+        cdef const_char *c_filepath = b_filepath
+        cdef int rc
+        if passphrase is not None:
+            b_passphrase = to_bytes(passphrase)
+            c_passphrase = b_passphrase
+        with nogil:
+            rc = c_ssh.ssh_pki_export_privkey_file(
+                self._key, c_passphrase, NULL, NULL, c_filepath)
+        if rc != c_ssh.SSH_OK:
+            raise KeyExportError(c_ssh.ssh_get_error(self._key))
+
+    def export_privkey_to_pubkey(self):
+        cdef SSHKey pub_key
+        cdef c_ssh.ssh_key _pub_key
+        cdef int rc
+        with nogil:
+            rc = c_ssh.ssh_pki_export_privkey_to_pubkey(self._key, &_pub_key)
+        if rc != c_ssh.SSH_OK:
+            raise KeyExportError(c_ssh.ssh_get_error(self._key))
+        pub_key = SSHKey.from_ptr(_pub_key)
+        return pub_key
+
+    def export_pubkey_base64(self):
+        cdef char *_key
+        cdef int rc
+        cdef bytes b_key
+        cdef size_t key_len
+        with nogil:
+            rc = c_ssh.ssh_pki_export_pubkey_base64(self._key, &_key)
+            if rc != c_ssh.SSH_OK:
+                with gil:
+                    raise KeyExportError(c_ssh.ssh_get_error(self._key))
+        b_key = _key
+        c_ssh.ssh_string_free_char(_key)
+        return b_key
+
+
+def generate(KeyType key_type, int bits):
+    cdef SSHKey key
+    cdef c_ssh.ssh_key _key
+    cdef int rc
+    with nogil:
+        rc = c_ssh.ssh_pki_generate(key_type._type, bits, &_key)
+    if rc != c_ssh.SSH_OK:
+        raise KeyGenerationError(c_ssh.ssh_get_error(_key))
+    key = SSHKey.from_ptr(_key)
+    return key
+
+
+def import_privkey_base64(bytes b64_key, passphrase=None):
+    cdef const_char *c_key = b64_key
+    cdef bytes b_passphrase
+    cdef const_char *c_passphrase = NULL
+    cdef int rc
+    cdef SSHKey key
+    cdef c_ssh.ssh_key _key
+    if passphrase is not None:
+        b_passphrase = to_bytes(passphrase)
+        c_passphrase = b_passphrase
+    with nogil:
+        rc = c_ssh.ssh_pki_import_privkey_base64(
+            c_key, c_passphrase, NULL, NULL, &_key)
+    if rc != c_ssh.SSH_OK:
+        raise KeyImportError(c_ssh.ssh_get_error(_key))
+    key = SSHKey.from_ptr(_key)
+    return key
+
+
+def import_privkey_file(filepath, passphrase=None):
+    cdef bytes b_passphrase
+    cdef bytes b_filepath = to_bytes(filepath)
+    cdef const_char *c_passphrase = NULL
+    cdef const_char *c_filepath = b_filepath
+    cdef int rc
+    cdef SSHKey key
+    cdef c_ssh.ssh_key _key
+    if passphrase is not None:
+        b_passphrase = to_bytes(passphrase)
+        c_passphrase = b_passphrase
+    with nogil:
+        rc = c_ssh.ssh_pki_import_privkey_file(
+            c_filepath, c_passphrase, NULL, NULL, &_key)
+    if rc != c_ssh.SSH_OK:
+        raise KeyExportError(c_ssh.ssh_get_error(_key))
+    key = SSHKey.from_ptr(_key)
+    return key
+
+
+def import_pubkey_base64(bytes b64_key, KeyType key_type):
+    cdef const_char *c_key = b64_key
+    cdef int rc
+    cdef SSHKey key
+    cdef c_ssh.ssh_key _key
+    with nogil:
+        rc = c_ssh.ssh_pki_import_pubkey_base64(
+            c_key, key_type._type, &_key)
+    if rc != c_ssh.SSH_OK:
+        raise KeyImportError(c_ssh.ssh_get_error(_key))
+    key = SSHKey.from_ptr(_key)
+    return key
+
+
+def import_pubkey_file(filepath):
+    cdef bytes b_filepath = to_bytes(filepath)
+    cdef const_char *c_filepath = b_filepath
+    cdef int rc
+    cdef SSHKey key
+    cdef c_ssh.ssh_key _key
+    with nogil:
+        rc = c_ssh.ssh_pki_import_pubkey_file(
+            c_filepath, &_key)
+    if rc != c_ssh.SSH_OK:
+        raise KeyExportError(c_ssh.ssh_get_error(_key))
+    key = SSHKey.from_ptr(_key)
+    return key

ssh/keytypes.pxd

@@ -0,0 +1,48 @@
+# This file is part of ssh-python.
+# Copyright (C) 2018 Panos Kittenis
+#
+# This library is free software; you can redistribute it and/or
+# modify it under the terms of the GNU Lesser General Public
+# License as published by the Free Software Foundation, version 2.1.
+#
+# This library is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+# Lesser General Public License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public
+# License along with this library; if not, write to the Free Software
+# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-130
+
+from c_ssh cimport ssh_keytypes_e
+
+
+cdef class KeyType:
+    cdef ssh_keytypes_e _type
+
+
+cdef class DSSKey(KeyType):
+    pass
+
+
+cdef class RSAKey(KeyType):
+    pass
+
+
+cdef class RSA1Key(KeyType):
+    pass
+
+
+cdef class ECDSAKey(KeyType):
+    pass
+
+
+cdef class DSSCert01Key(KeyType):
+    pass
+
+
+cdef class RSACert01Key(KeyType):
+    pass
+
+
+cdef KeyType from_keytype(ssh_keytypes_e _type)