add conversion for named tuples

Author: Christopher Doris

docs/src/releasenotes.md

@@ -1,6 +1,8 @@
 # Release Notes
 
 ## Unreleased
+* Python named tuples can be converted to Julia named tuples. So can Python iterables, if
+  the target `NamedTuple` type specifies field names.
 * Bug fixes.
 
 ## 0.9.5 (2022-08-19)

src/abstract/collection.jl

@@ -169,3 +169,29 @@ function pyconvert_rule_iterable(::Type{R}, x::Py, ::Type{Pair{K0,V0}}=Utils._ty
     V2 = Utils._promote_type_bounded(V0, typeof(v), V1)
     return pyconvert_return(Pair{K2,V2}(k, v))
 end
+
+# NamedTuple
+
+_nt_names_types(::Type) = nothing
+_nt_names_types(::Type{NamedTuple}) = (nothing, nothing)
+_nt_names_types(::Type{NamedTuple{names}}) where {names} = (names, nothing)
+_nt_names_types(::Type{NamedTuple{names,types} where {names}}) where {types} = (nothing, types)
+_nt_names_types(::Type{NamedTuple{names,types}}) where {names,types} = (names, types)
+
+function pyconvert_rule_iterable(::Type{R}, x::Py) where {R<:NamedTuple}
+    # this is actually strict and only converts python named tuples (i.e. tuples with a
+    # _fields attribute) where the field names match those from R (if specified).
+    names_types = _nt_names_types(R)
+    names_types === nothing && return pyconvert_unconverted()
+    names, types = names_types
+    PythonCall.pyistuple(x) || return pyconvert_unconverted()
+    names2_ = pygetattr(x, "_fields", pybuiltins.None)
+    names2 = @pyconvert(names === nothing ? Tuple{Vararg{Symbol}} : typeof(names), names2_)
+    pydel!(names2_)
+    names === nothing || names === names2 || return pyconvert_unconverted()
+    types2 = types === nothing ? NTuple{length(names2),Any} : types
+    vals = @pyconvert(types2, x)
+    length(vals) == length(names2) || return pyconvert_unconverted()
+    types3 = types === nothing ? typeof(vals) : types
+    return pyconvert_return(NamedTuple{names2,types3}(vals))
+end

src/convert.jl

@@ -415,6 +415,7 @@ function init_pyconvert()
     pyconvert_add_rule("_io:_IOBase", PyIO, pyconvert_rule_io, priority)
     pyconvert_add_rule("pandas.core.frame:DataFrame", PyPandasDataFrame, pyconvert_rule_pandasdataframe, priority)
     pyconvert_add_rule("pandas.core.arrays.base:ExtensionArray", PyList, pyconvert_rule_sequence, priority)
+    pyconvert_add_rule("builtins:tuple", NamedTuple, pyconvert_rule_iterable, priority)
     pyconvert_add_rule("builtins:tuple", Tuple, pyconvert_rule_iterable, priority)
     pyconvert_add_rule("datetime:datetime", DateTime, pyconvert_rule_datetime, priority)
     pyconvert_add_rule("datetime:date", Date, pyconvert_rule_date, priority)

test/convert.jl

@@ -154,6 +154,21 @@ end
     @test x2 === ("foo" => missing)
 end
 
+@testitem "named tuple → NamedTuple" begin
+    NT = pyimport("collections" => "namedtuple")
+    t1 = pyconvert(NamedTuple, NT("NT", "x y")(1, 2))
+    @test t1 === (x=1, y=2)
+    @test_throws Exception pyconvert(NamedTuple, (2, 3))
+    t2 = pyconvert(NamedTuple{(:x, :y)}, NT("NT", "x y")(3, 4))
+    @test t2 === (x=3, y=4)
+    @test_throws Exception pyconvert(NamedTuple{(:y, :x)}, NT("NT", "x y")(3, 4))
+    t3 = pyconvert(NamedTuple{names,Tuple{Int,Int}} where {names}, NT("NT", "x y")(4, 5))
+    @test t3 === (x=4, y=5)
+    @test_throws Exception pyconvert(NamedTuple{names,Tuple{Int,Int}} where {names}, (5, 6))
+    t4 = pyconvert(NamedTuple{(:x, :y),Tuple{Int,Int}}, NT("NT", "x y")(6, 7))
+    @test t4 === (x=6, y=7)
+end
+
 @testitem "mapping → Dict" begin
     x1 = pyconvert(Dict, pydict(["a"=>1, "b"=>2]))
     @test x1 isa Dict{String, Int}