Implementing the "make install" for the OSI 2.

The cmake file from current master branch is reuse and adjusted to allow several OSI versions on the same computer.

The main idea is to install the into a directory that takes the version into account.

This draft uses the major version described inside the version file to configure the installation path.

Author: FabeleAltran

CMakeLists.txt

@@ -1,7 +1,34 @@
-cmake_minimum_required(VERSION 3.7)
+cmake_minimum_required(VERSION 3.5)
 
 project(open_simulation_interface)
 
+# Set a default build type if none was specified
+set(default_build_type "Release")
+if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
+  set(default_build_type "Debug")
+endif()
+
+if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
+  message(STATUS "Setting build type to '${default_build_type}' as none was specified.")
+  set(CMAKE_BUILD_TYPE "${default_build_type}" CACHE
+      STRING "Choose the type of build." FORCE)
+  # Set the possible values of build type for cmake-gui
+  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS
+    "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
+endif()
+
+# Offer the user the choice of overriding the installation directories
+set(INSTALL_LIB_DIR /usr/local/lib CACHE PATH "Installation directory for libraries")
+set(INSTALL_INCLUDE_DIR /usr/local/include CACHE PATH "Installation directory for header files")
+
+if(WIN32 AND NOT CYGWIN)
+  set(DEF_INSTALL_CMAKE_DIR CMake)
+else()
+  set(DEF_INSTALL_CMAKE_DIR lib/cmake/${PROJECT_NAME})
+endif()
+set(INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH 
+    "Installation directory for CMake files")
+
 # read the version number from the file "VERSION" 
 file(STRINGS "VERSION" VERSION_CONTENTS)
 foreach(LINE ${VERSION_CONTENTS})
@@ -10,10 +37,15 @@ foreach(LINE ${VERSION_CONTENTS})
   string(REPLACE "${VERSION_NAME}=" "" VERSION_VALUE ${LINE})
   set(${VERSION_NAME} "${VERSION_VALUE}")
 endforeach()
+set(OPEN_SIMULATION_INTERFACE_VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH})
+
+set(INSTALL_LIB_DIR ${INSTALL_LIB_DIR}/osi${VERSION_MAJOR})
+set(INSTALL_INCLUDE_DIR ${INSTALL_INCLUDE_DIR}/osi${VERSION_MAJOR})
 
 configure_file(osi_version.proto.in ${CMAKE_CURRENT_SOURCE_DIR}/osi_version.proto)
 
 find_package(Protobuf 2.6.1 REQUIRED)
+set(PROTOBUF_IMPORT_DIRS ${PROTOBUF_INCLUDE_DIRS})
 
 set(OSI_PROTO_FILES
     osi_version.proto
@@ -41,16 +73,21 @@ add_library(${PROJECT_NAME}_static STATIC ${PROTO_SRCS} ${PROTO_HEADERS})
 target_include_directories(${PROJECT_NAME}_static
     PUBLIC
         ${PROTOBUF_INCLUDE_DIR}
-        ${CMAKE_CURRENT_BINARY_DIR}
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
+        $<INSTALL_INTERFACE:${INSTALL_INCLUDE_DIR}>
 )
 target_link_libraries(${PROJECT_NAME}_static PUBLIC ${PROTOBUF_LIBRARY})
+install(TARGETS ${PROJECT_NAME}_static
+        EXPORT ${PROJECT_NAME}_targets
+        ARCHIVE DESTINATION "${INSTALL_LIB_DIR}" COMPONENT lib)
 
 
 add_library(${PROJECT_NAME}_obj OBJECT ${PROTO_SRCS} ${PROTO_HEADERS})
 target_include_directories(${PROJECT_NAME}_obj
     PUBLIC
         ${PROTOBUF_INCLUDE_DIR}
-        ${CMAKE_CURRENT_BINARY_DIR}
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
+        $<INSTALL_INTERFACE:${INSTALL_INCLUDE_DIR}>
 )
 set_property(TARGET ${PROJECT_NAME}_obj PROPERTY POSITION_INDEPENDENT_CODE ON)
 
@@ -59,20 +96,58 @@ add_library(${PROJECT_NAME}_pic STATIC $<TARGET_OBJECTS:${PROJECT_NAME}_obj>)
 target_include_directories(${PROJECT_NAME}_pic
     PUBLIC
         ${PROTOBUF_INCLUDE_DIR}
-        ${CMAKE_CURRENT_BINARY_DIR}
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
+        $<INSTALL_INTERFACE:${INSTALL_INCLUDE_DIR}>
 )
 target_link_libraries(${PROJECT_NAME}_pic PUBLIC ${PROTOBUF_LIBRARY})
 set_property(TARGET ${PROJECT_NAME}_pic PROPERTY POSITION_INDEPENDENT_CODE ON)
 
+install(TARGETS ${PROJECT_NAME}_pic
+        EXPORT ${PROJECT_NAME}_targets
+        ARCHIVE DESTINATION "${INSTALL_LIB_DIR}" COMPONENT lib)
+
 
 add_library(${PROJECT_NAME} SHARED $<TARGET_OBJECTS:${PROJECT_NAME}_obj>)
 target_include_directories(${PROJECT_NAME}
     PUBLIC
         ${PROTOBUF_INCLUDE_DIR}
-        ${CMAKE_CURRENT_BINARY_DIR}
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
+        $<INSTALL_INTERFACE:${INSTALL_INCLUDE_DIR}>
 )
 target_link_libraries(${PROJECT_NAME} PUBLIC ${PROTOBUF_LIBRARY})
-
+install(TARGETS ${PROJECT_NAME}
+        EXPORT ${PROJECT_NAME}_targets
+        DESTINATION "${INSTALL_LIB_DIR}" COMPONENT lib)
+
+# Create the open_simulation_interface.cmake and open_simulation_interface-version files
+
+# ... for the build tree
+set(CONF_INCLUDE_DIRS "${PROJECT_SOURCE_DIR}" "${PROJECT_BINARY_DIR}")
+configure_file(open_simulation_interface-config.cmake.in
+               "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config.cmake" @ONLY)
+# ... for the install tree
+set(CONF_INCLUDE_DIRS ${INSTALL_INCLUDE_DIR} ${PROTOBUF_INCLUDE_DIR})
+configure_file(open_simulation_interface-config.cmake.in
+               "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/open_simulation_interface-config.cmake" @ONLY)
+# ... for both
+configure_file(open_simulation_interface-config-version.cmake.in
+               "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake" @ONLY)
+
+# Install the *cmake files
+install(FILES
+        "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/open_simulation_interface-config.cmake"
+        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake"
+        DESTINATION "${INSTALL_CMAKE_DIR}"
+        COMPONENT dev)
+
+# Header files
+install(FILES ${PROTO_HEADERS}
+        DESTINATION "${INSTALL_INCLUDE_DIR}")
+
+# Install the export set for use with the install-tree
+install(EXPORT ${PROJECT_NAME}_targets
+        DESTINATION "${INSTALL_CMAKE_DIR}" 
+        COMPONENT dev)
 
 # add a target to generate API documentation with Doxygen
 # Dependencies: Doxygen and proto2cpp.py
@@ -102,4 +177,5 @@ else()
 
     endif(NOT EXISTS ${FILTER_PROTO2CPP_PY_PATH}/proto2cpp.py)
 
-endif(NOT DOXYGEN_FOUND)
+endif(NOT DOXYGEN_FOUND)
+

VERSION

@@ -1,3 +1,3 @@
 VERSION_MAJOR = 2
 VERSION_MINOR = 2
-VERSION_PATCH = 0
+VERSION_PATCH = 1