firefox: add Whinlatter compatibility

- meta-clang is only a requirement for pre-whinlatter versions
- add a config fragment to specify the correct S variable for cbindgen
  and wasi-sdk-native, as they need different values in whinlatter and
  pre-whinlatter versions
- Firefox recipe specifies the AS variable to be used during compilation,
  however due to a change in whinlatter such changes need to be done inside
  tasks, otherwise the default toolchain settings overwrite these due to
  deferred inheritance. Move the AS specification into tasks.

Co-authored-by: Calvin Owens <calvin@wbinvd.org>
Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>

Author: 2 people

meta-firefox/classes/mozilla.bbclass

@@ -53,6 +53,8 @@ mozilla_run_mach() {
 	export INSTALL_SDK=0
 	export DESTDIR="${D}"
 
+	export AS="${CC}"
+
         cd "${S}"
 
 	./mach "$@"

meta-firefox/conf/layer.conf

@@ -115,6 +115,9 @@ BBFILE_PATTERN_firefox-browser-layer := "^${LAYERDIR}/"
 BBFILE_PRIORITY_firefox-browser-layer = "7"
 
 LAYERVERSION_firefox-browser-layer = "2"
-LAYERSERIES_COMPAT_firefox-browser-layer = "kirkstone scarthgap walnascar"
+LAYERSERIES_COMPAT_firefox-browser-layer = "kirkstone scarthgap walnascar whinlatter"
 
-LAYERDEPENDS_firefox-browser-layer = "clang-layer core openembedded-layer"
+LAYERDEPENDS_firefox-browser-layer = "core openembedded-layer"
+LAYERDEPENDS_firefox-browser-layer:append = '${@"" if "whinlatter" in d.getVar("LAYERSERIES_CORENAMES") else " clang-layer "}'
+
+require conf/post-whinlatter-s-config.inc

meta-firefox/conf/post-whinlatter-s-config.inc

@@ -0,0 +1,14 @@
+# In whinlatter the UNPACKDIR location has changed, and pathes created using
+# the ${WORKDIR} variable are not valid anymore. However older versions still
+# require these. This fragment contains a list of recipes in the meta-firefox
+# layer that needs their "S" variable modified depending on the used Yocto
+# version.
+
+WHINLATTER_S = "${UNPACKDIR}/${BB_GIT_DEFAULT_DESTSUFFIX}"
+NON_WHINLATTER_S = "${WORKDIR}/git"
+
+CORRECT_S = '${@bb.utils.contains_any("LAYERSERIES_CORENAMES", "whinlatter", d.getVar("WHINLATTER_S"), d.getVar("NON_WHINLATTER_S"), d)}'
+
+S:pn-cbindgen = "${CORRECT_S}"
+S:pn-cbindgen-native = "${CORRECT_S}"
+S:pn-wasi-sdk-native = "${CORRECT_S}"

meta-firefox/recipes-browser/firefox/firefox.inc

@@ -1,7 +1,7 @@
 DESCRIPTION ?= "Browser made by Mozilla"
 
 DEPENDS:append = "pulseaudio cbindgen-native clang-native \
-            nodejs-native python-zstandard gtk+3 \
+            nodejs-native python3-zstandard gtk+3 \
             libevent dbus-glib"
 
 DEPENDS:x86-64:append = " nasm-native "
@@ -121,7 +121,6 @@ SRC_URI += "${@bb.utils.contains('PACKAGECONFIG', 'forbid-multiple-compositors',
            ', '', d)}"
 
 TOOLCHAIN:pn-firefox = "clang"
-AS = "${CC}"
 
 DISABLE_STATIC = ""
 

meta-firefox/recipes-devtools/cbindgen/cbindgen_0.28.0.bb

@@ -1,11 +1,10 @@
 SUMMARY = "cbindgen creates C/C++11 headers for Rust libraries which expose a public C API"
 HOMEPAGE = "https://github.com/mozilla/cbindgen"
 LICENSE = "MPL-2.0"
-LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=9741c346eef56131163e13b9db1241b3"
 
 SRC_URI += "git://github.com/mozilla/cbindgen.git;protocol=https;branch=master"
 SRCREV = "bd78bbe59b10eda6ef1255e4acda95c56c6d0279"
-S = "${WORKDIR}/git"
 
 inherit cargo pkgconfig
 

meta-firefox/recipes-devtools/python-zstandard/python-zstandard_0.21.0.bb renamed to meta-firefox/recipes-devtools/python3-zstandard/python3-zstandard_0.21.0.bb

@@ -4,12 +4,6 @@ AUTHOR = "Gregory Szorc <gregory.szorc@gmail.com>"
 LICENSE = "BSD-3-Clause"
 LIC_FILES_CHKSUM = "file://LICENSE;md5=3ae87c50fd64b6f0942823686871e758"
 
-SRC_URI = "https://files.pythonhosted.org/packages/4d/70/1f883646641d7ad3944181549949d146fa19e286e892bc013f7ce1579e8f/zstandard-0.21.0.tar.gz"
-SRC_URI[md5sum] = "7baafeb332651d70881ce692edf912b3"
 SRC_URI[sha256sum] = "f08e3a10d01a247877e4cb61a82a319ea746c356a3786558bed2481e6c405546"
 
-S = "${WORKDIR}/zstandard-0.21.0"
-
-RDEPENDS_${PN} = ""
-
-inherit setuptools3
+inherit setuptools3 pypi

meta-firefox/recipes-devtools/wasi-sdk/files/0001-allow-compiling-with-cmake-4.patch

@@ -0,0 +1,25 @@
+From bf31dbdd45582713fd8727ecd3873e656f2b567a Mon Sep 17 00:00:00 2001
+From: Gyorgy Sarvari <skandigraun@gmail.com>
+Date: Sun, 20 Jul 2025 20:24:41 +0200
+Subject: [PATCH] allow compiling with cmake 4
+
+Upstream-Status: Pending
+
+Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>
+---
+ wasi-sdk.cmake | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/wasi-sdk.cmake b/wasi-sdk.cmake
+index 83ee9b0..a2ef1b2 100644
+--- a/wasi-sdk.cmake
++++ b/wasi-sdk.cmake
+@@ -1,7 +1,7 @@
+ # Cmake toolchain description file for the Makefile
+ 
+ # This is arbitrary, AFAIK, for now.
+-cmake_minimum_required(VERSION 3.4.0)
++cmake_minimum_required(VERSION 3.5.0)
+ 
+ set(CMAKE_SYSTEM_NAME WASI)
+ set(CMAKE_SYSTEM_VERSION 1)

meta-firefox/recipes-devtools/wasi-sdk/wasi-sdk-native_git.bb

@@ -10,14 +10,12 @@ inherit native
 
 DEPENDS = "clang-native cmake-native ninja-native"
 
-S = "${WORKDIR}/git"
-
 SRC_URI = "gitsm://github.com/WebAssembly/wasi-sdk.git;protocol=https;branch=main"
-SRC_URI += "file://0001-disable-exceptions-and-bulk-memory.patch"
+SRC_URI += "file://0001-disable-exceptions-and-bulk-memory.patch \
+            file://0001-allow-compiling-with-cmake-4.patch"
 
 SRCREV = "3fb0057a6da0313d18dad241ef7a87aa43f1485c"
 
-
 TOOLCHAIN = "clang"
 TOOLCHAIN:class-native = "clang"