Add issymmetrictype and ishermitiantype

Author: jishnub

src/symmetric.jl

@@ -461,9 +461,34 @@ issymmetric(A::Hermitian{<:Real}) = true
 issymmetric(A::Hermitian{<:Complex}) = isreal(A)
 issymmetric(A::Symmetric) = true
 
-# check if the symmetry is known from the type
-_issymmetric(::Union{SymSymTri, Hermitian{<:Real}}) = true
-_issymmetric(::Any) = false
+"""
+    issymmetrictype(T::Type)
+
+Return whether every instance `x` of the type `T` satisfies `issymmetric(x) == tue`,
+that is, the fact that the instance is symmetric is known from its type.
+
+!!! note
+    An instance `x::T` may still be symmetric when `issymmetrictype(T)` return `false`.
+"""
+issymmetrictype(::Type) = false
+issymmetrictype(::Type{<:Union{Symmetric,Hermitian{<:Real}}}) = true
+issymmetrictype(::Type{<:Real}) = true
+issymmetrictype(::Type{<:AbstractFloat}) = false
+issymmetrictype(::Type{Complex{T}}) where {T} = issymmetrictype(T)
+
+"""
+    ishermitiantype(T::Type)
+
+Return whether every instance `x` of the type `T` satisfies `ishermitian(x) == tue`,
+that is, the fact that the instance is hermitian is known from its type.
+
+!!! note
+    An instance `x::T` may still be hermitian when `ishermitiantype(T)` return `false`.
+"""
+ishermitiantype(::Type) = false
+ishermitiantype(::Type{<:Union{Symmetric{<:Real},Hermitian}}) = true
+ishermitiantype(::Type{<:Real}) = true
+ishermitiantype(::Type{<:AbstractFloat}) = false
 
 adjoint(A::Hermitian) = A
 transpose(A::Symmetric) = A

src/tridiag.jl

@@ -111,7 +111,7 @@ function (::Type{SymTri})(A::AbstractMatrix) where {SymTri <: SymTridiagonal}
     checksquare(A)
     du = diag(A, 1)
     d  = diag(A)
-    if !(_issymmetric(A) || _checksymmetric(d, du, diag(A, -1)))
+    if !(issymmetrictype(typeof(A)) || _checksymmetric(d, du, diag(A, -1)))
         throw(ArgumentError("matrix is not symmetric; cannot convert to SymTridiagonal"))
     end
     return SymTri(d, du)

test/symmetric.jl

@@ -1343,4 +1343,26 @@ end
     @test_throws msg LinearAlgebra.fillband!(Symmetric(A), 2, 0, 1)
 end
 
+@testset "issymmetrictype/ishermitiantype" begin
+    fsym(x) = Val(LinearAlgebra.issymmetrictype(typeof(x)))
+    @test @inferred(fsym(Symmetric(ones(2,2)))) == Val(true)
+    @test @inferred(fsym(Symmetric(ones(ComplexF64,2,2)))) == Val(true)
+    @test @inferred(fsym(Hermitian(ones(2,2)))) == Val(true)
+    @test @inferred(fsym(Hermitian(ones(ComplexF64,2,2)))) == Val(false)
+    @test @inferred(fsym(1)) == Val(true)
+    @test @inferred(fsym(1.0)) == Val(false)
+    @test @inferred(fsym(complex(1))) == Val(true)
+    @test @inferred(fsym(complex(1.0))) == Val(false)
+
+    fherm(x) = Val(LinearAlgebra.ishermitiantype(typeof(x)))
+    @test @inferred(fherm(Symmetric(ones(2,2)))) == Val(true)
+    @test @inferred(fherm(Symmetric(ones(ComplexF64,2,2)))) == Val(false)
+    @test @inferred(fherm(Hermitian(ones(2,2)))) == Val(true)
+    @test @inferred(fherm(Hermitian(ones(ComplexF64,2,2)))) == Val(true)
+    @test @inferred(fherm(1)) == Val(true)
+    @test @inferred(fherm(1.0)) == Val(false)
+    @test @inferred(fherm(complex(1))) == Val(false)
+    @test @inferred(fherm(complex(1.0))) == Val(false)
+end
+
 end # module TestSymmetric