Merge pull request #859 from Devsh-Graphics-Programming/yas_buildinfo

Build info cmake target

Author: AnastaZIuk

CMakeLists.txt

@@ -48,9 +48,10 @@ endif()
 
 find_package(Vulkan)
 if (Vulkan_FOUND)
-	message(STATUS "Building with Vulkan driver")
+	message(STATUS "Found Vulkan SDK")
+	cmake_path(GET Vulkan_INCLUDE_DIR PARENT_PATH VULKAN_SDK)
 else()
-	message(STATUS "Vulkan driver is not enabled")
+	message(STATUS "Vulkan SDK is not found")
 endif()
 
 option(NBL_COMPILE_WITH_CUDA "Compile with CUDA interop?" OFF)
@@ -280,5 +281,5 @@ add_subdirectory(artifacts)
 
 option(NBL_CPACK_INCLUDE_EXAMPLES "CPack with examples and media" ON)
 include(cpack/package)
-
+include(build/info)
 export(TARGETS ${_NBL_3RDPARTY_TARGETS_} Nabla NAMESPACE Nabla:: APPEND FILE ${NBL_ROOT_PATH_BINARY}/NablaExport.cmake)

cmake/build/info.cmake

@@ -0,0 +1,38 @@
+include_guard(GLOBAL)
+
+if (NOT DEFINED NBL_ROOT_PATH_BINARY)
+	message(FATAL_ERROR "NBL_ROOT_PATH_BINARY is not defined or it's empty")
+endif()
+
+if(NOT TARGET gtml)
+	message(FATAL_ERROR "gtml target not defined!")
+endif()
+
+set(OUTPUT_DIR "${NBL_ROOT_PATH_BINARY}")
+
+if(Vulkan_FOUND)
+	set(VKSDK_INFO_CMD "${VULKAN_SDK}/bin/vulkaninfoSDK" -j -o "${OUTPUT_DIR}/vulkan-info.json")
+else()
+	set(VKSDK_INFO_CMD "${CMAKE_COMMAND}" -E touch "${OUTPUT_DIR}/vulkan-info.json")
+endif()
+
+execute_process(COMMAND ${VKSDK_INFO_CMD})
+execute_process(COMMAND "${CMAKE_COMMAND}" -E capabilities OUTPUT_VARIABLE PIPE)
+file(WRITE "${OUTPUT_DIR}/cmake-caps.json" "${PIPE}")
+
+get_target_property(GTML_SOURCES gtml SOURCES)
+list(FILTER GTML_SOURCES INCLUDE REGEX "git_info\\.cpp$")
+
+set(BUILD_INFO_DEPENDENCIES 
+	"${OUTPUT_DIR}/vulkan-info.json"
+	"${OUTPUT_DIR}/cmake-caps.json"
+	CMakeCache.txt
+	CMakeFiles/CMakeConfigureLog.yaml
+	${GTML_SOURCES}
+)
+
+add_custom_target(nbl_build_info 
+	DEPENDS ${BUILD_INFO_DEPENDENCIES} gtml
+	COMMAND "${CMAKE_COMMAND}" -E tar c build_info.zip --format=zip ${BUILD_INFO_DEPENDENCIES}
+	COMMENT "Generating \"${NBL_ROOT_PATH_BINARY}/build_info.zip\", attach this within your issue"
+)