Update qmake for translations

Author: u-235

common.pri

@@ -11,18 +11,14 @@ CONFIG(debug, debug|release) {
     DEFINES *= QT_NO_DEBUG_OUTPUT # QT_NO_INFO_OUTPUT
 }
 
-APP_BINS = $${PROJECT_ROOT_PATH}/bin/$${BUILD_FLAG}
+APP_BINS = $$shadowed($${PROJECT_ROOT_PATH})/bin
 
 CONFIG *= c++11
 CONFIG -= debug_and_release debug_and_release_target
 
 # moc doesn't detect Q_OS_LINUX correctly, so add this to make it work
 linux*:DEFINES *= __linux__
 
-LANG_PATH = $${PROJECT_ROOT_PATH}/lang
-# define locales for translation
-LANG_LIST = pl ca de fi cs_CZ es nl ru
-
 !CONFIG(staticlib) {
     DESTDIR = $$APP_BINS
 }
@@ -136,36 +132,6 @@ defineReplace(findFiles) {
 }
 
 
-#
-# function tsFiles(modulename, locales)
-# Returns a list of files with this $${LANG_PATH}/modulename_lang.ts
-# example :
-# TARGET = bar
-# LANG_PATH = lang
-# LANG_LIST = pl fr de
-# $$tsFiles(foo, ru en) returns lang/foo_ru.ts lang/foo_en.ts
-# $$tsFiles(foo) returns lang/foo_pl.ts lang/foo_fr.ts lang/foo_de.ts
-# $$tsFiles() returns lang/bar_pl.ts lang/bar_fr.ts lang/bar_de.ts
-#
-defineReplace(tsFiles) {
-    module_name = $$1
-    locales = $$2
-
-    !defined(1, var) {
-        module_name = $$TARGET
-    }
-
-    !defined(2, var) {
-        locales = $$LANG_LIST
-    }
-
-    for(lang, locales) {
-        file_list += $${LANG_PATH}/$${module_name}_$${lang}.ts
-    }
-
-    return ($$file_list)
-}
-
 defineReplace(getVersion) {
     version_file = gcodeshared/include/version.h
     !exists ($${PROJECT_ROOT_PATH}/$${version_file}): error(In function getVersion: File \"$${version_file}\" not found)

gcodeshared/utils/medium.cpp

@@ -110,9 +110,7 @@ int Medium::checkLaunch()
 
 #endif // Q_OS_WIN
 
-	dir = dir.section(SLASH, -2, -1);
-
-	if (dir.startsWith(BIN) && (dir.endsWith(DEBUG) || dir.endsWith(RELEASE))) {
+	if (dir.contains("build")) {
 		return LAUNCH_SANDBOX;
 	}
 
@@ -144,7 +142,7 @@ void Medium::setupDirs()
 		break;
 
 	case LAUNCH_SANDBOX:
-		shareDir = rootDir.section(SLASH, 0, -3);
+		shareDir = rootDir.section(SLASH, 0, -2);
 		langDir = shareDir;
 		mSettingsDir = shareDir;
 		mSettingsDir.append(SLASH_BIN);

gcodeworkshop_top.pro

@@ -5,26 +5,8 @@ SUBDIRS = 3rdparty gcodeshared addons gcodeworkshop gcodefileserver
 
 
 include(common.pri)
+include(lang/lang.pri)
 
-QMAKE_EXTRA_TARGETS += lupdate
-lupdate.depends = lupdateGCodeWorkShop lupdateKdiff3
-QMAKE_EXTRA_TARGETS += lupdateGCodeWorkShop lupdateKdiff3
-lupdateGCodeWorkShop.commands = $$[QT_INSTALL_BINS]/lupdate \
-    $$PROJECT_ROOT_PATH/gcodeworkshop \
-    $$PROJECT_ROOT_PATH/gcodeshared \
-    $$PROJECT_ROOT_PATH/gcodefileserver \
-    $$PROJECT_ROOT_PATH/addons \
-    -ts $$tsFiles(gcodeworkshop)
-lupdateKdiff3.commands = $$[QT_INSTALL_BINS]/lupdate \
-    $$PROJECT_ROOT_PATH/3rdparty/kdiff3 \
-    -ts $$tsFiles(kdiff3)
-
-QMAKE_EXTRA_TARGETS += lrelease
-lrelease.commands = $$[QT_INSTALL_BINS]/lrelease \
-    $$tsFiles(gcodeworkshop) \
-    $$tsFiles(kdiff3)
-
-translate.files = $$LANG_PATH/*.qm
 examples.files = $$PROJECT_ROOT_PATH/examples/*
 doc.files = $$PROJECT_ROOT_PATH/README.md $$PROJECT_ROOT_PATH/doc/SerialTransmission_Help.html
 
@@ -41,14 +23,13 @@ unix {
     doc.path = $${PREFIX}/share/doc/gcodeworkshop
     mime.path = $${PREFIX}/share/mime/packages
     desktop.path = $${PREFIX}/share/applications
-    translate.path = $${PREFIX}/share/gcodeworkshop/lang
 
     ICONS_BASE_PATH = $$PROJECT_ROOT_PATH/install/linux/images
     icons.base = $$ICONS_BASE_PATH
     icons.files = $$findFiles($$ICONS_BASE_PATH, *.png)
     icons.path = $${PREFIX}/share/icons
 
-    INSTALLS += translate mime desktop icons examples doc
+    INSTALLS += mime desktop icons examples doc
 }
 
 macx {
@@ -57,9 +38,8 @@ macx {
 win32 {
     examples.path = $${PREFIX}/examples
     doc.path = $${PREFIX}/doc
-    translate.path = $${PREFIX}/lang
 
-    INSTALLS += translate examples doc
+    INSTALLS += examples doc
 }
 
 !defined(VERSION, var): VERSION = $$getVersion()

lang/lang.pri

@@ -0,0 +1,51 @@
+# Make target i18n
+########################################
+
+LANG_LIST = $$cat(languages.txt)
+
+QMAKE_EXTRA_TARGETS += i18n
+I18N_IN = $${PWD}
+I18N_OUT = $$shadowed($${I18N_IN})
+
+mkpath($${I18N_OUT})
+
+for (LANG, LANG_LIST) {
+    write_file($${I18N_OUT}/gcodeworkshop_$${LANG}.qm)
+    translates.files += $${I18N_OUT}/gcodeworkshop_$${LANG}.qm
+    QMAKE_EXTRA_TARGETS += i18n_g_$${LANG}
+    i18n.depends += i18n_g_$${LANG}
+    i18n_g_$${LANG}.commands = $$[QT_INSTALL_BINS]/lrelease $${I18N_IN}/gcodeworkshop_$${LANG}.ts -qm $${I18N_OUT}/gcodeworkshop_$${LANG}.qm
+    write_file($${I18N_OUT}/kdiff3_$${LANG}.qm)
+    translates.files += $${I18N_OUT}/kdiff3_$${LANG}.qm
+    QMAKE_EXTRA_TARGETS += i18n_k_$${LANG}
+    i18n.depends += i18n_k_$${LANG}
+    i18n_k_$${LANG}.commands = $$[QT_INSTALL_BINS]/lrelease $${I18N_IN}/kdiff3_$${LANG}.ts -qm $${I18N_OUT}/kdiff3_$${LANG}.qm
+}
+
+translates.base = $$I18N_OUT
+unix: translates.path = $${PREFIX}/share/gcodeworkshop/lang
+win32: translates.path = $${PREFIX}/lang
+!macx: INSTALLS += translates
+
+
+# Make target lupdate
+########################################
+
+QMAKE_EXTRA_TARGETS += lupdate
+lupdate.depends = lupdateGCodeWorkShop lupdateKdiff3
+QMAKE_EXTRA_TARGETS += lupdateGCodeWorkShop lupdateKdiff3
+
+for (LANG, LANG_LIST) {
+    GCODEWORKSHOP_TS += $${I18N_IN}/gcodeworkshop_$${LANG}.ts
+    KDIFF3_TS += $${I18N_IN}/kdiff3_$${LANG}.ts
+}
+
+lupdateGCodeWorkShop.commands = $$[QT_INSTALL_BINS]/lupdate \
+    $$PROJECT_ROOT_PATH/gcodeworkshop \
+    $$PROJECT_ROOT_PATH/gcodeshared \
+    $$PROJECT_ROOT_PATH/gcodefileserver \
+    $$PROJECT_ROOT_PATH/addons \
+    -ts $$GCODEWORKSHOP_TS
+lupdateKdiff3.commands = $$[QT_INSTALL_BINS]/lupdate \
+    $$PROJECT_ROOT_PATH/3rdparty/kdiff3 \
+    -ts $$KDIFF3_TS

lang/languages.txt

@@ -0,0 +1 @@
+ca cs_CZ de es fi nl pl ru