Add support for the xc8-cc CLI from XC8 2.00.

Elemecca · Elemecca · commit fec239727cbe · 2019-03-20T10:15:17.000-07:00
diff --git a/Modules/Compiler/XC8-C.cmake b/Modules/Compiler/XC8-C.cmake
@@ -13,6 +13,8 @@
 
 # called by `CMakeCInformation`
 # to configure the XC8 compiler interface for C files
+# this supports the `xc8` CLI driver in XC8 1.x
+# and the equivalent legacy CLI driver in XC8 2.x
 
 
 set(MICROCHIP_XC8_MODE "free"
diff --git a/Modules/Compiler/XC8CC-C.cmake b/Modules/Compiler/XC8CC-C.cmake
@@ -0,0 +1,39 @@
+#=============================================================================
+# Copyright 2019 Sam Hanes
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file COPYING.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake-Microchip,
+#  substitute the full License text for the above reference.)
+
+# called by `CMakeCInformation`
+# to configure the XC8CC compiler interface for C files
+# this supports the xc8-cc CLI driver from XC8 v2.x
+
+
+string(APPEND CMAKE_C_FLAGS_INIT
+    # build for the configured MCU model
+    " -mcpu=${MICROCHIP_MCU_MODEL}"
+    # fail if the requested optimization level is forbidden by the license
+    " --nofallback"
+)
+
+set(CMAKE_C_OUTPUT_EXTENSION ".p1")
+
+set(CMAKE_C_COMPILE_OBJECT)
+string(APPEND CMAKE_C_COMPILE_OBJECT
+    "<CMAKE_C_COMPILER> <FLAGS> <DEFINES> <INCLUDES>"
+    "   -o <OBJECT>   -c <SOURCE>"
+)
+
+set(CMAKE_C_LINK_EXECUTABLE)
+string(APPEND CMAKE_C_LINK_EXECUTABLE
+    "<CMAKE_C_COMPILER> <FLAGS> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS>"
+    "   <OBJECTS>   <LINK_LIBRARIES>"
+    "   -o <TARGET>"
+)
diff --git a/Modules/Platform/MicrochipMCU-C-XC8.cmake b/Modules/Platform/MicrochipMCU-C-XC8.cmake
@@ -27,19 +27,64 @@ if(NOT MICROCHIP_XC8_PATH)
     )
 endif()
 
-
 set(CMAKE_FIND_ROOT_PATH "${MICROCHIP_XC8_PATH}")
 
