Add basic support for XC8.

Author: Elemecca

Modules/Compiler/XC8-C.cmake

@@ -0,0 +1,44 @@
+#=============================================================================
+# Copyright 2018 Sam Hanes
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file COPYING.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake-Microchip,
+#  substitute the full License text for the above reference.)
+
+# called by `CMakeCInformation`
+# to configure the XC8 compiler interface for C files
+
+
+set(MICROCHIP_XC8_MODE "free"
+    CACHE STRING "the license mode for XC8 (pro, std, free)"
+)
+
+string(APPEND CMAKE_C_FLAGS_INIT
+    # don't output the copyright notice on every invocation
+    "-Q"
+    # use the configured license mode and fail if it's not available
+    " --mode=${MICROCHIP_XC8_MODE} --nofallback"
+    # build for the configured MCU model
+    " --chip=${MICROCHIP_MCU_MODEL}"
+)
+
+set(CMAKE_C_OUTPUT_EXTENSION ".p1")
+
+set(CMAKE_C_COMPILE_OBJECT)
+string(APPEND CMAKE_C_COMPILE_OBJECT
+    "<CMAKE_C_COMPILER> <FLAGS> <DEFINES> <INCLUDES>"
+    "   -o<OBJECT>   --pass1 <SOURCE>"
+)
+
+set(CMAKE_C_LINK_EXECUTABLE)
+string(APPEND CMAKE_C_LINK_EXECUTABLE
+    "<CMAKE_C_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS>"
+    "   <OBJECTS>   <LINK_LIBRARIES>"
+    "   -o<TARGET>"
+)

Modules/Platform/MicrochipMCU-C-XC8.cmake

@@ -0,0 +1,63 @@
+#=============================================================================
+# Copyright 2018 Sam Hanes
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file COPYING.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake-Microchip,
+#  substitute the full License text for the above reference.)
+
+# this module is called by `Platform/MicrochipMCU-C`
+# to provide information specific to the XC8 compiler
+
+include(MicrochipPathSearch)
+MICROCHIP_PATH_SEARCH(MICROCHIP_XC8_PATH xc8
+    CACHE "the path to a Microchip XC8 installation"
+)
+
+if(NOT MICROCHIP_XC8_PATH)
+    message(FATAL_ERROR
+        "No Microchip XC8 compiler was found. Please provide the path"
+        " to an XC8 installation on the command line, for example:\n"
+        "cmake -DMICROCHIP_XC8_PATH=/opt/microchip/xc8/v2.00 ."
+    )
+endif()
+
+
+set(CMAKE_FIND_ROOT_PATH ${MICROCHIP_XC8_PATH})
+
+# skip compiler search and just use XC8
+find_program(CMAKE_C_COMPILER "xc8")
+
+# skip compiler ID since XC8 isn't supported by CMake's test file
+set(CMAKE_C_COMPILER_ID_RUN 1)
+set(CMAKE_C_COMPILER_ID "XC8")
+
+# call the compiler to check its version
+function(_xc8_get_version)
+    execute_process(
+        COMMAND "${CMAKE_C_COMPILER}" "--ver"
+        OUTPUT_VARIABLE output
+        ERROR_VARIABLE  output
+        RESULT_VARIABLE result
+    )
+
+    if(result)
+        message(FATAL_ERROR
+            "Calling '${CMAKE_C_COMPILER} --ver' failed."
+        )
+    endif()
+
+    if(output MATCHES "XC8 C Compiler V([0-9]+\.[0-9]+)")
+        set(CMAKE_C_COMPILER_VERSION ${CMAKE_MATCH_1} PARENT_SCOPE)
+    else()
+        message(FATAL_ERROR
+            "Failed to parse output of '${CMAKE_C_COMPILER} --ver'."
+        )
+    endif()
+endfunction()
+_xc8_get_version()

Modules/Platform/MicrochipMCU-C.cmake

@@ -14,7 +14,9 @@
 # This module is loaded during the search for a C compiler
 # to provide the information necessary to find one.
 
-if(CMAKE_SYSTEM_PROCESSOR STREQUAL "PIC_16")
+if(CMAKE_SYSTEM_PROCESSOR STREQUAL "PIC_8")
+    include(Platform/MicrochipMCU-C-XC8)
+elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL "PIC_16")
     include(Platform/MicrochipMCU-C-XC16)
 elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL "PIC_32")
     include(Platform/MicrochipMCU-C-XC32)