-# skip compiler search and just use XC8
-find_program(CMAKE_C_COMPILER "xc8"
-    PATHS "${MICROCHIP_XC8_PATH}"
-    PATH_SUFFIXES "bin"
+
+if(NOT MICROCHIP_XC8_CLI)
+    set(MICROCHIP_XC8_CLI "xc8-cc")
+    set(_xc8_cli_default TRUE CACHE INTERNAL "" FORCE)
+endif()
+set(MICROCHIP_XC8_CLI "${MICROCHIP_XC8_CLI}"
+    CACHE STRING "the XC8 CLI driver to use ('xc8-cc' or 'xc8')"
 )
 
+
+if(MICROCHIP_XC8_CLI STREQUAL "xc8-cc")
+    find_program(CMAKE_C_COMPILER "xc8-cc"
+        PATHS "${MICROCHIP_XC8_PATH}"
+        PATH_SUFFIXES "bin"
+    )
+    set(_xc8_version_flag "--version")
+    set(CMAKE_C_COMPILER_ID "XC8CC")
+elseif(MICROCHIP_XC8_CLI STREQUAL "xc8")
+    find_program(CMAKE_C_COMPILER "xc8"
+        PATHS "${MICROCHIP_XC8_PATH}"
+        PATH_SUFFIXES "bin"
+    )
+    set(_xc8_version_flag "--ver")
+    set(CMAKE_C_COMPILER_ID "XC8")
+else()
+    message(FATAL_ERROR
+        "Invalid choice '${MICROCHIP_XC8_CLI}' for MICROCHIP_XC8_CLI."
+        " Please choose either 'xc8-cc' (recommended) or 'xc8'."
+        " See docs/xc8.md in your cmake-microchip installation for"
+        " details on this option."
+    )
+endif()
+
+
 if(NOT CMAKE_C_COMPILER)
+    if(_xc8_cli_default)
+        message(WARNING
+            "The XC8 command-line driver was not explicitly selected,"
+            " so the newer 'xc8-cc' driver is being used. This requires"
+            " XC8 version 2.00 or newer. If you want to use older versions"
+            " of XC8, or if you want to use the legacy 'xc8' driver in XC8"
+            " 2.00 or newer, add this line to your CMakeLists.txt before"
+            " the 'project' command:\n"
+            "    set(MICROCHIP_XC8_CLI xc8)\n"
+            "To suppress this message when XC8 is not found but continue"
+            " using the newer 'xc8-cc' driver, add this line to your"
+            " CMakeLists.txt before the 'project' command:\n"
+            "    set(MICROCHIP_XC8_CLI xc8-cc)\n"
+            "For more information on selecting a command-line driver"
+            " see docs/xc8.md in your cmake-microchip installation."
+        )
+    endif()
+
     message(FATAL_ERROR
-        "The XC8 compiler executable was not found, but what looks"
-        " like an XC8 installation was found at:\n"
+        "The XC8 compiler executable ${MICROCHIP_XC8_CLI} was not found,"
+        " but what looks like an XC8 installation was found at:\n"
         "    ${MICROCHIP_XC8_PATH}\n"
         "Please provide the path to a working XC8 installation on the"
         " command line, for example:\n"
@@ -49,28 +94,27 @@ endif()
 
 # skip compiler ID since XC8 isn't supported by CMake's test file
 set(CMAKE_C_COMPILER_ID_RUN 1)
-set(CMAKE_C_COMPILER_ID "XC8")
 
 # call the compiler to check its version
 function(_xc8_get_version)
     execute_process(
-        COMMAND "${CMAKE_C_COMPILER}" "--ver"
+        COMMAND "${CMAKE_C_COMPILER}" "${_xc8_version_flag}"
         OUTPUT_VARIABLE output
         ERROR_VARIABLE  output
         RESULT_VARIABLE result
     )
 
     if(result)
         message(FATAL_ERROR
-            "Calling '${CMAKE_C_COMPILER} --ver' failed."
+            "Calling '${CMAKE_C_COMPILER} ${_xc8_version_flag}' failed."
         )
     endif()
 
     if(output MATCHES "XC8 C Compiler V([0-9]+\.[0-9]+)")
         set(CMAKE_C_COMPILER_VERSION ${CMAKE_MATCH_1} PARENT_SCOPE)
     else()
         message(FATAL_ERROR
-            "Failed to parse output of '${CMAKE_C_COMPILER} --ver'."
+            "Failed to parse output of '${CMAKE_C_COMPILER} ${_xc8_version_flag}'."
         )
     endif()
 endfunction()
diff --git a/docs/xc8.md b/docs/xc8.md
@@ -0,0 +1,56 @@
+
+## Versions
+
+In XC8 version 2.00, Microchip switched from their proprietary HI-TECH C
+frontend to Clang in order to support C99. Rather than implement PIC
+code generation in LLVM, they translate LLVM's IR to p-code (the HI-TECH
+IR), which is then run through the same code generator used with the old
+HI-TECH frontend. Although they use Clang by default, current versions
+of XC8 still include the HI-TECH C frontend to support older projects.
+They've also bundled in AVR-GCC to support AVR parts.
+
+### Command-line Driver
+
+Since they now need to support multiple compilers, Microchip also
+introduced a new command-line driver, `xc8-cc`, in XC8 2.00.  `xc8-cc`
+is completely custom, but it uses GCC-style options for compatibility
+with XC16 and XC32. The old command-line driver `xc8` was retained for
+backwards compatibility.
+
+You can select which command-line driver to use by setting
+`MICROCHIP_XC8_CLI` to either `xc8-cc` or `xc8` in your `CMakeLists.txt`
+before calling the `project` command (which is when compiler resolution
+occurs). For example:
+
+```cmake
+# set up the Microchip cross toolchain
+set(CMAKE_TOOLCHAIN_FILE external/cmake-microchip/toolchain.cmake)
+
+# set the default MCU model
+set(MICROCHIP_MCU PIC18F87J50)
+
+# use the new command-line driver
+set(MICROCHIP_XC8_CLI xc8-cc)
+
+
+project(example C)
+```
+
+`MICROCHIP_XC8_CLI` may also be set on the command line as a cache
+variable, although doing so may break your project if you use
+command-line flags in your configuration that are specific to one of the
+drivers. For example:
+
+```plain
+cmake -DMICROCHIP_XC8_CLI=xc8 -DMICROCHIP_XC8_PATH=/opt/microchip/xc8/v1.45 .
+```
+
+For new projects it is recommended to use `xc8-cc`, which is the default
+in cmake-microchip as of version 0.3. Using `xc8-cc` is required if you
+want to use Clang (for C99) or AVR-GCC.
+
+Using the legacy `xc8` command-line driver is only recommended if you
+need to support versions of XC8 before 2.00, or if you have a significant
+number of command-line flags for `xc8` already and don't want to port
+them. It is *not* necessary to use `xc8` in order to use the old HI-TECH
+C frontend.
